文章目录
ARM指令
数据处理指令
- 包括：
算术指令： ADD ADC SUB SBC RSB RSC
逻辑指令： AND ORR EOR BIC
比较指令： CMP CMN TST TEQ
数据搬移： MOV MVN
上述指令只能对寄存器操作，不能针对存储器。 - 语法：
<操作>{}{S} Rd, Rn, Operand2
只有比较指令影响标志位 -不指定Rd
数据搬移（MOV指令）不指定Rn
第二个操作数通过桶型移位器送到ALU中。
数据处理指令机器码格式
| 机器码 | 说明 |
|---|---|
| mov r1,r2,lsl #2 | 指令机器码 0xe1a01102 |
| Cond | 指令的条件码。 |
| Opcode | 指令操作码。 |
| S | 操作是否影响cpsr,S=0不影响，S=1影响。 |
| Rn | 包含第一个操作数的寄存器编码。 |
| Rd | 目标寄存器编码。 |
| Operand2 | 第2操作数、Rm |
| I | 用于区别Operand2是立即数（I=1），还是寄存器移位（I=0） |
| Shift amount | 移位数 |
| Shift | 移位方式 |
数据处理指令
加法指令 ADD R1，R2，R3 R1=R2+R3
带进位加法 ADC R1，R2，R3 R1=R2+R3+C
减法指令 SUB R1，R2，R3 R1=R2-R3
逆向减法 RSB R1，R2，R3 R1=R3-R2
带借位减法 SBC R1，R2，R3 R1=R2-R3-!C
带借位逆减法 RSC R1，R2，R3 R1=R3-R2-!C
逻辑与指令 AND R0，R0，#0X0F
逻辑或指令 ORR R0，R0，#0X0F
逻辑异或 EOR R0，R0，#0X0F
位清除 BIC R0，R0，#9
比较指令 CMP R1，#10 cpsr = R1-10
反值比较指令 CMN R1，R2 cpsr = R1+R2
位测试指令 TST R1，#3 cpsr = R1 AND 3
相等测试 TEQ R1，R2 cpsr = R1 EOR R2
数据传输指令 MOV R1，R2 R1=R2
取反传送指令 MVN R1，R2 R1=~R2
立即数
- 有任何一条ARM 指令可包括一个32 bit的立即数
所有的ARM指令都是32 bits固定长度 - 数据处理指令格式中，第二个操作数有12位
- 4 bit 移位值 (0-15)乘于2，得到一个范围在0-30，步长为 2的移位值。
- 记住一条准则： “最后8位一定要移动偶数位”.
条件码
指令是如何存储的，如何被解析的？
指令机器码
示例
搬移指令
mov r0, #3 @r0=3
mov r1, r0 @r1=r0
mov r0, r1, LSL#2 @r0 = r1 << 2
mov r0, r1, LSR#1 @r0 = r1>>1
mrs r2, cpsr
msr cpsr,r3
条件执行
if (a==0) x=0;
if (a>0) x=x+3;
cmp r0,#0 ; R0与R1比较，做R0-R1的操作
moveq r1,#0 ; 若r0 =0,则r1=0
addgt r1,r1, #1; 若r0>0,则r1= r1 + 1
逻辑指令
and r0,r1,#0xFF // r0 = r1&0xFF
orr r3,r0,#0x0F // r3 = r0|0x0F
bic r0,r0,#0x03 // 清除r0中的0号位和1号位
tst r0,#0x20 //测试第6位是否为0 ，为0则Z标志置1
cmp r1,r0 //将R1与R0相减做比较，并根据结果设置CPSR的标志位
案例1：使能中断和快速中断？
mrs r0,cpsr
bic r0,r0,#0xc0 @清除中断禁止位[7:6]
msr cpsr ,r0
案例2：判断当前工作状态是否是ARM状态，是则切换到user 工作模式？
mrs r0,cpsr
tst r0,#0x20
andeq r0,r0,#0xFFFFFFE0 @将低五位模式位清零
orreq r0,r0,#0x10 @将低五位模式位设置成10000
msreq cpsr,r0
算术指令
add r0,r1,r2 //r0=r1+r2
sub r0,r1,#3 //r0= r1 - 3
sub r0,r1,r2,LSL#1 //先把r2左移一位
mul r1,r2,r3 //r1=r2*r3
跳转指令
b main //跳转到标号为main地代码处
bl func //保存下一条要执行的指令的位置到 LR寄存器,跳转函数func
//当跳转代码结束后,用MOV PC,LR指令跳回来
beq addr //当CPSR寄存器中的Z条件码置位时，跳转到该地址处
bne addr //当不等时，跳转到地址addr
案例3：汇编实现下面功能
void main(void)
{
int ret=0;
func1(2);
while(1) {};
}
func1(int a)
{
if(a==2)
return func2(a);
else
return func3(a);
}
func2(int a)
{
return a+3;
}
func3(int a)
{
return a-1;
}
.text
main:
mov r5,#0
mov r0,#3
bl func1
main_end:
b main_end
func1:
mov r8,lr @备份lr寄存器中的地址
cmp r0,#2
bleq func2
blne func3
mov pc,r8
func1_end:
func2:
add r0,r0,#3
mov pc,lr
func2_end:
func3:
sub r0,r0,#1
mov pc,lr
func3_end:
.end
案例4:汇编实现求最大公约数?(如9 15 值是3)
int GCD(int a,int b)
{
while(1)
{
if(a==b)
break;
if(a>b){
a=a-b;
}else{
b=b-a;
}
}
return a;
}
.text
main:
mov r0,#9
mov r1,#15
bl gcd
main_end:
b main_end
gcd:
loop_gcd:
cmp r0,r1
beq gcd_end
subgt r0,r0,r1
sublt r1,r1,r0
b loop_gcd
gcd_end:
mov pc,lr
案例5:实现 延时1秒函数
@delay fos 1 second
delay1s:
ldr r4,=0x24f000
loop_delay1s:
sub r4,r4,#1
cmp r4,#0
bne loop_delay1s
delay1s_end:
mov pc,lr
Load/Store 指令
-
注：load/store架构规定，存储器之间不能直接拷贝，需通过寄存器做中转
ldr r0,[r1] (load) //r0=*r1 r1里存放的是地址，把该地址里存放的内容读入到r0中 //LDRB（byte） LDRH（half word） ldr r0，[r1，#8] //r0=*（r1+8) 存储器地址为r1+8的字数据读入寄存器0。 ldr pc,_irq // pc = *(_irq) 将标号中的内容放入pc中 str r0,[r1] (store) // *r1 = r0 将寄存器r0中值写入到存储器地址为r1的空间中 str r0,[r1],#4 // r0=*r1, r1=r1+4 将r0 中的字数据写入以r1为地址的内存中,并将新地址r1+4 写入r1 str r0,[r1,#4] //*(r1+4)=r0 将r0 中的字数据写入以r1+4 为地址的内存中
案例6:
代码段只读，数据段可读可写
.text @代码段
main:
ldr r5,=buf @伪指令
ldr r0,[r5] @load指令，将r5中的地址所对应的内容（字），放入r0中
ldrb r1,[r5] @load指令，将r5中的地址所对应的内容（字节），放入r0中
ldrh r2,[r5],#4 @load指令，将r5中的地址所对应的内容（半字），放入r0中。之后将r5中的地址向后偏移4
ldr r3,[r5],#-4 @load指令，将r5中的地址所对应的内容（字），放入r0中。之后将r5中的地址向前偏移4
ldr r6,=dest_buf1
ldr r7,=dest_buf2
ldr r8,=dest_buf3
str r0,[r6]
str r1,[r7]
strb r2,[r8]
main_end:
b main_end
.data @数据段
buf: .byte 0x01,0x02,0x03,0x04 @相当于C语言中的数组，char buf[]={0x01,0x02,0x03,0x04}
dest_buf1: .space 4 @相当于C语言中的数组，char buf[4]
dest_buf2: .space 4 @相当于C语言中的数组，char buf[4]
dest_buf3: .space 8 @相当于C语言中的数组，char buf[8]
.end @程序结束
前索引/后索引寻址
案例7:
main()
{
int i=0;
const char buf[]={1,2,3};
char destBuf[8];
for(i=0,i<3,i++)
{
destBuf[i] = buf[i];
}
}
.text @代码段
main:
ldr r6,=buf
ldr r7,=dest_buf
mov r5,#0
loop:
cmp r5,#3
beq main_end
ldrb r0,[r6],#1
strb r0,[r7],#1
add r5,r5,#1
b loop
main_end:
b main_end
buf: .byte 1,2,3
.data @数据段
dest_buf: .space 3
.end @代码结束
GNU 汇编伪指令
.text 将定义符开始的代码编译到代码段
.data 将定义符开始的代码编译到数据段
.end 文件结束
.equ GPG3CON, 0XE03001C0 定义宏（即用GPG3CON代替 0XE03001C0）
.byte 定义变量 1字节
.byte 0x11,'a',0 定义字节数组
.word 定义word变量 (4字节 32位机)
.word 0x12344578,0x33445566
.string 定义字符串 .string "abcd\0"
ldr r0,=0xE0028008 载入大常数0xE0028008 到r0中
.global _start 声明_start 为全局符号
案例8
.text
main:
ldr r5,=srcBuf
ldr r6,=destBuf
loop:
ldrb r4,[r5]
cmp r4,#0
beq main_end
ldrb r0,[r5],#1
strb r0,[r6],#1
b loop
main_end:
b main_end
srcBuf:
.string "abcdefg\0"
.data
destBuf:
.space 8
.end
批量操作指令
批量操作指令 (ia-Increment After ib-Increment Before da-Dec After db-Dec Before)
ldmia r0!, {r3 - r10} //r0里地址指向的内容批量，load 到r3~r10寄存器中， r0里地址会自动加4
stmia r0!, {r3 - r10} //把r3~r10寄存器中内容，store 到r0里地址执行空间中，r0里地址会自动加4
- LDM / STM指令允许一次传送1到16个寄存器到/从存储器中。
寄存器传送顺序是固定的，不能被改变
最小数字的寄存器总是被对应到存储器的最低地址上。
LDMIA r10!,{r0,r1,r4} - 基址寄存器指定存储器访问开始的地址
- 块传送指令针对下列情况很有效：
从存储器中搬运一块数据
保存或恢复堆栈中的内容
如果是慢速存储器，会影响中断响应时间
案例9
实现块数据批量拷贝
r12指向源数据起始地址
r14指向源数据尾地址
r13指向目的数据起始地址
.text
ldr r12,=srcBuf
ldr r13,=dstBuf
ldmia r12!,{r0 - r11}
stmia r13!,{r0 - r11}
.data
srcBuf:
.string "abdfasdf13535dfksjdlfkjlksldkjflkl\0"
srcBuf_end:
dstBuf:
.space 12*4
.end
堆栈操作指令
语法：
<LDM|STM>{<cond>}<addressing_mode> Rb{!}, <寄存器 list>
4 种寻址操作:
- LDMIA / STMIA Increment After （先操作，后增加）
- LDMIB / STMIB Increment Before （先增加，后操作）
- LDMDA / STMDA Decrement After （先操作，后递减）
- LDMDB / STMDB Decrement Before （先递减，后操作）
-
可选项“ ! ”将导致LDM / STM 指令去自动更新基址寄存器
-
后缀为IA, IB时，加上4 乘以 用于传送的寄存器的数目的值
-
后缀为DA, DB时，减去4乘以用于传送的寄存器的数目的值
示例: ; r12指向源数据起始地址 ; r14指向源数据尾地址 ; r13指向目的数据起始地址 loop LDMIA r12!, {r0-r11} STMIA r13!, {r0-r11} CMP r12, r14 BNE loop
stmfd sp!,{r0-r12,lr} 将寄存器r0~r12 lr中的值存入栈中
常用于中断保护现场,! 表示会自动偏移
ldmfd sp!,{r0-r12,pc}^ 将栈中值逐个弹出到寄存器r0~r12 pc中
常用于中恢复断现场，^表示会恢复spsr到cpsr
软中断指令
-
产生一个异常陷阱，跳转到SWI 硬件向量。
-
SWI 处理程序可以检测SWI号，从而决定采取何种操作。
-
通过SWI机制，运行在用户模式下的应用程序，可请求操作系统执行一系列特权操作。
语法： SWI{<cond>} <SWI number>swi 0x02 产生软中断， 软中断号为2
扫一扫
2642
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
