批处理安装绿色版MySQL 5.7.24

1.下载MySQL 5.7.24

https://cdn.mysql.com//Downloads/MySQL-5.7/mysql-5.7.24-winx64.zip

2.进行解压

解压后如下

3.创建_mysql.bat，并增加安装模块

首先加入以下代码，以管理员身份启动，并设置设置mysql路径

%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
set mysql=C:\Programs\mysql-5.7.24-winx64

增加选择模块，1:start 2:install 3:uninstall:，默认是1

set option=1
set /p option="1:start 2:install 3:uninstall: "
if %option% equ 1 goto start
if %option% equ 2 goto install
if %option% equ 3 goto uninstall

然后增加install部分，先是创建my.ini配置文件，接着往里加入配置，用bat来替代手动创建文件并输入

:install
echo [mysql]>>%mysql%\my.ini
echo default-character-set=utf8>>%mysql%\my.ini
echo [mysqld]>>%mysql%\my.ini
echo port = 3307>>%mysql%\my.ini
echo basedir=%mysql:\=\\%>>%mysql%\my.ini
echo datadir=%mysql:\=\\%\\data>>%mysql%\my.ini
echo max_connections=200>>%mysql%\my.ini
echo character-set-server=utf8>>%mysql%\my.ini
echo default-storage-engine=INNODB>>%mysql%\my.ini

创建data文件夹，并初始化以及安装服务

md %mysql%\data
%mysql%\bin\mysqld.exe --initialize --user=mysql --console
%mysql%\bin\mysqld.exe --install MySQL57

执行_mysql.bat，选择2.install，等待安装完毕，如下图所示

查看MySQL路径下，多了my.ini文件，以及data文件夹

此后，增加启动以及删除模块，在此之前，先在脚本底端增加一个标签：end，以便所有的模块执行完了都跳转到末尾，不影响其他的脚本逻辑。再在%mysql%\bin\mysqld.exe --install MySQL57语句后增加goto end，增加完成以后就可以添加启动以及删除模块了

增加启动以及删除模块

增加启动模块

:start
net start MySQL57
goto end

增加删除模块

:uninstall
net stop MySQL57
del %mysql%\my.ini
rd /s /q %mysql%\data
%mysql%\bin\mysqld.exe --remove MySQL57
goto end

至此，已经完成MySQL自动化构建工具，增加几个注意的点：
1.在my.ini写入配置时，如果用的是 ‘’ 而不是 ‘\’ 就会有路径上的问题，笔者在自身的电脑上对于 ‘’ 没有问题，但是在公司电脑上，’’ 则是有问题的

2.对于MySQL服务的检测: 以java -jar启动项目为例，一般启动Java项目使用java -jar test.jar，总会有MySQL服务忘记启动的情况，此时增加如下代码，将原有语句包围，则可以实现执行时检测：

net start|findstr /I "mysql57">nul && java -jar test.jar || echo MySQL未运行

3.对于编写的_mysql.bat，切忌不用chcp 65001来改变界面字符，会导致执行时在中文路径下的找不到路径问题，但是在笔者自身的电脑上经测试又是没有问题的，只在公司电脑上出现过