触发器,出入库操作(单据写入)时自动更新物料的当前库存数字

--  作者:彭建军
--  日期:2005-06-27
--  页面:Page3
--  概要:触发器的创建、修改、删除以及调用
--  说明:以下示例均在[查询分析器]下进行,可配合图形界面进行测试
--================================================--

/*
建立虚拟测试环境,包含:表[卷烟库存表],表[卷烟销售表]。
请大家注意跟踪这两个表的数据,体会触发器到底执行了什么业务逻辑,对数据有什么影响。
为了能更清晰的表述触发器的作用,表结构存在数据冗余,且不符合第三范式,这里特此说明。
*/

USE Master
GO

IF EXISTS (SELECT NAME FROM SYSOBJECTS WHERE XTYPE = 'U' AND NAME = '卷烟库存表')
    DROP TABLE 卷烟库存表
GO
IF EXISTS (SELECT NAME FROM SYSOBJECTS WHERE XTYPE = 'U' AND NAME = '卷烟销售表')
    DROP TABLE 卷烟销售表
GO

--业务规则:销售金额 = 销售数量 * 销售单价 业务规则。

CREATE TABLE 卷烟销售表
(
    卷烟品牌        VARCHAR(40) PRIMARY KEY NOT NULL,
    购货商          VARCHAR(40) NULL,
    销售数量        INT NULL,
    销售单价        MONEY NULL,
    销售金额        MONEY NULL
)
GO

--业务规则:库存金额 = 库存数量 * 库存单价 业务规则。

CREATE TABLE 卷烟库存表
(
    卷烟品牌        VARCHAR(40) PRIMARY KEY NOT NULL,
    库存数量        INT NULL,
    库存单价        MONEY NULL,
    库存金额        MONEY NULL
)
GO

--创建触发器,示例1

/*
创建触发器[T_INSERT_卷烟库存表],这个触发器较简单。
说明:      每当[卷烟库存表]发生 INSERT 动作,则引发该触发器。
触发器功能:    强制执行业务规则,保证插入的数据中,库存金额 = 库存数量 * 库存单价。
注意:      [INSERTED]、[DELETED]为系统表,不可创建、修改、删除,但可以调用。
重要:      这两个系统表的结构同插入数据的表的结构。
*/
IF EXISTS (SELECT NAME FROM SYSOBJECTS WHERE XTYPE = 'TR' AND NAME = 'T_INSERT_卷烟库存表')
    DROP TRIGGER T_INSERT_卷烟库存表
GO

CREATE TRIGGER T_INSERT_卷烟库存表
ON 卷烟库存表
FOR INSERT
AS
--提交事务处理
BEGIN TRANSACTION
    --强制执行下列语句,保证业务规则
    UPDATE 卷烟库存表
    SET 库存金额 = 库存数量 * 库存单价
    WHERE 卷烟品牌 IN (SELECT 卷烟品牌 from INSERTED)
COMMIT TRANSACTION
GO

/* 
针对[卷烟库存表],插入测试数据:
注意,第一条数据(红塔山新势力)中的数据符合业务规则,
第二条数据(红塔山人为峰)中,[库存金额]空,不符合业务规则,
第三条数据(云南映像)中,[库存金额]不等于[库存数量]乘以[库存单价],不符合业务规则。
第四条数据库存数量为0。
请注意在插入数据后,检查[卷烟库存表]中的数据是否 库存金额 = 库存数量 * 库存单价。
*/

INSERT INTO 卷烟库存表(卷烟品牌,库存数量,库存单价,库存金额)
    SELECT '红塔山新势力',100,12,1200 UNION ALL
    SELECT '红塔山人为峰',100,22,NULL UNION ALL
    SELECT '云南映像',100,60,500      UNION ALL
    SELECT '玉溪',0,30,0
GO

--查询数据

SELECT * FROM 卷烟库存表
GO
/*

结果集

RecordId  卷烟品牌       库存数量  库存单价  库存金额
--------  ------------  --------  -------  ---------
1         红塔山新势力   100       12.0000  1200.0000
2         红塔山人为峰   100       22.0000  2200.0000
3         云南映像       100       60.0000  6000.0000
4         玉溪           0         30.0000  .0000

(所影响的行数为 4 行)

*/


--触发器示例2

/*
创建触发器[T_INSERT_卷烟销售表],该触发器较复杂。
说明:       每当[卷烟库存表]发生 INSERT 动作,则引发该触发器。
触发器功能:    实现业务规则。
业务规则:   如果销售的卷烟品牌不存在库存或者库存为零,则返回错误。
            否则则自动减少[卷烟库存表]中对应品牌卷烟的库存数量和库存金额。
*/
IF EXISTS (SELECT NAME FROM SYSOBJECTS WHERE XTYPE = 'TR' AND NAME = 'T_INSERT_卷烟销售表')
    DROP TRIGGER T_INSERT_卷烟销售表
GO

CREATE TRIGGER T_INSERT_卷烟销售表
ON 卷烟销售表
FOR INSERT
AS
BEGIN TRANSACTION
    --检查数据的合法性:销售的卷烟是否有库存,或者库存是否大于零
    IF NOT EXISTS (
        SELECT 库存数量
        FROM 卷烟库存表
        WHERE 卷烟品牌 IN (SELECT 卷烟品牌 FROM INSERTED)
    )
        BEGIN
            --返回错误提示
            RAISERROR('错误!该卷烟不存在库存,不能销售。',16,1)
            --回滚事务
            ROLLBACK
            RETURN
        END

    IF EXISTS (
        SELECT 库存数量
        FROM 卷烟库存表
        WHERE 卷烟品牌 IN (SELECT 卷烟品牌 FROM INSERTED) AND
        库存数量 <= 0          
    )
        BEGIN
            --返回错误提示
            RAISERROR('错误!该卷烟库存小于等于0,不能销售。',16,1)
            --回滚事务
            ROLLBACK
            RETURN
        END
   
    --对合法的数据进行处理

    --强制执行下列语句,保证业务规则
    UPDATE 卷烟销售表
    SET 销售金额 = 销售数量 * 销售单价
    WHERE 卷烟品牌 IN (SELECT 卷烟品牌 FROM INSERTED)

    DECLARE @卷烟品牌 VARCHAR(40)
    SET @卷烟品牌 = (SELECT 卷烟品牌 FROM INSERTED)

    DECLARE @销售数量 MONEY
    SET @销售数量 = (SELECT 销售数量 FROM INSERTED)

    UPDATE 卷烟库存表
    SET 库存数量 = 库存数量 - @销售数量,
        库存金额 = (库存数量 - @销售数量)*库存单价
    WHERE 卷烟品牌 = @卷烟品牌
COMMIT TRANSACTION
GO

--请大家自行跟踪[卷烟库存表]和[卷烟销售表]的数据变化。
--针对[卷烟销售表],插入第一条测试数据,该数据是正常的。

INSERT INTO 卷烟销售表(卷烟品牌,购货商,销售数量,销售单价,销售金额)
    SELECT '红塔山新势力','某购货商',10,12,1200
GO

--针对[卷烟销售表],插入第二条测试数据,该数据 销售金额 不等于 销售单价 * 销售数量。
--触发器将自动更正数据,使 销售金额 等于 销售单价 * 销售数量。

INSERT INTO 卷烟销售表(卷烟品牌,购货商,销售数量,销售单价,销售金额)
    SELECT '红塔山人为峰','某购货商',10,22,2000
GO

--针对[卷烟销售表],插入第三条测试数据,该数据中的卷烟品牌在 卷烟库存表 中找不到对应。
--触发器将报错。

INSERT INTO 卷烟销售表(卷烟品牌,购货商,销售数量,销售单价,销售金额)
    SELECT '红河V8','某购货商',10,60,600
GO

/*
结果集
服务器: 消息 50000,级别 16,状态 1,过程 T_INSERT_卷烟销售表,行 15
错误!该卷烟不存在库存,不能销售。
*/

--针对[卷烟销售表],插入第三条测试数据,该数据中的卷烟品牌在 卷烟库存表 中库存为0。
--触发器将报错。

INSERT INTO 卷烟销售表(卷烟品牌,购货商,销售数量,销售单价,销售金额)
    SELECT '玉溪','某购货商',10,30,300
GO

/*
结果集
服务器: 消息 50000,级别 16,状态 1,过程 T_INSERT_卷烟销售表,行 29
错误!该卷烟库存小于等于0,不能销售。
*/
--查询数据
SELECT * FROM 卷烟库存表

SELECT * FROM 卷烟销售表
GO

/*
补充:
1、本示例主要通过一个简单的业务规则实现来进行触发器使用的说明,具体的要根据需要灵活处理;
2、关于触发器要理解并运用好 INSERTED ,DELETED 两个系统表;
3、本示例创建的触发器都是 FOR INSERT ,具体的语法可参考:

    Trigger语法

    CREATE TRIGGER trigger_name
    ON { table | view }
    [ WITH ENCRYPTION ] --用于加密触发器
    {
        { { FOR | AFTER | INSTEAD OF } { [ INSERT ] [ , ] [ UPDATE ] }
            [ WITH APPEND ]
            [ NOT FOR REPLICATION ]
            AS
            [ { IF UPDATE ( column )
                [ { AND | OR } UPDATE ( column ) ]
                    [ ...n ]
            | IF ( COLUMNS_UPDATED ( ) { bitwise_operator } updated_bitmask )
                    { comparison_operator } column_bitmask [ ...n ]
            } ]
            sql_statement [ ...n ]
        }
    }

4、关于触发器,还应该注意
(1)、DELETE 触发器不能捕获 TRUNCATE TABLE 语句。
(2)、触发器中不允许以下 Transact-SQL 语句:
        ALTER DATABASE CREATE DATABASE DISK INIT
        DISK RESIZE DROP DATABASE LOAD DATABASE
        LOAD LOG RECONFIGURE RESTORE DATABASE
        RESTORE LOG
(3)、触发器最多可以嵌套 32 层。

*/

--修改触发器
--实质上,是将 CREATE TRIGGER ... 修改为 ALTER TRIGGER ...即可。

--删除触发器
DROP TRIGGER xxx
GO

--删除测试环境
DROP TABLE 卷烟库存表
GO
DROP TABLE 卷烟销售表
GO
DROP TRIGGER T_INSERT_卷烟库存表
GO
DROP TRIGGER T_INSERT_卷烟销售表
GO


/*
触发器:出入库操作(单据写入)时自动更新物料的当前库存数字
作者:ranzj@vip.sina.com
日期:2005年12月4日 18:26
*/
CREATE TRIGGER [TRI_CRK2KC_INSERT] ON [dbo].[CK]
AFTER INSERT
AS

BEGIN

  DECLARE @CRK int,@PJBH varchar(20),@SL int   --定义变量:出入库标志、单据编号、出入库标数量
  SELECT @CRK=[CRK],@PJBH=[PJBH],@SL=[SL] FROM [INSERTED] --赋值:出入库单据写入时的入库标志、单据编号、出入库标数量

  IF @CRK=1  --如果为入库,当前库存增入库数
    UPDATE [WLB] SET [KC]=[KC]+@SL WHERE [BM]=@PJBH
  ELSE   --如果为出库,当前库存减出库数
    UPDATE [WLB] SET [KC]=[KC]-@SL WHERE [BM]=@PJBH

END


---------------------------------------------------
/*
触发器:出入库操作(单据删除)时自动更新物料的当前库存数字
作者:ranzj@vip.sina.com
日期:2005年12月4日 18:26
*/
CREATE TRIGGER [TRI_CRK2KC_DELETE] ON [dbo].[CK]
FOR DELETE
AS

BEGIN

  DECLARE @CRK int,@PJBH varchar(20),@SL int   --定义变量:出入库标志、单据编号、出入库标数量
  SELECT @CRK=[CRK],@PJBH=[PJBH],@SL=[SL] FROM [DELETED] --赋值:出入库单据删除时的入库标志、单据编号、出入库标数量

  IF @CRK=1 --如果为入库单据删除,当前库存减原入库数
    UPDATE [WLB] SET [KC]=[KC]-@SL WHERE [BM]=@PJBH
  ELSE  --如果为出库单据删除,当前库存增原出库数
    UPDATE [WLB] SET [KC]=[KC]+@SL WHERE [BM]=@PJBH

END

---------------------------------------------------
/*
触发器:出入库操作(单据修改)时自动更新物料的当前库存数字
作者:ranzj@vip.sina.com
日期:2005年12月4日 18:26
*/
CREATE TRIGGER [TRI_CRK2KC_UPDATE] ON [dbo].[CK]
FOR UPDATE
AS

BEGIN

  DECLARE @CRK int,@PJBH varchar(20),@SL int   --定义变量:出入库标志、单据编号、出入库标数量

  SELECT @CRK=[CRK],@PJBH=[PJBH],@SL=[SL] FROM [DELETED] --赋值:出入库单据修改前的入库标志、单据编号、出入库标数量
  IF @CRK=1  --如果为入库单据修改,先让当前库存减原入库数
    UPDATE [WLB] SET [KC]=[KC]-@SL WHERE [BM]=@PJBH
  ELSE   --如果为出库单据修改,先让当前库存增原出库数
    UPDATE [WLB] SET [KC]=[KC]+@SL WHERE [BM]=@PJBH

  SELECT @CRK=[CRK],@PJBH=[PJBH],@SL=[SL] FROM [INSERTED] --赋值:出入库单据修改后的入库标志、单据编号、出入库标数量
  IF @CRK=1  --如果为入库单据修改,然后让当前库存增入库数
    UPDATE [WLB] SET [KC]=[KC]+@SL WHERE [BM]=@PJBH
  ELSE   --如果为出库单据修改,然后让当前库存减出库数
    UPDATE [WLB] SET [KC]=[KC]-@SL WHERE [BM]=@PJBH

END


---------------------------------------------------
/*
触发器:修改WLB的期初库存时自动更新物料的当前库存数字
作者:ranzj@vip.sina.com
日期:2005年12月4日 18:59
*/
CREATE TRIGGER [TRI_QC2KC_UPDATE] ON [dbo].[WLB]
FOR UPDATE
AS

IF UPDATE([QC])  --仅当WLB的期初库存被修改时才触发,其他字段修改时不触发
BEGIN

  DECLARE @BM varchar(20),@QC_1 int,@QC_2 int --定义变量:物料编号(在WLB表中应唯一)、期初库存修改前值、期初库存修改后值

  SELECT @QC_1=[QC] FROM [DELETED]  --赋值:期初库存修改前的物料编号、期初库存
  SELECT @BM=[BM],@QC_2=[QC] FROM [INSERTED] --赋值:期初库存修改后的物料编号、期初库存

  IF @QC_1<>@QC_2  --期初库存修改前、后值不等时才修改当前库存数字;否则无动作
    UPDATE [WLB] SET [KC]=[KC]+(@QC_2-@QC_1) WHERE [BM]=@BM

END

---------------------------------------------------

阅读更多
个人分类: Database
想对作者说点什么? 我来说一句

没有更多推荐了,返回首页

关闭
关闭
关闭