delphi的socket通讯 多个客户端 (转)

ClientSocket组件为客户端组件。它是通信的请求方,也就是说,它是主动地与服务器端建立连接。 
ServerSocket组件为服务器端组件。它是通信的响应方,也就是说,它的动作是监听以及被动接受客户端的连接请求,并对请求进行回复。 
ServerSocket组件可以同时接受一个或多个ClientSocket组件的连接请求,并与每个ClientSocket组件建立单独的连接,进行单独的通信。因此,一个服务器端可以为多个客户端服务。 
设计思路 
本例包括一个服务器端程序和一个客户端程序。客户端程序可以放到多个计算机上运行,同时与服务器端进行连接通信。 
本例的重点,一是演示客户端与服务器端如何通信;二是当有多个客户端同时连接到服务器端时,服务器端如何识别每个客户端,并对请求给出相应的回复。为了保证一个客户端断开连接时不影响其它客户端与服务器端的通信,同时保证服务器端能够正确回复客户端的请求,在本例中声明了一个记录类型: 
type 
client_record=record 
CHandle: integer; //客户端套接字句柄 
CSocket:TCustomWinSocket; //客户端套接字 
CName:string; //客户端计算机名称 
CAddress:string; //客户端计算机IP地址 
CUsed: boolean; //客户端联机标志 
end; 
利用这个记录类型数据保存客户端的信息,同时保存当前客户端的连接状态。其中,CHandle保存客户端套接字句柄,以便准确定位每个与服务器端保持连接的客户端;Csocket保存客户端套接字,通过它可以对客户端进行回复。Cused记录当前客户端是否与服务器端保持连接。 
下面对组件ServerSocket和ClientSocket的属性设置简单说明。 
ServerSocket的属性: 
· Port,是通信的端口,必须设置。在本例中设置为1025; 
· ServerTypt,服务器端读写信息类型,设置为stNonBlocking表示异步读写信息,本例中采用这种方式。 
· ThreadCacheSize,客户端的最大连接数,就是服务器端最多允许多少客户端同时连接。本例采用默认值10。 
其它属性采用默认设置即可。 
ClientSocket的属性: 
· Port,是通信的端口,必须与服务器端的设置相同。在本例中设置为1025; 
· ClientType,客户端读写信息类型,应该与服务器端的设置相同,为stNonBlocking表示异步读写信息。 
· Host,客户端要连接的服务器的IP地址。必须设置,当然也可以在代码中动态设置。 
其它属性采用默认设置即可。 
程序源代码: 
· 服务器端源码(uServerMain.pas): 
unit uServerMain; 
interface 
uses 
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs, 
ScktComp, ToolWin, ComCtrls, ExtCtrls, StdCtrls, Buttons; 
const 
CMax=10; //客户端最大连接数 
type 
client_record=record 
CHandle: integer; //客户端套接字句柄 
CSocket:TCustomWinSocket; //客户端套接字 
CName:string; //客户端计算机名称 
CAddress:string; //客户端计算机IP地址 
CUsed: boolean; //客户端联机标志 
end; 
type 
TfrmServerMain = class(TForm) 
ServerSocket: TServerSocket; 
ControlBar1: TControlBar; 
ToolBar1: TToolBar; 
tbConnect: TToolButton; 
tbClose: TToolButton; 
tbDisconnected: TToolButton; 
Edit1: TEdit; 
Memo1: TMemo; 
StatusBar: TStatusBar; 
procedure tbConnectClick(Sender: TObject); 
procedure tbDisconnectedClick(Sender: TObject); 
procedure ServerSocketClientRead(Sender: TObject; 
Socket: TCustomWinSocket); 
procedure ServerSocketListen(Sender: TObject; 
Socket: TCustomWinSocket); 
procedure ServerSocketClientConnect(Sender: TObject; 
Socket: TCustomWinSocket); 
procedure ServerSocketClientDisconnect(Sender: TObject; 
Socket: TCustomWinSocket); 
procedure tbCloseClick(Sender: TObject); 
procedure FormCreate(Sender: TObject); 
procedure FormClose(Sender: TObject; var Action: TCloseAction); 
procedure ServerSocketGetSocket(Sender: TObject; Socket: Integer; 
var ClientSocket: TServerClientWinSocket); 
procedure ServerSocketClientError(Sender: TObject; 
Socket: TCustomWinSocket; ErrorEvent: TErrorEvent; 
var ErrorCode: Integer); 
private 
{ Private declarations } 
public 
{ Public declarations } 
session: array[0..CMax] of client_record; //客户端连接数组 
Sessions: integer; //客户端连接数 
end; 
var 
frmServerMain: TfrmServerMain; 
implementation 
{$R *.DFM} 
//打开套接字连接,并使套接字进入监听状态 
procedure TfrmServerMain.tbConnectClick(Sender: TObject); 
begin 
ServerSocket.Open ; 
end; 
//关闭套接字连接,不再监听客户端的请求 
procedure TfrmServerMain.tbDisconnectedClick(Sender: TObject); 
begin 
ServerSocket.Close; 
StatusBar.Panels[0].Text :='服务器套接字连接已经关闭,无法接受客户端的连接请求.'; 
end; 
//从客户端读取信息 
procedure TfrmServerMain.ServerSocketClientRead(Sender: TObject; 
Socket: TCustomWinSocket); 
var 
i:integer; 
begin 
//将从客户端读取的信息添加到Memo1中 
Memo1.Lines.Add(Socket.ReceiveText); 
for i:=0 to sessions do 
begin 
//取得匹配的客户端 
if session[i].CHandle = Socket.SocketHandle then 
begin 
session[i].CSocket.SendText('回复客户端'+session[i].CAddress+' ==> '+Edit1.Text); 
end; 
end; 
end; 
//服务器端套接字进入监听状态,以便监听客户端的连接 
procedure TfrmServerMain.ServerSocketListen(Sender: TObject; 
Socket: TCustomWinSocket); 
begin 
StatusBar.Panels[0].Text :='等待客户端连接...'; 
end; 
//当客户端连接到服务器端以后 
procedure TfrmServerMain.ServerSocketClientConnect(Sender: TObject; 
Socket: TCustomWinSocket); 
var 
i,j:integer; 
begin 
j:=-1; 
for i:=0 to sessions do 
begin 
//在原有的客户端连接数组中有中断的客户端连接 
if not session[i].CUsed then 
begin 
session[i].CHandle := Socket.SocketHandle ;//客户端套接字句柄 
session[i].CSocket := Socket; //客户端套接字 
session[i].CName := Socket.RemoteHost ; //客户端计算机名称 
session[i].CAddress := Socket.RemoteAddress ;//客户端计算机IP 
session[i].CUsed := True; //连接数组当前位置已经占用 
Break; 
end; 
j:=i; 
end; 
if j=sessions then 
begin 
inc(sessions); 
session[j].CHandle := Socket.SocketHandle ; 
session[j].CSocket := Socket; 
session[j].CName := Socket.RemoteHost ; 
session[j].CAddress := Socket.RemoteAddress ; 
session[j].CUsed := True; 
end; 
StatusBar.Panels[0].Text := '客户端 '+Socket.RemoteHost + ' 已经连接'; 
end; 
//当客户端断开连接时 
procedure TfrmServerMain.ServerSocketClientDisconnect(Sender: TObject; 
Socket: TCustomWinSocket); 
var 
i:integer; 
begin 
for i:=0 to sessions do 
begin 
if session[i].CHandle =Socket.SocketHandle then 
begin 
session[i].CHandle :=0; 
session[i].CUsed := False; 
Break; 
end; 
end; 
StatusBar.Panels[0].Text :='客户端 '+Socket.RemoteHost + ' 已经断开'; 
end; 
//关闭窗口 
procedure TfrmServerMain.tbCloseClick(Sender: TObject); 
begin 
Close; 
end; 
procedure TfrmServerMain.FormCreate(Sender: TObject); 
begin 
sessions := 0; 
end; 
procedure TfrmServerMain.FormClose(Sender: TObject; 
var Action: TCloseAction); 
begin 
ServerSocket.Close ; 
end; 
//当客户端正在与服务器端连接时 
procedure TfrmServerMain.ServerSocketGetSocket(Sender: TObject; 
Socket: Integer; var ClientSocket: TServerClientWinSocket); 
begin 
StatusBar.Panels[0].Text :='客户端正在连接...'; 
end; 
//客户端发生错误 
procedure TfrmServerMain.ServerSocketClientError(Sender: TObject; 
Socket: TCustomWinSocket; ErrorEvent: TErrorEvent; 
var ErrorCode: Integer); 
begin 
StatusBar.Panels[0].Text :='客户端'+Socket.RemoteHost +'发生错误!'; 
ErrorCode := 0; 
end; 
end. 
· 客户端源码(uClientMain.pas): 
unit uClientMain; 
interface 
uses 
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs, 
ScktComp, ComCtrls, ToolWin, ExtCtrls, StdCtrls, Buttons; 
const 
SocketHost = '172.16.1.6'; //服务器端地址 
type 
TfrmClientMain = class(TForm) 
ControlBar1: TControlBar; 
ToolBar1: TToolBar; 
tbConnected: TToolButton; 
tbSend: TToolButton; 
tbClose: TToolButton; 
tbDisconnected: TToolButton; 
ClientSocket: TClientSocket; 
Edit1: TEdit; 
Memo1: TMemo; 
StatusBar: TStatusBar; 
btnSend: TBitBtn; 
procedure tbConnectedClick(Sender: TObject); 
procedure tbDisconnectedClick(Sender: TObject); 
procedure ClientSocketRead(Sender: TObject; Socket: TCustomWinSocket); 
procedure tbSendClick(Sender: TObject); 
procedure tbCloseClick(Sender: TObject); 
procedure FormShow(Sender: TObject); 
procedure ClientSocketConnect(Sender: TObject; 
Socket: TCustomWinSocket); 
procedure ClientSocketConnecting(Sender: TObject; 
Socket: TCustomWinSocket); 
procedure ClientSocketDisconnect(Sender: TObject; 
Socket: TCustomWinSocket); 
procedure FormClose(Sender: TObject; var Action: TCloseAction); 
procedure ClientSocketError(Sender: TObject; Socket: TCustomWinSocket; 
ErrorEvent: TErrorEvent; var ErrorCode: Integer); 
private 
{ Private declarations } 
public 
{ Public declarations } 
end; 
var 
frmClientMain: TfrmClientMain; 
implementation 
{$R *.DFM} 
//打开套接字连接 
procedure TfrmClientMain.tbConnectedClick(Sender: TObject); 
begin 
ClientSocket.Open ; 
end; 
//关闭套接字连接 
procedure TfrmClientMain.tbDisconnectedClick(Sender: TObject); 
begin 
ClientSocket.Close; 
end; 
//接受服务器端的回复 
procedure TfrmClientMain.ClientSocketRead(Sender: TObject; 
Socket: TCustomWinSocket); 
begin 
Memo1.Lines.Add(Socket.ReceiveText); 
end; 
//发送信息到服务器端 
procedure TfrmClientMain.tbSendClick(Sender: TObject); 
begin 
ClientSocket.Socket.SendText(Edit1.Text); 
end; 
procedure TfrmClientMain.tbCloseClick(Sender: TObject); 
begin 
Close; 
end; 
//设置要连接的服务器端地址 
procedure TfrmClientMain.FormShow(Sender: TObject); 
begin 
ClientSocket.Host := SocketHost; 
end; 
//已经连接到服务器端 
procedure TfrmClientMain.ClientSocketConnect(Sender: TObject; 
Socket: TCustomWinSocket); 
begin 
tbSend.Enabled := True; 
tbDisconnected.Enabled :=True; 
btnSend.Enabled := True; 
StatusBar.Panels[0].Text := '已经连接到 '+ Socket.RemoteHost ; 
end; 
//正在连接到服务器端 
procedure TfrmClientMain.ClientSocketConnecting(Sender: TObject; 
Socket: TCustomWinSocket); 
begin 
StatusBar.Panels[0].Text := '正在连接到服务器... ' ; 
end; 
//当断开与服务器端的连接时发生 
procedure TfrmClientMain.ClientSocketDisconnect(Sender: TObject; 
Socket: TCustomWinSocket); 
begin 
tbSend.Enabled := False; 
btnSend.Enabled := False; 
tbDisconnected.Enabled := False; 
StatusBar.Panels[0].Text := '已经断开与 '+ Socket.RemoteHost +' 的连接'; 
end; 
procedure TfrmClientMain.FormClose(Sender: TObject; 
var Action: TCloseAction); 
begin 
ClientSocket.Close ; 
end; 
//当与服务器端的连接发生错误时 
procedure TfrmClientMain.ClientSocketError(Sender: TObject; 
Socket: TCustomWinSocket; ErrorEvent: TErrorEvent; 
var ErrorCode: Integer); 
begin 
StatusBar.Panels[0].Text := '与服务器端的连接发生错误'; 
ErrorCode := 0; 
end; 
end. 
小结 
上述方法是比较简单的实现方法,同时也是相对较容易理解的方法。通过这个方法,笔者成功实现了局域网内多个客户端与服务器端进行Socket通信的功能,同时可以保证一个客户端的连接、通信或是断开都不影响其它客户端的正常通信。 
附录: 
服务器端窗体和客户端窗体及组件的属性设置参加相应的DFM文件。 
uServerMain.pas对应的DFM文件(uServerMain.dfm) 
object frmServerMain: TfrmServerMain 
Left = 297 
Top = 258 
BorderIcons = [biSystemMenu, biMinimize] 
BorderStyle = bsSingle 
Caption = 'ServerSocket' 
ClientHeight = 279 
ClientWidth = 476 
Color = clBtnFace 
Font.Charset = DEFAULT_CHARSET 
Font.Color = clWindowText 
Font.Height = -11 
Font.Name = 'MS Sans Serif' 
Font.Style = [] 
OldCreateOrder = False 
OnClose = FormClose 
OnCreate = FormCreate 
PixelsPerInch = 96 
TextHeight = 13 
object ControlBar1: TControlBar 
Left = 0 
Top = 0 
Width = 476 
Height = 30 
Align = alTop 
AutoSize = True 
TabOrder = 0 
object ToolBar1: TToolBar 
Left = 11 
Top = 2 
Width = 459 
Height = 22 
ButtonHeight = 21 
ButtonWidth = 55 
Caption = 'ToolBar1' 
EdgeInner = esNone 
EdgeOuter = esNone 
Flat = True 
ShowCaptions = True 
TabOrder = 0 
object tbConnect: TToolButton 
Left = 0 
Top = 0 
Caption = ' 连接 ' 
ImageIndex = 0 
OnClick = tbConnectClick 
end 
object tbDisconnected: TToolButton 
Left = 55 
Top = 0 
Caption = '断开' 
ImageIndex = 4 
OnClick = tbDisconnectedClick 
end 
object tbClose: TToolButton 
Left = 110 
Top = 0 
Caption = '关闭' 
ImageIndex = 3 
OnClick = tbCloseClick 
end 
end 
end 
object Edit1: TEdit 
Left = 0 
Top = 232 
Width = 473 
Height = 21 
TabOrder = 1 
Text = '你好!' 
end 
object Memo1: TMemo 
Left = 0 
Top = 30 
Width = 476 
Height = 195 
Align = alTop 
TabOrder = 2 
end 
object StatusBar: TStatusBar 
Left = 0 
Top = 257 
Width = 476 
Height = 22 
Panels = < 
item 
Width = 50 
end> 
SimplePanel = False 
end 
object ServerSocket: TServerSocket 
Active = False 
Port = 1025 
ServerType = stNonBlocking 
OnListen = ServerSocketListen 
OnGetSocket = ServerSocketGetSocket 
OnClientConnect = ServerSocketClientConnect 
OnClientDisconnect = ServerSocketClientDisconnect 
OnClientRead = ServerSocketClientRead 
OnClientError = ServerSocketClientError 
Left = 368 
end 
end 
uClientMain.pas对应的DFM文件(uClientMain.dfm) 
object frmClientMain: TfrmClientMain 
Left = 361 
Top = 290 
BorderIcons = [biSystemMenu, biMinimize] 
BorderStyle = bsSingle 
Caption = 'ClientSocket' 
ClientHeight = 230 
ClientWidth = 402 
Color = clBtnFace 
Font.Charset = DEFAULT_CHARSET 
Font.Color = clWindowText 
Font.Height = -11 
Font.Name = 'MS Sans Serif' 
Font.Style = [] 
OldCreateOrder = False 
Position = poScreenCenter 
OnClose = FormClose 
OnShow = FormShow 
PixelsPerInch = 96 
TextHeight = 13 
object ControlBar1: TControlBar 
Left = 0 
Top = 0 
Width = 402 
Height = 30 
Align = alTop 
AutoSize = True 
TabOrder = 0 
object ToolBar1: TToolBar 
Left = 11 
Top = 2 
Width = 385 
Height = 22 
ButtonHeight = 21 
ButtonWidth = 55 
Caption = 'ToolBar1' 
EdgeInner = esNone 
EdgeOuter = esNone 
Flat = True 
ShowCaptions = True 
TabOrder = 0 
object tbConnected: TToolButton 
Left = 0 
Top = 0 
Caption = ' 连接 ' 
ImageIndex = 0 
OnClick = tbConnectedClick 
end 
object tbSend: TToolButton 
Left = 55 
Top = 0 
Caption = '发送' 
Enabled = False 
ImageIndex = 1 
OnClick = tbSendClick 
end 
object tbDisconnected: TToolButton 
Left = 110 
Top = 0 
Caption = '断开' 
Enabled = False 
ImageIndex = 3 
OnClick = tbDisconnectedClick 
end 
object tbClose: TToolButton 
Left = 165 
Top = 0 
Caption = '退出' 
ImageIndex = 2 
OnClick = tbCloseClick 
end 
end 
end 
object Edit1: TEdit 
Left = 0 
Top = 184 
Width = 321 
Height = 21 
TabOrder = 1 
Text = '问候' 
end 
object Memo1: TMemo 
Left = 0 
Top = 30 
Width = 402 
Height = 147 
Align = alTop 
TabOrder = 2 
end 
object StatusBar: TStatusBar 
Left = 0 
Top = 208 
Width = 402 
Height = 22 
Panels = < 
item 
Width = 50 
end> 
SimplePanel = False 
end 
object btnSend: TBitBtn 
Left = 336 
Top = 183 
Width = 60 
Height = 22 
Caption = '发送' 
Enabled = False 
TabOrder = 4 
OnClick = tbSendClick 
end 
object ClientSocket: TClientSocket 
Active = False 
ClientType = ctNonBlocking 
Port = 1025 
OnConnecting = ClientSocketConnecting 
OnConnect = ClientSocketConnect 
OnDisconnect = ClientSocketDisconnect 
OnRead = ClientSocketRead 
OnError = ClientSocketError 
Left = 320 
end 
end 

 

 

一个简单的例子,供参考:   
    
  //================================客户端=====================================   
  unit   Unit1;   
    
  interface   
    
  uses   
      Windows,   Messages,   SysUtils,   Variants,   Classes,   Graphics,   Controls,   Forms,   
      Dialogs,   StdCtrls,   ScktComp;   
    
  type   
      TForm1   =   class(TForm)   
          ClientSocket1:   TClientSocket;   
          OpenDialog1:   TOpenDialog;   
          Button1:   TButton;   
          procedure   Button1Click(Sender:   TObject);   
      private   
          {   Private   declarations   }   
      public   
          {   Public   declarations   }   
      end;   
    
  var   
      Form1:   TForm1;   
    
  implementation   
    
  {$R   *.dfm}   
    
  procedure   TForm1.Button1Click(Sender:   TObject);   
  var   
      s   :   TWinSocketStream;   
      f,   f2:   TFileStream;   
  begin   
      if   not   OpenDialog1.Execute   then   Exit;   
      ClientSocket1.Open;   
      s   :=   TWinSocketStream.Create(ClientSocket1.Socket,   60000);   
      f   :=   TFileStream.Create(OpenDialog1.FileName,   fmShareDenyWrite);   
      try   
          s.CopyFrom(f,   0);   
      finally   
          s.Free;   
          f.Free;   
          ClientSocket1.Close;   
      end;   
  end;   
    
  end.   
    
  //========================================服务器端====================================   
  unit   Unit2;   
    
  interface   
    
  uses   
      Windows,   Messages,   SysUtils,   Variants,   Classes,   Graphics,   Controls,   Forms,   
      Dialogs,   ScktComp;   
    
  type   
      TForm1   =   class(TForm)   
          ServerSocket1:   TServerSocket;   
          procedure   ServerSocket1GetThread(Sender:   TObject;   
              ClientSocket:   TServerClientWinSocket;   
              var   SocketThread:   TServerClientThread);   
          private   
          {   Private   declarations   }   
          public   
          {   Public   declarations   }   
          end;   
      TClientThread   =   Class(TServerClientThread)   
          private   
          public   
          procedure   ClientExecute;   override;   
          end;   
            
  var   
      Form1:   TForm1;   
    
  implementation   
    
  {$R   *.dfm}   
    
    
  procedure   TClientThread.ClientExecute;   
  var   
      ReceiveBuffer   :   Array[0..1023]   Of   Char;   
      SocketStream   :   TWinSocketStream;   
      BytesRead   :   Integer;   
      F   :   TFileStream;   
      FileName:   string;   
  begin   
    while   not   Terminated   and   ClientSocket.Connected   do   
      Begin   
        try   
            SocketStream   :=   TWinSocketStream.Create(ClientSocket,   100);   
            FileName   :=   'C:/afile';   
            if   FileExists(FileName)   then   FileName   :=   FileName   +   '0';   
            F   :=   TFileStream.Create(FileName,   fmCreate);   
            try   
                FillChar(ReceiveBuffer,   sizeof(ReceiveBuffer),   0);   
                  while   SocketStream.WaitForData(5000)   do   
                  begin   
                      BytesRead   :=   SocketStream.Read(ReceiveBuffer,SizeOf(ReceiveBuffer));   
                      if   BytesRead   =   0   then   
                          ClientSocket.Close   
                      Else   
                        F.WriteBuffer(ReceiveBuffer,   BytesRead);   
                  end;   
            finally   
                SocketStream.Free;   
                ClientSocket.Close;   
                f.Free;   
            end;   
        except   
        end;   
      end;   
  end;   
    
    
  procedure   TForm1.ServerSocket1GetThread(Sender:   TObject;   
      ClientSocket:   TServerClientWinSocket;   
      var   SocketThread:   TServerClientThread);   
  begin   
      SocketThread   :=   TClientThread.Create(False,   ClientSocket);   
  end;   
    
  end.   
 

 

 

-----------------------------------------------------------------------------------------------------------------------------------

ClientSocket和ServerSocket,它们对Winsock的API进行了很好的封装生成了TClientSocket和TserverSocket两个类(控件)。通过这两个控件,可以很方便的生成TCP/IP网络应用程序。TClientSocket类是客户端的Socket类,通过它可以与服务器程序建立TCP连接,并进行数据交换。TserverSocket是服务端的Socket类,通过它,应用程序可以提供TCP网络服务,等待用户连接,并在连接后进行数据交换。以下是对两个控件进行介绍。
ClientSocket
简介
ClientSocket是封装了作为客户端的Socket的一个控件,当在应用程序的Form中加入了控件之后,就可以选择所要连接的Server,需要Server提供什么样的服务。当设定好参数之后,就可以开始和Server建立连接了。连接建立好之后就可以通过ClientSocket和ServerSocket交换数据了。交换数据之后可以断开连接。
   TClientSocket的类继承关系如下:
                                 Tobject
                                    
                                 Tpersistent

                                 Tcomponent

                                 TcustomSocket

TClientSocket
TcustomSocket把WinSock的API已经封装好了,包含了WinSock的初始化、退出的环境清理、API的调用既网络事件的消息响应等。
ClientSocket 的属性
(1)     Active
类型:布尔型
表示是否建立连接;
(2)     Address
类型:string
建立连接后不可更改,更改后引发一个EsocketError异常。    
如果设定了host属性,则address将会被忽略。
(3)     ClientType
         CtNonBlocking,就是允许Socket异步的处理读写事件
         Ctblocking 读写操作是同时进行的。
(4)     Host
         用于指定域名或IP
         同样在连接时,改变Host属性会产生一个EsocketError的异常。
(5)     Name
(6)     Port
指定端口号。
           连接过程中改变会产生一个EsocketError的异常。
(7)     Service
用于指定服务的名字。
使用Service属性后PORT属性将被忽略。
       连接过程如果改变了,会产生一个EsocketError的异常。
(8)     Socket
           是一个TclientWinSocket类的对象,它描述了Windows Socket连接的客户端的属性和状态,并通过它对Socket进行操作。
           Socket的常用属性:
           Connected   属性,指明是否与服务器建立连接。
           LocalAdress   属性,指明本机IP。
           LocalHost     属性,表示本机主机名。
           Localport     属性,表示本次连接使用的端口号。
           RemoteAdress 属性,服务器的IP。
           RemoteHost   属性,服务器的主机名。
           RemotePort   属性,服务器使用的端口号。
ClientSocket的方法:
(1)Open
参数:无;
返回值:无;
初始化Socket,尝试与服务器连接,并把Active属性设为true
(2)     Close
参数:无;
返回值:无;
断开连接,把Active属性设为False;
(3)     Socket对象的方法
ReceiveLength方法
参数:无
返回值:integer
Socket 收到多少数据
ReceiveText 方法
参数:无
返回值:string
用于接收数据组成的字符串。注意:此方法只适用于异步方式的socket,在OnRead事件处理过程中被调用。对于同步的socket只能用TwinSocketStream对象来读取数据。
Readbuf方法
参数(var Buf;Count Integer)
返回值:integer
可以读入指定的字节到指定的变量中,其中,Count是要读取的字节数,Buf是数据缓冲区变量。在调用之前,一般应该调用ReciveLength来确定有多少字符可读,并要检查指定的变量是否足够容纳这些数据而不会引起内存越界。
适用条件与Receivetext相同。
SendText方法
参数:(const S:string)
返回值:无
把一个字符串通过Socket发送到服务器。其中,S是要发送的字符串。本方法可以在发送数据的地方调用,如果发送出现任何错误,该发送过程会中断,引发一个EsocketError异常。
SendBuf方法
参数:(var Buf; Count:integer)
返回值:integer
可以把指定的数据发送到服务器端,本方法可以在需要发送数据的地方调用。同样如果发送过程出现任何错误过程会被中断,引发一个EsocketError的异常。
ClientSocket的事件
(1)     OnConnecting 事件
本事件发生于Client已经定位了服务端的Socket之后,在完全建立连接之前。在本事件的处理过程中可以获取要建立服务器的IP和端口号。
(2)     Onconnect   事件
本事件发生于服务端接受请求之后,并在客户端完成连接之后。在事件处理过程中,应该是完成连接之后客户端所进行的动作的处理代码,这取决于所选取的服务,一般情况下是在该连接上进行数据交换。
(3)     OnDisconnect 事件
本事件发生与Active属性被设为False之后,而客户端真正终止网络连接之前。可以在本事件处理过程中加入原码,进行网络连接终止前的处理,如释放某些已分配的资源文件等。
(4)     OnRead 事件
本事件发生于ClientSocket接收到数据,要求程序读取的时候。此时可以读取数据并进行处理。
(5)     OnWrite 事件
本事件发生于ClientSocket要往服务器端发送数据的时候。
(6)     OnError 事件
当ClientSocket在建立连接,读写数据,关闭连接等发生错误时,就会发出本事件的通知
定义:procedure (Sender: Tobject; Socket:Tcustom WinSocket; ErrorEvent: TerrorEvent;var ErrorCode:Integer) of object
其中参数ErrorEvent指明了错误发生的类型,参数ErrorCode则是Windows Socket Api返回的错误代码。参数ErrorEvent是一个集合类的对象,可能的取值有:eeGeneral,eeSend,eeReceive,eeConnect,eeDisconnect,eeAccept。分别表示:一般错误、发送数据时出错、读取数据时出错、建议连接时出错、终止连接时出错、接受连接时出错(ServerSocket);
通过对不同错误的处理,可以增强自己应用程序的可靠性。当成功处理完某一错误事件后,应该将ErrorCode的值设为0。以免再次触发EsocketError异常的产生。
                   ServerSocket简介
ServerSocket是封装了作为Server既服务器端的Socket的一个控件。在应用程序的Form中加入了ServerSocket之后,应用程序就可以作为一个服务程序而存在。当ServerSocket激活以后,正常状态下处于侦听状态,等待客户程序的连接。客户端请求连接时,启动了一个新的线程,接受客户的请求,完成连接之后,就可以给客户提供服务,服务完成之后,终止网络连接,线程退出。而主线程仍处于侦听状态,可以接受多个客户的连接请求。并可同时提供服务。
TserverSocket 的类继承关系如下:
                             Tobject
                             Tpersistent

                             Tcomponent

                             TcustomSocket

                             TcustomServerSocket
            
                             TserverSocket
ServerSocket控件的属性
(1)     Active
属性为true时,进入侦听状态,等待客户连接。
(2)     ServerType属性
指明ServerSocket的类型,可取的值有:stNonBlocking,stThreadBlocking两种。
当ServerSocket设为stThreadBlocking,则每当接受一个客户的连接就自动生成一个线程,以处理客户的各种请求。当通过它发送或接受信息时,线程就会自动进入休眠状态直到数据传输完毕,然后会发出OnClientRead或OnClientWrite事件通知,让主线程进行处理。
把ServerSocket设定为stNonBlocking,则Socket可以异步的处理数据接收和发送。默认情况下,所有的客户连接的处理都是在单一的线程中进行的,当接收到数据或要发送数据时,也会发出OnClientRead和OnClientWrite事件通知。

(3)     ThreadCacheSize属性
指明最大能有最大能有多少个线程在等待新的用户连接。
当Servertype是stThreadBlocking型时,每接受一个用户连接就要产生一个新的线程,为了提高系统的性能,ServerSocket会把已经断开的客户线程保留在缓冲区里。而不是释放他们。这样当一个新的请求到来的时候,就不必创建新的线程能减少所用的时间提高性能。
           ThreadCacheSize的值不能设的太小,否则许多时间会浪费在创建和释放线程上,当然也不能太大,否则,系统资源(如内存)浪费太大,也不利于提高系统性能。
(4)     Port属性
指明ServerSocket提供服务所在的端口号。
(5)     Service 属性
提供服务的名称。
如果ServerSocket已经启动,任何企图改变Port和Service属性的值将会产生一个EsocketError的异常。
(6)     name属性
(7)     Socket属性
是一个TserverWinSocket类的对象,描述了服务器作为侦听端的特性。
Socket对象常用的属性有:
Connected,LocalAddress,LocalHost,LocalPort,RemoteAddress,RemoteHost,
RemotePortd。
ActiveConnections属性:整型(Integer),指明了ServerSocket当前正在打开的已经被接受了的客户请求,可以通过它来查看ServerSocket 的使用情况。
AciveThreads属性:整型。指明了ServerSocket当前正在使用的TserverClientThread线程对象的数目。通过本属性的值,可以监看线程的使用情况。对于stThreadBlocking型的ServerSocket,每接受一个客户的连接,ActiveThread记数就会加一。
IdleThread 属性:整型。指明了在当前在线程缓冲区内,但是没有使用的线程的对象的数目。通过这一值的大小可以检查ThreadCacheSize的取值是否合理。
Connections属性:这是TcustomWinSocket对象数组。该数组的下标值是从0到ActivConnection-1。通过这一数组可以访问每一个客户端相连的Socket.。
ServerSocket控件的方法
(1)     Open方法
初始化ServerSocket,把Active属性设为True, 进入侦听状态,等待客户连接。
(2)     Close方法
终止所有的Socket连接,并释放网络资源,把Active属性的值设为False,ServerSocket不在接受客户端的连接请求。
(3)     Socket对象的方法
Socket对象的常用方法有:ReceiveLeghth,ReceiveText,ReceiveBuf,Sendtext,SendBuf等。
ServerSocket的事件
(1)     OnClientConnect事件
本事件发生在连接请求被接受之后,可以开始提供服务。
(2)     OnClientDisconnect事件
当某一客户连接被终止时,产生本事件,在本事件中可以进行终止后的清除工作,如释放相关的内存等。
(3) OnClientRead 事件
    当ServerSocket收到客户发送过来的文件之后,发出本事件的通知,要求处理数据响应客户的请求。
    对于ServerType是stThreadBlocking的Server Socket,应使用TwinSocketStream对象来读取数据。
(4) OnClientSocketWrite事件
    在ServerSocket要向客户发送数据的时,发出本事件通知。同样 对于ServerType是stThreadBlocking的Server Socket,应使用TwinSocketStream对象来读取数据。
(5)     OnClientError事件
同ClientSocket的Onerror事件。

转载于:https://www.cnblogs.com/FuYan/p/3745808.html

  • 0
    点赞
  • 0
    评论
  • 3
    收藏
  • 一键三连
    一键三连
  • 扫一扫,分享海报

简介 笔者当初为了学习JAVA,收集了很多经典源码,源码难易程度分为初级、中级、高级等,详情看源码列表,需要的可以直接下载! 这些源码反映了那时那景笔者对未来的盲目,对代码的热情、执着,对IT的憧憬、向往!此时此景,笔者只专注Android、Iphone等移动平台开发,看着这些源码心中有万分感慨,写此文章纪念那时那景! Java 源码包 Applet钢琴模拟程序java源码 2个目标文件,提供基本的音乐编辑功能。编辑音乐软件的朋友,这款实例会对你有所帮助。 Calendar万年历 1个目标文件 EJB 模拟银行ATM流程及操作源代码 6个目标文件,EJB来模拟银行ATM机的流程及操作:获取系统属性,初始化JNDI,取得Home对象的引用,创建EJB对象,并将当前的计数器初始化,调用每一个EJB对象的count()方法,保证Bean正常被激活和钝化,EJB对象是用完毕,从内存中清除,从账户中取出amt,如果amt>账户余额抛出异常,一个实体Bean可以表示不同的数据实例,我们应该通过主键来判断删除哪个数据实例&hellip;&hellip; ejbCreate函数用于初始化一个EJB实例 5个目标文件,演示Address EJB的实现 ,创建一个EJB测试客户端,得到名字上下文,查询jndi名,通过强制型得到Home接口,getInitialContext()函数返回一个经过初始化的上下文,用client的getHome()函数调用Home接口函数得到远程接口的引用,用远程接口的引用访问EJB。 EJB中JNDI的使用源码例子 1个目标文件,JNDI的使用例子,有源代码,可以下载参考,JNDI的使用,初始化Context,它是连接JNDI树的起始点,查找你要的对象,打印找到的对象,关闭Context&hellip;&hellip; ftp文件传输 2个目标文件,FTP的目标是:(1)提高文件的共享性(计算机程序和/或数据),(2)鼓励间接地(通过程序)使用远程计算机,(3)保护用户因主机之间的文件存储系统导致的变化,(4)为了可靠和高效地传输,虽然用户可以在终端上直接地使用它,但是它的主要作用是供程序使用的。本规范尝试满足大型主机、微型主机、个人工作站、和TACs 的不同需求。例如,容易实现协议的设计。 Java EJB中有、无状态SessionBean的两个例子 两个例子,无状态SessionBean可会话Bean必须实现SessionBean,获取系统属性,初始化JNDI,取得Home对象的引用,创建EJB对象,计算利息等;在有状态SessionBean中,用累加器,以对话状态存储起来,创建EJB对象,并将当前的计数器初始化,调用每一个EJB对象的count()方法,保证Bean正常被激活和钝化,EJB对象是用完毕,从内存中清除&hellip;&hellip; Java Socket 聊天通信演示代码 2个目标文件,一个服务器,一个客户端。 Java Telnet客户端实例源码 一个目标文件,演示Socket的使用。 Java 组播组中发送和接受数据实例 3个目标文件。 Java读写文本文件的示例代码 1个目标文件。 java俄罗斯方块 一个目标文件。 Java非对称加密源码实例 1个目标文件 摘要:Java源码,算法相关,非对称加密   Java非对称加密源程序代码实例,本例中使用RSA加密技术,定义加密算法可用 DES,DESede,Blowfish等。   设定字符串为“张三,你好,我是李四”   产生张三的密钥对(keyPairZhang)   张三生成公钥(publicKeyZhang)并发送给李四,这里发送的是公钥的数组字节   通过网络或磁盘等方式,把公钥编码传送给李四,李四接收到张三编码后的公钥,将其解码,李四用张三的公钥加密信息,并发送给李四,张三用自己的私钥解密从李四处收到的信息&hellip;&hellip; Java利用DES私钥对称加密代码实例 同上 java聊天室 2个目标文件,简单。 java模拟掷骰子2个 1个目标文件,输出演示。 java凭图游戏 一个目标文件,简单。 java求一个整数的因子 如题。 Java生成密钥的实例 1个目标文件 摘要:Java源码,算法相关,密钥   Java生成密钥、保存密钥的实例源码,通过本源码可以了解到Java如何产生单钥加密的密钥(myKey)、产生双钥的密钥对(keyPair)、如何保存公钥的字节数组、保存私钥到文件privateKey.dat、如何用Java对象序列化保存私钥,通常应对私钥加密后再保存、如何从文件中得到公钥编码的字节数组、如何从字节数组解码公钥。 Java数据压缩与传输实例 1个目标文件 摘要:Java源码,文件操作,数据压缩,文件传输   Java数据压缩与传输实例,可以学习一下实例化套按字、得到文件输入流、压缩输入流、文件输出流、实例化缓冲
表情包
插入表情
评论将由博主筛选后显示,对所有人可见 | 还能输入1000个字符
©️2021 CSDN 皮肤主题: 编程工作室 设计师:CSDN官方博客 返回首页
实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、C币套餐、付费专栏及课程。

余额充值