作业真的成功了吗?_链接服务器远程存储过程调用失败

工作环境中,之前遇到了一个问题. 作业中使用链接服务器远程存储过程调用. 实际是失败了,但代理作业并没有报出这个错误.

查了一下在2008年,就有这个报告了.

https://connect.microsoft.com/SQLServer/feedback/details/337043/no-error-raised-when-a-remote-procedure-times-out

 

例子:

1.建立一个链接服务器

EXEC master.dbo.sp_addlinkedserver @server = N'LOCALHOST', @srvproduct=N'SQL Server'
EXEC master.dbo.sp_addlinkedsrvlogin @rmtsrvname=N'LOCALHOST',@useself=N'True',@locallogin=NULL,@rmtuser=NULL,@rmtpassword=NULL
EXEC master.dbo.sp_serveroption @server=N'LOCALHOST', @optname=N'rpc', @optvalue=N'true'
EXEC master.dbo.sp_serveroption @server=N'LOCALHOST', @optname=N'rpc out', @optvalue=N'true'

2.将timeout修改为5秒

exec sp_configure'remote query timeout', 5
reconfigure

3.执行模拟查询超时

DECLARE @returnCode int = 0
DECLARE @sql nvarchar(max) = 'WAITFOR DELAY ''00:00:06''; exec sp_who2'
EXEC @returnCode = [localhost].master.dbo.sp_executesql @sql

注意:消息对话框显示一条警告消息来说明查询超时。但未返回任何结果，并且也没有引发错误。

就是这么个错误.在实际使用中一定要小心.

下面是做了一个补救措施.就是把错误报出来.抓错误,就是用try…catch啦.

BEGIN TRY
        DECLARE @returnCode int = 0
        DECLARE @linkedServer sysname = 'localhost'
        DECLARE @databaseName sysname = 'master'
        DECLARE @procErrorMsg nvarchar(255) = N'远程存储过程 %s 在数据库 %s 使用链接服务器 %s 失败.'
        DECLARE @procName sysname
        DECLARE @sql nvarchar(max)

        SET @procName = 'sp_who'
        SET @sql = 'WAITFOR DELAY ''00:00:06''; exec ' + @procName
        EXEC @returnCode = [localhost].master.dbo.sp_executesql @sql
        IF @returnCode IS NULL
        BEGIN
                RAISERROR (@procErrorMsg, 16, 1, @procName, @databaseName, @linkedServer)
        END

        SET @procName = 'sp_who2'
        SET @sql = 'WAITFOR DELAY ''00:00:06''; exec ' + @procName
        EXEC @returnCode = [localhost].master.dbo.sp_executesql @sql
        IF @returnCode IS NULL
        BEGIN
                RAISERROR (@procErrorMsg, 16, 1, @procName, @databaseName, @linkedServer)
        END
END TRY
BEGIN CATCH
        DECLARE @errorMessage nvarchar(max)
        DECLARE @errorSeverity tinyint
        DECLARE @errorState tinyint

        SELECT @errorMessage = ERROR_MESSAGE(), @errorSeverity = ERROR_SEVERITY(), @errorState = ERROR_STATE()
        RAISERROR (@errorMessage, @errorSeverity, @errorState)
END CATCH 

测试了一下,在最新的版本里面2016 SP1 13.0.4001中这个问题还是存在.