王爽《汇编语言》课程设计二（只包含CMOS RAM操作不包含软盘操作）

最新推荐文章于 2022-01-11 16:34:21 发布
最新推荐文章于 2022-01-11 16:34:21 发布
阅读量1.7k 收藏 6
点赞数 8
分类专栏： Assembler/Disassembler 文章标签： 汇编语言 cmos ascii
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/apollon_krj/article/details/71908442
版权

遇到的瓶颈问题：如何能做到随时获取键盘中断，而不是一直等着按F1或ESC键。（int 16H的0号功能与1号功能的配合）：
我们知道BIOS键盘缓冲区 15字节数据，高8位保存扫描码，低8位保存ASCII码。缓冲区为一个环形队列。int 16例程的0号功能可以从键盘缓冲区中阻塞式读取数据，获取到的数据会存放到AX中，高八位存放扫描码，低八位存放对应的ASCII码。
int 9H则可以用来向缓冲区中写数据，每写一次，缓冲区队尾指针就后移一次。int 16H读取一次(0号功能读)则队头指针就后移一次（即读取某字节后，该字节就被跳过，下次不会再读）。当队列为空时（队头队尾指针重合时），int 16H的0号功能再去读，读取不到则阻塞等待。
但是我们有时候需要非阻塞式读取，因为不能说读取不到键盘输入程序就不执行了(有时候键盘输入只是影响当前状态，并不能停止当前状态)，那么我们就需要用int 16H的1号功能非阻塞读取缓冲区，但是非阻塞读取时，即使数据已经读取走，缓冲区也不会发生变化(只负责读取不负责修改队列，下次读的还是上一次的字节位置)，所以需要每次在处理非阻塞读取到的内容的子程序中阻塞读取一次，将非阻塞读取但没有删除(即没有移动队头指针)的数据清除，也就是将队头指针后移一次。

对于阻塞读取非阻塞的残留数据，使用的自实现方法为：clear_keyboard_buffer
几个核心点：
①阻塞与非阻塞读取键盘缓冲区：clear_keyboard_buffer
②显示信息的组织与存储（不采用data段，而直接放在code段中）
③CMOS RAM的读取与修改
④在时间显示时，按键只F1、ESC键有效，其它键无效，也不影响键盘缓冲区与下次读取（程序中解决的基本问题，但没有解决个别键的影响问题）

;2017年5月13日16:18:14
;Mail:mailbox_krj@163.com
;Author:KangRuoJin
;Version:v1.2

assume cs:code,ss:stack

stack segment
    db 128 dup (0)
stack ends

code segment
start:
    mov bx,stack
    mov ss,bx
    mov sp,128

    call copy_boot

    mov bx,0
    push bx
    mov bx,7E00H
    push bx
    retf    ;跳转到0:7E00H开始执行

mov ax,4C00H
int 21H
;================================================================
boot:
    jmp boot_start
;*******************************************************************************************
    MENU_1  db 'Weclome to System of Mr.Kang',0
    MENU_2  db '(1) Reset PC',0
    MENU_3  db '(2) Start System',0
    MENU_4  db '(3) ShowClock',0
    MENU_5  db '(4) Set Clock',0
    MENU_6  db 'Please Enter Your Choose(1~4):',0

    MENU_ADDRESS    dw offset MENU_1 - offset boot + 7E00H
                    dw offset MENU_2 - offset boot + 7E00H
                    dw offset MENU_3 - offset boot + 7E00H
                    dw offset MENU_4 - offset boot + 7E00H
                    dw offset MENU_5 - offset boot + 7E00H
                    dw offset MENU_6 - offset boot + 7E00H
    time    db 'YY/MM/DD hh:mm:ss',0
    cmos    db 9,8,7,4,2,0
    clockone    db 'press F1 to change the color, press ESC to return',0
    clock2  db 'Please input Date and Time,(YY MM DD hh mm ss):',0
    change  db 12 dup (0),0
;*******************************************************************************************
boot_start:
    call init_reg ;ds、es寄存器初始化
    call clear_screen ;清屏与屏幕初始化（包括边框显示）
    call show_menu ;显示menu菜单
    jmp choose_option ;开始进入选择的循环中去
mov ax,4C00H
int 21H
;================================================================
choose_option:
    call clear_keyboard_buffer  ;清除键盘缓冲区
    mov ah,0
    int 16H

    cmp al,'1'
    je choose_option_one
    cmp al,'2'
    je choose_option_two
    cmp al,'3'
    je choose_option_three
    cmp al,'4'
    je choose_option_four
    jmp choose_option
;================================
choose_option_one:               
jmp choose_option                

choose_option_two:               
jmp choose_option                

choose_option_three:             
    call ShowClock               
jmp boot_start          ;跳回到boot_start清屏，并重新显示                

choose_option_four:    
    call SetClock
jmp boot_start     
;=================================================================
SetClock:
    call init_reg           ;寄存器初始化
    call clear_screen       ;清屏并重新画边框
    call clear_change_stack ;清空存放修改内容的栈缓冲区

    ;设置显示提示信息的位置为10行15列开始
    mov di,160*10+15*2
    mov si,offset clock2 - offset boot + 7E00H
    call show_line
    ;显示修改缓冲区中的内容
    mov di,160*12+30*2      
    mov si,offset change - offset boot + 7E00H
    call show_line

    call get_string
    call set_CMOSRAM
ret
;=================================================================
set_CMOSRAM:
    mov bx,offset cmos - offset boot + 7E00H
    mov si,offset change - offset boot + 7E00H
    mov cx,6

    ChangeMessage:   ;GetMessage的逆过程
        push cx

        mov dx,ds:[si]
        sub dx,3030H
        mov cl,4
        shl dl,cl
        and dh,00001111B
        or dl,dh

        mov al,ds:[bx]
        out 70H,al    ;将al送入地址端口70h
        mov al,dl
        out 71H,al ;    将数据写入CMOSRAM时钟

        inc bx
        add si,2
        pop cx
    loop ChangeMessage
ret
;================================================================= 
get_string:
    mov si,offset change - offset boot + 07E00H
    mov bx,0
getSting:
    mov ah,0
    int 16H
    cmp al,'0'  ;判断是否是小于‘0’
    jb noNumber
    cmp al,'9'  ;判断是否大于'9'
    ja noNumber
    call char_push
    cmp bx,12
    ja EnterKey         ;超过输入范围就不允许再输，直接结束
    mov di,160*12+30*2  ;与SetClock中，显示修改缓冲区中的内容位置相对应
    call show_line
    jmp getSting
noNumber:
    cmp ah,0EH  ;退格通码
    je BackspaceKey
    cmp ah,1CH  ;回车通码
    je EnterKey
    jmp getSting
BackspaceKey:
    call char_pop
    mov di,160*12+30*2  ;与SetClock中，显示修改缓冲区中的内容位置相对应    
    call show_line
    jmp getSting
EnterKey:
ret
;=================================================================
char_push:
    cmp bx,12
    ja char_push_over ;大于12则不再入栈，直接返回
    mov ds:[si+bx],al ;入栈
    inc bx
    char_push_over:
ret
char_pop:
    cmp bx,0
    je char_pop_over
    dec bx
    mov byte ptr ds:[si+bx],'*'
    char_pop_over:
ret
;=================================================================      
clear_change_stack:
    push bx
    push cx

    mov bx,offset change - offset boot + 7E00H
    mov cx,6            
    ClearChangeStack:
        mov word ptr ds:[bx],'**'
        add bx,2
    loop ClearChangeStack

    pop cx
    pop bx
ret
;=================================================================
ShowClock:
    call init_reg           ;寄存器初始化
    call clear_screen       ;清屏并重新画边框
    mov di,14*160+15*2      ;设置显示提示信息的位置为14行15列开始
    mov si,offset clockone - offset boot + 7E00H
    call show_line  ;显示

    ShowClockStart:
        call GetTimeMessage     ;获取时间信息放到time中去
        mov di,10*160+30*2      ;设置显示时间与日期的位置为10行30列开始
        mov si,offset time - offset boot + 7E00H
        call show_line          ;按规则显示

        ;这里的读取键盘缓冲区是自己完成，我们亦可以在
        mov ah,1        ;非阻塞式读取，由于是非阻塞读取，当读取到之后，缓冲区不会清空
        int 16H
        jz ShowClockStart
        cmp ah,3BH
        je ChangeColor
        cmp al,1BH      ;ESC扫描码为1，与设定的功能号有冲突，所以用ASCII码
        je ReturnToMainMenu
        cmp al,0        ;能到达这一步说明不为F1也不为ESC
        jne ClearKeyBuffer  ;但是不为0说明一定是有键盘中断产生，就要清除无用的键盘中断
    jmp ShowClockStart
;================================
ChangeColor:                    ;改变颜色
    call ChangeShowColor
ClearKeyBuffer:
    call clear_keyboard_buffer  ;清除非阻塞读取时未清空的缓冲区
    jmp ShowClockStart
ReturnToMainMenu:               ;退回到choose_option时会清除缓冲区，所以这里不需要清除缓冲区
ret
;================================================================
GetTimeMessage:
    mov cx,6
    mov bx,offset cmos - offset boot + 7E00H
    mov si,offset time - offset boot + 7E00H
    GetMessage:   
        push cx
        mov al,ds:[bx]

        out 70H,al    ;将al送入地址端口70h
        in al,71H ;从数据端口71h处读出单元内容
        mov ah,al
        mov cl,4
        shr al,cl ;右移4位
        and ah,0FH    ;al分成两个表示BCD码值的数据
        add ax,3030H  ;BCD码+30h=10进制数对应的ASCII码

        mov word ptr ds:[si],ax     ;ASCII码写入time段
        inc bx
        add si,3
        pop cx
    loop GetMessage
ret
;================================================================
ChangeShowColor:
    push bx
    push cx

    mov cx,2000
    mov bx,1
    loopChangeShowColor:
        add byte ptr es:[bx],1
        or byte ptr es:[bx],00001000B       ;高亮不闪烁设置
        and byte ptr es:[bx],10001111B      ;背景一直为黑色
        add bx,2
    loop loopChangeShowColor

    pop cx
    pop bx
ret
;================================================================
clear_keyboard_buffer:
    mov ah,1
    int 16H         ;修改了ax，所以ZF可能会改变

    jz ClearKeyboardBufferOver  ;如果非阻塞读取的数据为0则结束
    mov ah,0        ;否则，则继续用阻塞的方式清除一次缓冲区字节
    int 16H
    jmp clear_keyboard_buffer
    ClearKeyboardBufferOver:
ret
;================================================================
init_reg:
    mov bx,0B800H
    mov es,bx
    mov bx,0
    mov ds,bx
ret
;================================================================
clear_screen:
    mov bx,0
    mov cx,2000
    mov dx,1F00H    ;黑屏白字
    ClearScreen:
        mov es:[bx],dx  
        add bx,2
    loop ClearScreen

    mov bx,6*160+10*2
    mov cx,60
    clear_showframe_UpandDown:
        mov byte ptr es:[bx],'#'
        mov byte ptr es:[bx+160*9],'#'
        add bx,2
    loop clear_showframe_UpandDown

    mov bx,7*160+10*2
    mov cx,8
    clear_showframe_LeftandRight:
        mov byte ptr es:[bx],'#'
        mov byte ptr es:[bx+59*2],'#'
        mov byte ptr es:[bx+2],'#'
        mov byte ptr es:[bx+59*2-2],'#'
        add bx,160
    loop clear_showframe_LeftandRight

ret
;================================================================
show_menu:
    mov bx,offset MENU_ADDRESS - offset boot + 7E00H
    mov di,160*8 + 25*2
    mov cx,6
    ShowMenu:   
        mov si,ds:[bx]  ;获取输出行信息的偏移地址
        call show_line  ;给定显示的位置显示一行
        add bx,2        ;获取下一条内容的地址
        add di,160      ;输出到下一行
    loop ShowMenu
ret
;================================================================
show_line:
    push ax
    push si
    push di
ShowLineStart:
    mov al,ds:[si]  ;获取一个字符
    cmp al,0        ;遇到0则输出结束
    je ShowLineOver
    mov es:[di],al  ;遇到的不是0则输出到显示屏上
    add di,2
    inc si
    jmp ShowLineStart
ShowLineOver:
    pop di
    pop si
    pop ax
ret
;================================================================
boot_end:nop
;================================================================
copy_boot:  ;将代码段复制到0:7E00H处（正式的写法都需要将代码放到内存中去）
    mov bx,cs
    mov ds,bx
    mov si,offset boot

    mov bx,0
    mov es,bx
    mov di,7E00H
    mov cx,offset boot_end - offset boot
    cld
    rep movsb
ret
;================================================================
code ends
end start

测试环境：VMWare Workstation 下的WINOWS XP（WINDOWS 8.1下的DOSBOX中去修改CMOS RAM的内容会无效，即选项4测试不成功）。
测试截图：
（1）、主界面：
这里写图片描述

（2）、时间显示：
这里写图片描述

（3）、F1键改变颜色：
上图也是按F1键改变颜色后的截图（总共有000~111的八种颜色切换）
这里写图片描述

这里写图片描述
（4）、设置日期与时间：
这里写图片描述
可以看到，我们修改的时间成功了：
这里写图片描述

Apollon_krj
关注
  • 8
    点赞
  • 踩
  • 6
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
王爽 汇编语言第二版 课程设计2
01-20 2499
王爽汇编语言 课程设计2 掌握一门编程语言最重要的就是实践，王爽老的师的课程设计二，如果完整写出来要400行至800行代码，独立完成这个课程设计，会使你熟练16位汇编，掌握8086汇编精髓。这个课程设计不方便调试，独立完成的话要费一点时间，也许你会认为汇编已经过时了，没有必要浪费时间认真学，但是学习汇编语言，是解理计算机原理的捷径，汇编语言是万国语言的基础。如果只懂高级语言，那么只能做人家设计好...
王爽《汇编语言》课程设计2（不涉及软盘版本）
weixin_41944412的博客
06-24 987
assume cs:code,ds:data,ss:stack stack segment db 128 dup (0) stack ends data segment db 256 dup (0) data ends code segment start: mov ax,stack mov ss,ax mov sp,128 ...
DOS命令(7) BIOS密码破解
liuminofhengyang的专栏
10-26 1206
<br />“CMOS密码”就是通常所说的“开机密码”，主要是为了防止别人使用自已的计算机，设置的一个屏障。  <br /><br />“CMOS密码”破解方法很多，主要有以下几种：  <br /><br />一、更改硬件配置  <br />　　 当丢失CMOS密码时，你可以先试着改动机器的硬件后再重新启动，因为启动时如果系统发现新的硬件配置与原来的硬件配置不相同，可能会充许你直接进入 CMOS重新设置而不需要密码。改动硬件配置的方法很简单：比如拔去一根内存条或安装一块不同型号的CPU（当然要主板支持）、更
王爽老师版汇编语言课程设计2
我真的睡不够
07-20 766
一、虚拟环境架设 1、安装虚拟机VM6.03（vmware） 2、创建虚拟机，客户机操作系统类型“其它”MS－DOS，用光盘镜像安装DOS622。 下载地址http://205.196.120.225/1ycwwydjjw1g/00007135820/filefront/dos6.22.iso.rar 3、使用WinImage工具，创建一张1.44M的软盘IMG文件，并加载到虚拟机的软驱中，做为实验软盘。 二、编写代码及测试 注意环节 1、代码长...
王爽汇编课程设计2
03-03
完全自我独立完成的王爽汇编语言课程设计2，虽然自我比较满意，比较完整，可以给初学者一个参考，大虾们也可提提建议。 （本程序在Virtual PC 上通过，杀毒软件提示病毒，但具体原因你知道的，请不要担心）
汇编语言第三版王爽课程设计2
01-02
本程序基本实现了该课程设计的要求，可能还存在一些问题，有待改善
王爽《汇编语言》课程设计2源程序.asm
08-25
王爽《汇编语言》课程设计2源程序.asm。测试环境：VMware创建XP虚拟机和软盘镜像，运行编译后的可执行文件.exe。重启XP虚拟机查看效果。
《汇编语言第4版王爽》全部检测点、实验任务与课程设计答案
08-23
除此之外还包含学习笔记（PDF版和GoodNotes5版），DOSBox0.74-3入门教程以及汇编环境搭建教程，功能强大的文本编辑器UE(支持官网更新)，教材用到的所有文件以及汇编常用文件，例如masm5.0/debug.exe/link.exe/tc2.0....
王爽汇编语言学习课程工具资料
最新发布
08-20
汇编语言是一种低级程序设计语言，它与机器语言密切相关，但比机器语言更易读、易写。通过学习汇编语言，我们可以了解到计算机指令集的基本结构，掌握如何直接控制硬件资源。《汇编语言王爽(第2版)》课后答案为读者...
王爽汇编语言第二版答案.docx
07-01
王爽汇编语言第二版答案 王爽汇编语言第二版答案文档是一个非常有价值的参考资源，对于学习汇编语言的学生和爱好者来说非常重要。本文档包含汇编语言第二版课中的每一处“检测点”、“实验题”的答案，并且每一道...
王爽汇编中课程设计2
08-18
王爽的课程设计2，很好的可以参考。我试过了，正确通过
王爽汇编语言(第二版)
05-12
《王爽汇编语言(第二版)》是学习汇编语言的经典教材，它深入浅出地介绍了计算机系统的基础知识和汇编语言编程技术。这本书主要分为几个部分，涵盖了从基本概念到高级应用的广泛内容。 首先，书中从计算机硬件结构...
汇编语言课程设计2完整代码及详细解析、动态显示时间
shaco_的博客
04-22 2557
汇编语言课程设计2完整代码及详细解析 建议先自己思考问题的答案,不懂则返回看书 此代码在DOSBox下的运行结果截图：
汇编语言 — 课程设计2 — （二）重启计算机及引导现有操作系统
zorro_z的博客
01-11 550
上一次完成了安装程序以及页面展示的代码编写，这次开始进行功能开发，本次开发前两个功能，分别是重新启动计算机以及引导现有的操作系统。 这次是在上次的代码基础上进行功能开发，不过，代码上有所调整，添加了引导程序，为什么会这么做？下面会进行说明。 首先给出调整后的代码，功能和（一）篇的内容一样，都是安装程序以及页面欢迎信息展示，不同的是添加了引导程序，以及将任务程序写入了 2 扇区。 boot segment ; 将软盘中0道0...
王爽 汇编语言 课程设计2 修正
LongSky的专栏
10-07 1943
;本程序在VMWARE中调试通过,可以写入软盘,并正常执行;可以使用Bochs 但是操作细节比较复杂;程序界面不够友好;程序的切换方式是 ESC 注意不要进入时间设置就退不出来了.;在时间设置界面没有设置提示语句,进去就是黑屏幕,不过只要输入数字就会显示.注意输入 的;数字的大小,世界上没有24:00:00以后的时间.我也懒得去判断输入了.;输入后按回车或者超过6个有效 数字,程序会自动设置时间,
王爽汇编语言学习课程设计2
liuxiaozhi123的博客
06-23 407
assume cs:code code segment start: ;//////////////////////////////////// ;安装到软盘 mov ax,cs mov es,ax mov bx,offset softset mov al,1 mov ch,0 mov cl,1 mov dl,0 mov dh,0 mov ah,3 int 13h mov bx,offset subs ;// mov al,2 mov ch,0 mov cl,2 mov dl,0 mov
王爽 -- 汇编语言课程设计2一些问题记录
grantxx的专栏
06-20 9576
整体程序通过重写19号中断例程实现。在19号中断例程中调用不同的子程序，实现不同的功能。 1.动态显示时间的子程序        通过循环读取cmos中的时间信息实现动态显示时间。显示过程中还要实现对F1和esc键做出相应动作。但是，不能用16h号中断来获得相应的键，然后做相应的动作。因为要动态显示时间，必须要循环读取cmos中的时间。在循环中放入读取键盘输入的16h中断，当键盘输入缓冲区为空
王爽汇编语言课程设计1
06-11
王爽的汇编语言课程设计1是一道比较经典的大学汇编语言课程设计题目，其内容为实现一个简单的计算器程序。该程序的功能要求如下： 1. 实现加、减、乘、除四则运算。 2. 实现二进制、十进制、十六进制之间的转换。 ...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值