通过请求跨系统COPY程序、配置

最新推荐文章于 2024-03-25 09:49:24 发布
最新推荐文章于 2024-03-25 09:49:24 发布
阅读量494 收藏 3
点赞数 1
分类专栏： ABAP 文章标签： sap abap
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/a86632678/article/details/129885298
版权

转自链接: link
本文演示如何把SAP内的程序等复制到完全无关的另一套系统。

1、在源系统把要复制到对象放到传输请求中。

以程序为例：
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述

上传请求后，请求会出现在STMS中，需要到STMS中导入请求。

在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
使用相同的方法，可以把数据字典内容、SCREEN、Smartforms，甚至表内容，后台配置等等方便的从一个系统复制到另外一个系统了。

附上代码：


TYPE-POOLS: trwbo, stms.
TABLES: sscrfields.
DATA: retcode ,
      len       TYPE i,
      tra_dir   TYPE text255,
      request   LIKE e070-trkorr,
      system    LIKE tmscsys-sysnam,
      req_infos TYPE stms_wbo_requests WITH HEADER LINE.
DATA: filename  LIKE sdbah-actid,
      extension LIKE sdbad-funct.

SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME TITLE t1.
PARAMETERS: p_down RADIOBUTTON GROUP typ USER-COMMAND sele DEFAULT 'X'.
PARAMETERS: p_upld RADIOBUTTON GROUP typ.
SELECTION-SCREEN END OF BLOCK b1.

SELECTION-SCREEN BEGIN OF BLOCK b2 WITH FRAME TITLE t2.
PARAMETERS: p_file TYPE char255 LOWER CASE MODIF ID m2,
            p_clnt TYPE mandt DEFAULT sy-mandt MATCHCODE OBJECT h_t000 MODIF ID m2,
            p_view AS CHECKBOX DEFAULT 'X' MODIF ID m2.
SELECTION-SCREEN END OF BLOCK b2.

SELECTION-SCREEN BEGIN OF BLOCK b3 WITH FRAME TITLE t3.
PARAMETERS:p_reqnum TYPE trkorr MODIF ID m3,
           p_folder TYPE char128 DEFAULT 'C:\' LOWER CASE MODIF ID m3.
SELECTION-SCREEN END OF BLOCK b3.

INITIALIZATION.
  system = sy-sysid.
  CALL FUNCTION 'RSPO_R_SAPGPARAM'
    EXPORTING
      name   = 'DIR_TRANS'
    IMPORTING
      value  = tra_dir
    EXCEPTIONS
      error  = 1
      OTHERS = 0.
  IF tra_dir IS INITIAL.
    MESSAGE e000(oo) WITH 'DIR_TRANS目录未找到'.
  ENDIF.

AT SELECTION-SCREEN OUTPUT.
  t1 = '选择功能'.
  t2 = '上传参数'.
  t3 = '下载参数'.
  %_p_down_%_app_%-text = '下载请求到本机'.
  %_p_upld_%_app_%-text = '上传请求'.
  %_p_file_%_app_%-text = '文件'.
  %_p_clnt_%_app_%-text = '上传到Client'.
  %_p_view_%_app_%-text = '传输前查看请求内容'.
  %_p_reqnum_%_app_%-text = '请求号'.
  %_p_folder_%_app_%-text = '下载到文件夹'.

  LOOP AT SCREEN.
    CASE screen-group1.
      WHEN 'M2'.
        IF p_down = 'X'.
          screen-active = '0'.
        ELSE.
          screen-active = '1'.
        ENDIF.
      WHEN 'M3'.
        IF p_down = 'X'.
          screen-active = '1'.
        ELSE.
          screen-active = '0'.
        ENDIF.
    ENDCASE.
    MODIFY SCREEN.
  ENDLOOP.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_reqnum.
  DATA: request_header TYPE trwbo_request_header,
        is_selection   TYPE trwbo_selection.
  is_selection-reqstatus = 'R'.
  CALL FUNCTION 'TR_PRESENT_REQUESTS_SEL_POPUP'
    EXPORTING
      iv_organizer_type   = ''
      is_selection        = is_selection
    IMPORTING
      es_selected_request = request_header.
  p_reqnum = request_header-trkorr.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_folder.
  DATA: folder  TYPE string.
  CALL METHOD cl_gui_frontend_services=>directory_browse
    CHANGING
      selected_folder = folder
    EXCEPTIONS
      cntl_error      = 1
      error_no_gui    = 2
      OTHERS          = 3.
  p_folder = folder.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.
  CALL FUNCTION 'WS_FILENAME_GET'
    EXPORTING
      def_path         = 'C:\'
      mask             = ',请求控制文件(K*.*),K*.*,ALL File(*.*),*.*.'
      mode             = 'O'
    IMPORTING
      filename         = p_file
    EXCEPTIONS
      inv_winsys       = 1
      no_batch         = 2
      selection_cancel = 3
      selection_error  = 4
      OTHERS           = 5.

START-OF-SELECTION.
  PERFORM check_input .
  CASE 'X'.
    WHEN p_down.
      PERFORM downrequest .
    WHEN p_upld.
      PERFORM read_req.
      PERFORM uprequest.
      IF p_view = 'X'.
        PERFORM viewrequest.
      ELSE.
        PERFORM import_request.
      ENDIF.
  ENDCASE.

*&--------------------------------------------------------------------*
*&      Form  check_input
*&--------------------------------------------------------------------*
FORM check_input.
  CALL FUNCTION 'TR_AUTHORITY_CHECK_ADMIN'
    EXPORTING
      iv_adminfunction = 'TADD'
    EXCEPTIONS
      e_no_authority   = 1
      e_invalid_user   = 2
      OTHERS           = 3.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE 'E' NUMBER sy-msgno
      WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

  IF p_down = 'X'.
    IF p_reqnum = '' OR p_folder = ''.
      MESSAGE s000(oo) WITH '必须输入请求号和本机文件夹'.
      STOP.
    ENDIF.
  ELSE.
    IF p_clnt = '' OR p_file = '' .
      MESSAGE s000(oo) WITH '必须输入文件名和Client'.
      STOP.
    ELSE.
      CALL FUNCTION 'SPLIT_FILENAME'
        EXPORTING
          long_filename  = p_file
        IMPORTING
          pure_filename  = filename
          pure_extension = extension.
      CONCATENATE extension filename INTO request.
    ENDIF.
  ENDIF.
ENDFORM.

*&---------------------------------------------------------------------*
*&      Form  downrequest
*&---------------------------------------------------------------------*
FORM downrequest .
  DATA: lappfile LIKE rcgfiletr-ftappl,
        lguifile LIKE rcgfiletr-ftfront.

  len = strlen( p_folder ) - 1.
  IF p_folder+len CA '/\'.
    p_folder+len = ''.
  ENDIF.

  CONCATENATE tra_dir '/data/R ' p_reqnum+4(6) '.' p_reqnum(3) INTO lappfile.
  CONCATENATE p_folder  '\R' p_reqnum+4(6) '.' p_reqnum(3) INTO lguifile.
  PERFORM down_file USING lappfile lguifile.

  CONCATENATE tra_dir '/cofiles/K ' p_reqnum+4(6) '.' p_reqnum(3) INTO lappfile.
  CONCATENATE p_folder  '\K' p_reqnum+4(6) '.' p_reqnum(3) INTO lguifile.
  PERFORM down_file USING lappfile lguifile.

  MESSAGE s000(oo) WITH '成功下载到' lguifile.
ENDFORM.                    " downrequest

*&--------------------------------------------------------------------*
*&      Form  DOWN_FILE
*&--------------------------------------------------------------------*
FORM down_file USING applfile frontfile .
  DATA: lappfile     LIKE rcgfiletr-ftappl,
        lguifile     LIKE rcgfiletr-ftfront,
        err_flg      LIKE boole-boole,
        err_txt(100) TYPE c.

  lappfile = applfile .
  lguifile = frontfile .
  sy-cprog = 'RC1TCG3Y'.
  CALL FUNCTION 'C13Z_FILE_DOWNLOAD_BINARY'
    EXPORTING
      i_file_front_end    = lguifile
      i_file_appl         = lappfile
      i_file_overwrite    = 'X'
    IMPORTING
      e_flg_open_error    = err_flg
      e_os_message        = err_txt
    EXCEPTIONS
      fe_file_open_error  = 1
      fe_file_exists      = 2
      fe_file_write_error = 3
      ap_no_authority     = 4
      ap_file_open_error  = 5
      ap_file_empty       = 6
      OTHERS              = 7.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE 'E' NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
  IF err_flg = 'X'.
    MESSAGE e000(oo) WITH err_txt.
  ENDIF.
ENDFORM.                               " DOWN_FILE

*&--------------------------------------------------------------------*
*&      Form  read_req
*&--------------------------------------------------------------------*
FORM read_req.
  CALL FUNCTION 'TMS_MGR_READ_TRANSPORT_REQUEST'
    EXPORTING
      iv_request                 = request
      iv_target_system           = system
    IMPORTING
      et_request_infos           = req_infos[]
    EXCEPTIONS
      read_config_failed         = 1
      table_of_requests_is_empty = 2
      system_not_available       = 3
      OTHERS                     = 4.
  READ TABLE req_infos INDEX 1.
  IF req_infos-e070 IS NOT INITIAL .
    CALL FUNCTION 'POPUP_TO_CONFIRM'
      EXPORTING
        titlebar       = '确认'
        text_question  = '请求文件已存在，是否覆盖？'
        default_button = '1'
      IMPORTING
        answer         = retcode.
    IF retcode <> '1'.
      MESSAGE s000(oo) WITH '用户终止'.
      STOP.
    ENDIF.
  ENDIF.
ENDFORM.

*&---------------------------------------------------------------------*
*&      Form  UPLOADREQUEST
*&---------------------------------------------------------------------*
FORM uprequest .
  DATA: lappfile LIKE rcgfiletr-ftappl.

  CONCATENATE tra_dir '/cofiles/' filename '.' extension INTO lappfile .
  PERFORM up_file USING lappfile p_file .

  len = strlen( p_file ) - 11.
  p_file+len(1) = 'R'.
  CONCATENATE tra_dir '/data/R' filename+1 '.' extension INTO lappfile .
  PERFORM up_file USING lappfile p_file .

  CALL FUNCTION 'TMS_MGR_FORWARD_TR_REQUEST'
    EXPORTING
      iv_request      = request
      iv_target       = system
      iv_tardom       = ''
      iv_tarcli       = ''
      iv_source       = system
      iv_srcdom       = ''
      iv_import_again = 'X'
      iv_monitor      = 'X'
      iv_verbose      = ''
    EXCEPTIONS
      OTHERS          = 99.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
      WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4  .
  ENDIF.
ENDFORM.

*&--------------------------------------------------------------------*
*&      Form  UP_FILE
*&--------------------------------------------------------------------*
FORM up_file USING applfile frontfile .
  DATA: lappfile     LIKE rcgfiletr-ftappl,
        lguifile     LIKE rcgfiletr-ftfront,
        err_flg      LIKE boole-boole,
        err_txt(100) TYPE c.

  lappfile = applfile .
  lguifile = frontfile .
  sy-cprog = 'RC1TCG3Y'.
  CALL FUNCTION 'C13Z_FILE_UPLOAD_BINARY'
    EXPORTING
      i_file_front_end   = lguifile
      i_file_appl        = lappfile
      i_file_overwrite   = 'X'
    IMPORTING
      e_flg_open_error   = err_flg
      e_os_message       = err_txt
    EXCEPTIONS
      fe_file_not_exists = 1
      fe_file_read_error = 2
      ap_no_authority    = 3
      ap_file_open_error = 4
      ap_file_exists     = 5
      OTHERS             = 6.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE 'E' NUMBER sy-msgno
      WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
  IF err_flg = 'X'.
    MESSAGE e000(oo) WITH err_txt.
  ENDIF.
ENDFORM.                    "UP_FILE

*&--------------------------------------------------------------------*
*&
*&--------------------------------------------------------------------*
FORM import_request.
  DATA: it_clients TYPE  stms_clients.

  CALL FUNCTION 'TR_AUTHORITY_CHECK_ADMIN'
    EXPORTING
      iv_adminfunction = 'IMPS'
    EXCEPTIONS
      e_no_authority   = 1
      e_invalid_user   = 2
      OTHERS           = 3.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE 'E' NUMBER sy-msgno
      WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

  APPEND p_clnt TO it_clients.
  CALL FUNCTION 'TMS_UI_IMPORT_TR_REQUEST'
    EXPORTING
      iv_system             = system
      iv_request            = request
      iv_tarcli             = p_clnt
      iv_some_active        = space
      it_clients            = it_clients
    EXCEPTIONS
      cancelled_by_user     = 1
      import_request_denied = 2
      import_request_failed = 3
      OTHERS                = 4.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE 'E' NUMBER sy-msgno
      WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4  .
  ENDIF.

  CALL FUNCTION 'TMS_UIQ_IMPORT_QUEUE_DISPLAY'
    EXPORTING
      iv_system = system
    EXCEPTIONS
      OTHERS    = 99.
ENDFORM.

*&---------------------------------------------------------------------*
*&      Form  viewrequest
*&---------------------------------------------------------------------*
FORM viewrequest.
  DATA queue TYPE tmscsys.

  SELECT SINGLE * INTO queue FROM tmscsys WHERE sysnam = system.
  CALL FUNCTION 'TMS_UI_SHOW_TRANSPORT_REQUEST'
    EXPORTING
      iv_request                    = request
      iv_target_system              = ''
      is_queue                      = queue
    EXCEPTIONS
      show_transport_request_failed = 1
      OTHERS                        = 2.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
      WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4  .
  ENDIF.

  CALL FUNCTION 'POPUP_TO_CONFIRM'
    EXPORTING
      titlebar              = '确认'
      text_question         = '是否继续传输？'
      text_button_1         = '传输'
      text_button_2         = '退出，不传输'
      icon_button_1         = 'ICON_IMPORT_TRANSPORT_REQUEST'
      default_button        = '2'
      display_cancel_button = 'X'
    IMPORTING
      answer                = retcode.
  IF retcode = '1'.
    PERFORM import_request.
  ELSE.
    IF req_infos-e070 IS INITIAL.
      CALL FUNCTION 'TMS_MGR_MAINTAIN_TR_QUEUE'
        EXPORTING
          iv_command = 'DELFROMBUFFER'
          iv_system  = system
          iv_domain  = ''
          iv_request = request
          iv_tarcli  = ''
          iv_monitor = 'X'
          iv_verbose = ''
        EXCEPTIONS
          OTHERS     = 99.
    ENDIF.
  ENDIF.
ENDFORM.                    "viewrequest
a86632678
关注
  • 1
    点赞
  • 踩
  • 3
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
sap服务器之间文件复制,sap跨服务器客户端复制
weixin_31943957的博客
08-11 848
sap跨服务器客户端复制 内容精选换一换应用备份操作流程如图1所示。下载并安装客户端：进行应用备份前需要先在目标主机上下载和安装客户端，相关操作请参见下载和安装客户端。安装完成后，云备份系统会自动发现已安装客户端的主机，显示在“已安装的客户端”列表中。注册关联资源：在备份之前，需要先在对应的备份界面，注册需备份的文件集或数据库。相关操作请参见注册备份资源。创建存储库：创建用于存完成安装客户端后，云...
微信小程序ajax实现请求服务器数据，模版遍历数据
03-29
昨天下载了一个微信小程序的开发者工具，大概看了一下文档，简单的用他的方法实现了ajax请求。 微信小程序文档地址：https://mp.weixin.qq.com/wiki?t=resource/res_main&id=mp1474632113_xQVCl&token=&lang=zh_CN ...
跨系统传输请求 程序代码
Damon的 SAP BLOG
01-19 1036
内容： 当某公司有多个平行系统时，比如 多个dev ，但是部署在不同服务器。有时候需要传输请求至其它系统。 PS：传输至同系统中的不同client 用TCODE: SCC1. *&---------------------------------------------------------------------* *& Report ZTRANS_TR *&-----
SAP Client Copy
matinal 當冬夜漸暖 。公众号：matinal
08-01 556
配置client copy参数，Selected profile栏选“SAP_ALL”Source client和Source client user masters都选000。这些client是SAP的标准client，它们包含了client的一些初始数据。client 000是SAP的一个参考client，里面有所有的SAP表和一些可修改的示例记录。我在000中执行，想往新建完的client中copy，就得到上面的错误了。没有应用数据，包括主数据和运作数据，不能使用该client于实际的生产过程。
SNP Glue：SAP数据导入到其他系统的多种方式
SNP公司——中国数据转型公司
10-06 376
SAP是一款功能强大的企业资源计划（ERP）软件，许多企业依赖SAP来管理和处理其核心业务数据。然而，有时候企业需要将SAP中的数据导入到其他系统中，以实现更广泛的数据共享和集成，便于企业实现数据智能。本文将介绍几种常见的方式，帮助企业了解如何将SAP数据导入到其他系统中。选择合适的方式可以提高数据导入的效率和准确性，实现系统间的无缝集成。将SAP数据导入到其他系统中是实现数据共享和集成的重要步骤。根据具体的需求和系统架构，可以选择合适的方式进行数据导入，包括批量导出与导入、
SAP ABAP AL11导出传输请求与导入非传输系统或修改配置文件
ABAP开发程序员
11-19 4183
文章目录前言一、导入导出传输请求到其他测试系统二、使用步骤1.引入库2.读入数据总结 前言 有些时候我们需要把代码放到非传输系统去测试，全部代码再敲一遍太费时间，我们就可以利用AL11,CG3Y,CG3Z,STMS等这几个来传递整体内容 PS:AL11是个好用的T-CEDE 一、导入导出传输请求到其他测试系统 首先传输一个副本到测试机，把工作台请求的内容包含到副本中，然后把副本传输到测试机 进入AL11的参数DIR_TRANS（路径） 在这两个文件夹中下载刚才副本的对应文件，co..
SAP ABAP 跨系统拷贝表数据
刘欣的CSDN博客
02-11 1018
放这里免得忘记了： 一、在源系统放一个RFC函数ZPP_TABLE_GET来取数 FUNCTIONZPP_TABLE_GET.*"----------------------------------------------------------------------*"*"本地接口：*"IMPORTING*"VALUE(DATE)TYPESY-DATUM*"VALUE(ZZ_PLATFORM)TYPEZZ_PLATFORM*"TABLES*"...
burp-copy-as-ffuf:Burp扩展程序，用于复制请求并构建FFUF框架
05-09
复制请求并使用Burp代理进行验证Copy as FFUF skeleton, verify via Burp" 复制请求并使用Burp代理进行攻击Copy as FFUF skeleton, proxy via Burp" 也许添加一个简单的用户界面，允许配置单词列表的路径 要求 ...
Storm配置项详解.docx
11-05
Storm是一个分布式实时计算系统，允许开发者编写处理无限数据流的程序。配置项是Storm的核心组成部分，它们用于定制Storm集群的行为，以适应不同的环境和需求。以下是对文档中提及的一些主要配置项的详细解释： 1. ...
TCPCopy部署文档
09-22
在完成部署并运行tcpcopy和Intercept之后，可以通过监控网络流量、系统资源使用情况以及应用程序的日志来查看测试效果。此外，可以使用诸如tcpdump、Wireshark等网络分析工具来分析复制的流量。 ### 6. 常见错误 在...
SAP集团拷贝 client copy
09-01
本教程详细描写了SAP client 拷贝过程，按照该教程操作，完全可以成功完成集团拷贝！
华中科技大学操作系统实验与课设.zip
最新发布
04-20
在操作系统中，字符设备驱动程序负责与硬件交互，处理来自用户空间的输入输出请求，这对于理解I/O子系统至关重要。 【lab_tinyOS】 `lab_tinyOS` 可能是一个微型操作系统或操作系统模拟器的实验，让学生在更简单的...
SAP HANA System系统复制概览
Aiden_Hy的博客
01-30 454
系统复制支持0秒的RPO(recovery point object, 恢复点目标)和以分钟计量的RTO(recovery time object, 恢复时间目标)。设置系统复制实际上是使用secondary系统配置作为主系统的副本，与系统中活跃的主机的数量相同。此外它需要主系统与辅助系统之间可靠的连接。主系统中的每个服务都与辅助系统中对应的服务配对通信，但是其区别在于，辅助系统只能在Active/Active (read enable)的配置中接受查询。
SAP-如何将请求从源系统A复制到目标系统B，在没有传输路径时
weixin_46196889的博客
12-27 824
SAP-如何将请求从源系统A复制到目标系统B，在没有传输路径时 小伙伴们在经常会遇到一个问题，新copy出来的系统没有传输路径，有时用户要把在其他系统开发的程序打包放到新系统中，那么如何做到把请求放到新copy出来的系统呢？ 1.登录源系统GUI tcode：rz11 输入参数：DIR_TRANS 查看请求存放路径，一般默认就是/usr/sap/trans 2.登录源操作系统服务器进入/usr/sap/trans目录下找到 data 和 cofiles， 已释放的请求会在这两个目录下生产两个文件，例如：
SAP ABAP 复制迁移数据库表数据
matinal 當冬夜漸暖 。公众号：matinal
03-02 645
其实很简单就是用move-corresponding语句，匹配两边的相同字段，然后赋值，就可以实现简单地在。
SAP system copy 操作流程笔记
weixin_57415610的博客
11-20 1105
SAP system copy 操作流程笔记 一、准备工作：OS 二、准备工作：SAP 三、SAP执行后处理
九十二、SAP中ALV事件之六，复制一个标准工具栏到自己的程序
weixin_30346033的博客
07-31 404
一、我们来到SE41，点击复制状态按钮 二、点击复制状态后，弹出一个框框，上面是模板内容，下面是我们自己的程序 三、我们根据上一篇的标准模板内容，填好相应的模板和我们的程序的内容 三、点击复制按钮 五、SAP会提示哪些内容会被复制，我们点击复制 六、提示已经被复制 七、回到SE38，来到我们自己的程序中，会看到多了一个GUI，名字为TIANPAN_TO...
SAP_BASIS模块- CLIENT拷贝方法（包括同服务器和跨服务器拷贝）
qq_40141758的博客
03-25 1847
SAP Client本地拷贝以及跨服务拷贝保姆级教程，新手小白都看得懂~~
SAP发送数据到外围系统接口
beyond911的专栏
10-05 1190
文章目录1. Introduction2.code 1. Introduction This is an interface .(data From sap to mes ). The process is that we convert data format(sap data to jason data and jason data to sap data). 2.code ** gv_json DATA ztrexjson TYPE REF TO cl_trex_json_serializer
Linux系统调用详解：核心机制与Ioctl、Procfs、Netlink应用
ioctl允许用户通过特定的命令码向驱动程序发送请求，比如设置设备的配置参数或读取状态信息。ioctl是单向的，即只能由用户空间发起通知，驱动程序根据命令进行响应，但不返回任何参数到用户空间，除非特别设计为带有...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值