Windows 的CMD命令更改IP地址

1. 在工控行业中，与设备进行网络对接时，经常需要调整电脑的IP地址以适应不同的网络环境。为了简化配置过程，我们可以利用批处理文件（.bat）的方式，使用户只需运行一个文件，输入相应的网络名称和IP地址，就能自动完成与设备网络对接的配置。以下是这一流程的详细解释：
2. 创建批处理文件：
   创建一个批处理文件，可以使用文本编辑器（如TXT）输入以下内容：

@echo off
setlocal enabledelayedexpansion
chcp 65001 > nul 2>&1

echo 获取网络适配器列表...
netsh interface ipv4 show config
echo ---------------------------------------

echo 请输入要设置的网络适配器名称:
set /p "adapterName=适配器名称:"
set /p choice=是要设置静态IP吗？(Y/N):

if /i "%choice%"=="Y" (

    echo 请输入IP地址
    set /p "ipAddress=IP地址:"

    echo 适配器名称：!adapterName!
    echo IP地址：!ipAddress!

    rem 设置静态IP地址
    netsh interface ipv4 set address name="!adapterName!" static !ipAddress! 255.255.255.0

    echo 确认设置静态IP完成
    timeout /t 5 /nobreak
    netsh interface ipv4 show config
    pause
) else if /i "%choice%"=="N" (
    echo 自动配置IP地址...
    netsh interface ipv4 set address name="!adapterName!" source=dhcp

    echo 检测自动配置IP地址完成
    timeout /t 15 /nobreak
    netsh interface ipv4 show config
    pause
)
endlocal

1. 将文件TXT后缀“.TXT”改为“.bat”，另存为“CMD切换IP.bat”文件后。
2. 双击运行，即可进入IP配置流程。
3. 首先扫描网络接口，获取网络适配器列表…。
4. 复制对应的接口名称，不需要双引号“”，回车。
5. “Y”配置静态IP地址，“N”配置自动获取IP地址， 子网掩码默认“255.255.255.0”，该程序中网关没有填写。
6. 选择“Y”进行静态IP配置，输入需要的IP地址，回车。
7. 配置完成后等待数秒，网络配置完成，该程序的5秒和15秒是测试时自身电脑的连接速度可做参考。
8. 读秒结束后会再一次扫描 获取网络适配器列表…确认IP更换完成。