中断控制器

在ARM中CPU有七种工作模式:

这里写图片描述

什么叫做工作模式?
每一种工作模式都有哪些东西?
每一种工作模式下面都有一些不同的寄存器、不同的权限、不同的触发条件;

不同的寄存器,如图:
这里写图片描述

可以看出,不同工作模式使用的寄存器是不一样的。比如同是一条指令: mov R8 #1;
在不同的模式下会对应不同的寄存器,这样作的好处是:当从一种模式切换到另外一种模式的时候,如果那一种模式有自己独有的寄存器的话,那么原来(先前)的那种模式的寄存器就不需要保存,如果要返回到先前那一种模式,自动切换到先前那种模式对应的寄存器去。

比如,现在系统正处于系统/用户模式,突然发生了某件事切换到快中断模式;这时候首先需要保存现场,所谓的现场就是上一个模式对应的那些寄存器;因为在快中断模式下有自己的r8_frq-r14_frq寄存器,那么只需要保存r0-r7;当在快中断模式下做完事情以后,需要切换到系统/用户模式下面,只需要把原来的r0-r7恢复过去就是了,这就省去了一些寄存器的保存和恢复。

不同的权限:
当我们的系统跑起来的时候,用户模式不能访问某些寄存器、不能访问某些地址。内核运行在管理模式下面,可以访问全部,当然这些需要配合MMU来实现;

触发条件:
1,上电后,就位于管理模式
2,发生中断的时候,就会进入中断模式(IRQ)

这里写图片描述

异常:

在说异常之前先说一下中断,为什么要有中断?
以一个人为例,如图:
这里写图片描述

同理程序想知道某个按键是否被按下了?不断的查询、中断;

中断是一种异常,比如按键中断、串口中断;

发生了异常之后,会有哪些事情发生?
1,CPU会强制进入异常模式,比如强制进入中断模式、取指异常模式。所谓进入这个模式就是切换那些寄存器;
2,PC指针会等于异常入口。所谓的异常入口,就是一些固定的地址。

这里写图片描述

接下来看一下程序,先看一下head.S文件,代码如下:

@******************************************************************************
@ File:head.S
@ 功能:初始化,设置中断模式、管理模式的栈,设置好中断处理函数
@******************************************************************************       

.extern     main
.text 
.global _start 
_start:
@******************************************************************************       
@ 异常向量,本程序中,除Reset和HandleIRQ外,其它异常都没有使用
@******************************************************************************       
    b   Reset

@ 0x04: 未定义指令中止模式的向量地址
HandleUndef:
    b   HandleUndef 

@ 0x08: 管理模式的向量地址,通过SWI指令进入此模式
HandleSWI:
    b   HandleSWI

@ 0x0c: 指令预取终止导致的异常的向量地址
HandlePrefetchAbort:
    b   HandlePrefetchAbort

@ 0x10: 数据访问终止导致的异常的向量地址
HandleDataAbort:
    b   HandleDataAbort

@ 0x14: 保留
HandleNotUsed:
    b   HandleNotUsed

@ 0x18: 中断模式的向量地址
    b   HandleIRQ

@ 0x1c: 快中断模式的向量地址
HandleFIQ:
    b   HandleFIQ

Reset:                  
    ldr sp, =4096           @ 设置栈指针,以下都是C函数,调用前需要设好栈
    bl  disable_watch_dog   @ 关闭WATCHDOG,否则CPU会不断重启

    msr cpsr_c, #0xd2       @ 进入中断模式
    ldr sp, =3072           @ 设置中断模式栈指针

    msr cpsr_c, #0xd3       @ 进入管理模式
    ldr sp, =4096           @ 设置管理模式栈指针,
                            @ 其实复位之后,CPU就处于管理模式,
                            @ 前面的“ldr sp, =4096”完成同样的功能,此句可省略

    bl  init_led            @ 初始化LED的GPIO管脚
    bl  init_irq            @ 调用中断初始化函数,在init.c中
    msr cpsr_c, #0x53       @ 设置I-bit=0,开IRQ中断

    ldr lr, =halt_loop      @ 设置返回地址
    ldr pc, =main           @ 调用main函数
halt_loop:
    b   halt_loop

HandleIRQ:
    sub lr, lr, #4                  @ 计算返回地址
    stmdb   sp!,    { r0-r12,lr }   @ 保存使用到的寄存器
                                    @ 注意,此时的sp是中断模式的sp
                                    @ 初始值是上面设置的3072

    ldr lr, =int_return             @ 设置调用ISR即EINT_Handle函数后的返回地址  
    ldr pc, =EINT_Handle            @ 调用中断服务函数,在interrupt.c中
int_return:
    ldmia   sp!,    { r0-r12,pc }^  @ 中断返回, ^表示将spsr的值复制到cpsr

比如代码中的第一条指令b Reset 表示复位异常,它的入口地址为0;

又比如:

@ 0x04: 未定义指令中止模式的向量地址
HandleUndef:
    b   HandleUndef 

当发生了未定义指令异常,程序就会跳转0x40处执行;至于在0x40要做什么事,这需要由程序来决定,CPU只负责跳转过去;

如果我们想用中断的话,我们应该怎么做?
中断谁(被中断程序)?去恢复谁?
1,中断发生后,得保存别人的状态;当发生中断后,CPU会跳转到某个地址去执行,在这个地址上,我们保存别人的状态;如果有很多中断,哪些中断要发生,我们先要使能中断,在使能之前,可能需要先初始化;中断发生后,CPU自动切换到中断模式,在中断的入口地址上,我们在程序里面要保存别人的状态;

2,中断处理:对于不同的中断源,会有不同的处理方法,因此我们需要先分辨中断源,对于不同的中断源我们要分别处理;处理完成以后,需要一些清理工作;

3,恢复别人的状态,让别人的程序继续运行;

这里写图片描述

按键中断:
第一,肯定 会有一个寄存来使能/禁止这个中断;
第二,肯定会有一个像状态一样的寄存器来分辨中断源;
第三,对按钮来说,当按下想中断,松开也想中断,显然对这些寄存器本身还有一些设置,比如高电平触发还是低电平触发?上升沿触发还是下降沿触发;
第四,引脚设置。一个引脚可以设置为输出、输入、中断;
第五,如果有很多按键同时按下,由谁中断?优先级寄存器

这里写图片描述

中断控制器:
这里写图片描述

从上图可知2440的中断大概会涉及到七个寄存器

接下来看代码;先看一下makefile文件:

objs := head.o init.o interrupt.o main.o

int.bin: $(objs)
    arm-linux-ld -Ttext 0x00000000 -o int_elf $^
    arm-linux-objcopy -O binary -S int_elf $@
    arm-linux-objdump -D -m arm int_elf > int.dis

%.o:%.c
    arm-linux-gcc -Wall -O2 -c -o $@ $<

%.o:%.S
    arm-linux-gcc -Wall -O2 -c -o $@ $<

clean:
    rm -f int.bin int_elf int.dis *.o       

makefile文件并没有什么特别,接着看一下head.S文件,代码如下:

@******************************************************************************
@ File:head.S
@ 功能:初始化,设置中断模式、管理模式的栈,设置好中断处理函数
@******************************************************************************       

.extern     main
.text 
.global _start 
_start:
@******************************************************************************       
@ 异常向量,本程序中,除Reset和HandleIRQ外,其它异常都没有使用
@******************************************************************************       
    b   Reset

@ 0x04: 未定义指令中止模式的向量地址
HandleUndef:
    b   HandleUndef 

@ 0x08: 管理模式的向量地址,通过SWI指令进入此模式
HandleSWI:
    b   HandleSWI

@ 0x0c: 指令预取终止导致的异常的向量地址
HandlePrefetchAbort:
    b   HandlePrefetchAbort

@ 0x10: 数据访问终止导致的异常的向量地址
HandleDataAbort:
    b   HandleDataAbort

@ 0x14: 保留
HandleNotUsed:
    b   HandleNotUsed

@ 0x18: 中断模式的向量地址
    b   HandleIRQ

@ 0x1c: 快中断模式的向量地址
HandleFIQ:
    b   HandleFIQ

Reset:                  
    ldr sp, =4096           @ 设置栈指针,以下都是C函数,调用前需要设好栈
    bl  disable_watch_dog   @ 关闭WATCHDOG,否则CPU会不断重启

    msr cpsr_c, #0xd2       @ 进入中断模式
    ldr sp, =3072           @ 设置中断模式栈指针

    msr cpsr_c, #0xd3       @ 进入管理模式
    ldr sp, =4096           @ 设置管理模式栈指针,
                            @ 其实复位之后,CPU就处于管理模式,
                            @ 前面的“ldr sp, =4096”完成同样的功能,此句可省略

    bl  init_led            @ 初始化LED的GPIO管脚
    bl  init_irq            @ 调用中断初始化函数,在init.c中
    msr cpsr_c, #0x53       @ 设置I-bit=0,开IRQ中断

    ldr lr, =halt_loop      @ 设置返回地址
    ldr pc, =main           @ 调用main函数
halt_loop:
    b   halt_loop

HandleIRQ:
    sub lr, lr, #4                  @ 计算返回地址
    stmdb   sp!,    { r0-r12,lr }   @ 保存使用到的寄存器
                                    @ 注意,此时的sp是中断模式的sp
                                    @ 初始值是上面设置的3072

    ldr lr, =int_return             @ 设置调用ISR即EINT_Handle函数后的返回地址  
    ldr pc, =EINT_Handle            @ 调用中断服务函数,在interrupt.c中
int_return:
    ldmia   sp!,    { r0-r12,pc }^  @ 中断返回, ^表示将spsr的值复制到cpsr

其中“ b Reset”就表示中断向量或异常向量
一上电的时候,系统就会跳到0地址,即复位;
注意异常向量只有4个字节,通常在这个4字节里面只是一个跳转指令,跳转其他地方去处理。

接下来中断的初始化,init.c代码中下:

/*
 * init.c: 进行一些初始化
 */ 

#include "s3c24xx.h"

/*
 * LED1,LED2,LED4对应GPF4、GPF5、GPF6
 */
#define GPF4_out    (1<<(4*2))
#define GPF5_out    (1<<(5*2))
#define GPF6_out    (1<<(6*2))

#define GPF4_msk    (3<<(4*2))
#define GPF5_msk    (3<<(5*2))
#define GPF6_msk    (3<<(6*2))

/*
 * S2,S3,S4对应GPF0、GPF2、GPG3
 */
#define GPF0_eint     (0x2<<(0*2))
#define GPF2_eint     (0x2<<(2*2))
#define GPG3_eint     (0x2<<(3*2))

#define GPF0_msk    (3<<(0*2))
#define GPF2_msk    (3<<(2*2))
#define GPG3_msk    (3<<(3*2))

/*
 * 关闭WATCHDOG,否则CPU会不断重启
 */
void disable_watch_dog(void)
{
    WTCON = 0;  // 关闭WATCHDOG很简单,往这个寄存器写0即可
}

void init_led(void)
{
    // LED1,LED2,LED4对应的3根引脚设为输出
    GPFCON &= ~(GPF4_msk | GPF5_msk | GPF6_msk);
    GPFCON |= GPF4_out | GPF5_out | GPF6_out;
}

/*
 * 初始化GPIO引脚为外部中断
 * GPIO引脚用作外部中断时,默认为低电平触发、IRQ方式(不用设置INTMOD)
 */ 
void init_irq( )
{
    // S2,S3对应的2根引脚设为中断引脚 EINT0,ENT2
    GPFCON &= ~(GPF0_msk | GPF2_msk);
    GPFCON |= GPF0_eint | GPF2_eint;

    // S4对应的引脚设为中断引脚EINT11
    GPGCON &= ~GPG3_msk;
    GPGCON |= GPG3_eint;

    // 对于EINT11,需要在EINTMASK寄存器中使能它
    EINTMASK &= ~(1<<11);

    /*
     * 设定优先级:
     * ARB_SEL0 = 00b, ARB_MODE0 = 0: REQ1 > REQ3,即EINT0 > EINT2
     * 仲裁器1、6无需设置
     * 最终:
     * EINT0 > EINT2 > EINT11即K2 > K3 > K4
     */
    PRIORITY = (PRIORITY & ((~0x01) | (0x3<<7))) | (0x0 << 7) ;

    // EINT0、EINT2、EINT8_23使能
    INTMSK   &= (~(1<<0)) & (~(1<<2)) & (~(1<<5));
}




程序的目的是当有按钮按下的时候使用中断的方式点亮LED;首先把三个管脚设置为中断引脚:

    // S2,S3对应的2根引脚设为中断引脚 EINT0,ENT2
    GPFCON &= ~(GPF0_msk | GPF2_msk);
    GPFCON |= GPF0_eint | GPF2_eint;

    // S4对应的引脚设为中断引脚EINT11
    GPGCON &= ~GPG3_msk;
    GPGCON |= GPG3_eint;

设置为中断引脚之后,应该设置与中断相关的初始化;使能外部中断寄存器:

    // 对于EINT11,需要在EINTMASK寄存器中使能它
    EINTMASK &= ~(1<<11);

    // EINT0、EINT2、EINT8_23使能
    INTMSK   &= (~(1<<0)) & (~(1<<2)) & (~(1<<5));

中断的软、硬处理过种:

head.s 中的汇编的处理HandleIRQ函数代码如下:

HandleIRQ:
    sub lr, lr, #4                  @ 计算返回地址
    stmdb   sp!,    { r0-r12,lr }   @ 保存使用到的寄存器
                                    @ 注意,此时的sp是中断模式的sp
                                    @ 初始值是上面设置的3072

    ldr lr, =int_return             @ 设置调用ISR即EINT_Handle函数后的返回地址  
    ldr pc, =EINT_Handle            @ 调用中断服务函数,在interrupt.cint_return:
    ldmia   sp!,    { r0-r12,pc }^  @ 中断返回, ^表示将spsr的值复制到cpsr

interrupt.c中调用中断处理函数,interrupt.c代码如下:

#include "s3c24xx.h"

void EINT_Handle()
{
    unsigned long oft = INTOFFSET;
    unsigned long val;

    switch( oft )
    {
        // S2被按下
        case 0: 
        {   
            GPFDAT |= (0x7<<4);   // 所有LED熄灭
            GPFDAT &= ~(1<<4);      // LED1点亮
            break;
        }

        // S3被按下
        case 2:
        {   
            GPFDAT |= (0x7<<4);   // 所有LED熄灭
            GPFDAT &= ~(1<<5);      // LED2点亮
            break;
        }

        // K4被按下
        case 5:
        {   
            GPFDAT |= (0x7<<4);   // 所有LED熄灭
            GPFDAT &= ~(1<<6);      // LED4点亮                
            break;
        }

        default:
            break;
    }

    //清中断
    if( oft == 5 ) 
        EINTPEND = (1<<11);   // EINT8_23合用IRQ5
    SRCPND = 1<<oft;
    INTPND = 1<<oft;
}

当中断发生以后,通过unsigned long oft = INTOFFSET;读取寄存器,然后判断…..;
然后清中断,需要阅读2440的芯片手册;

SP:表示中断有关的特有的寄存器。

中断的处理流程:

这里写图片描述

中断处理完成以后,(head.S)恢复现场:

int_return:
    ldmia   sp!,    { r0-r12,pc }^  @ 中断返回, ^表示将spsr的值复制到cpsr
评论 2
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值