Spy++原理初探(VB篇)

Spy++原理初探

南京 阿珊境界

下载源代码 

API函数,就会提到句柄,像SendMessage, GetWindowText等,最常用到的参数就是句柄。啥是句柄呢?就是窗口的锅把儿,你拎着它,整个锅儿都听你的话。那啥是窗口呢?不仅仅指我们常说的窗体Form,还包括所有控件,如文本框,按钮,复选框等等。这些句柄怎么获取呢?用Spy++呀。本文中,笔者就和您一起打造一个VB版的Spy++。(笔者以前写过一篇VC版的Spy++,得到了许多网友的关注,所以撰写此文,以飨VB战壕的朋友们。)

 

一.         界面设计

新建EXE工程,在窗体frmMain上画一个PictureBoxpicShot),用以装载探测器的靶形图标;画两个CheckBoxchkAlwaysOnTopchkHex)用于选择窗口是否在最上面和句柄等值的返回形式是否为十六进制。

再下面是选项卡控件,我们有两种选择。一种是用Microsoft Windows Common Controls6.0(mscomctl.ocx)中的TabStrip,这种控件的用法与VC中类似,标签页不可以在主窗体设计时直接做,而是要画N个子窗体或PictureBox,然后在运行时按情况调用;第二种选择是Microsoft Tabbed Dialog Control6.0(tabctl32.ocx),这个控件可以直接在上面设计每个标签页,我们就选择它。

把选项卡控件命名为SSTab1,通过其属性页设置好各标签页的标题为“常规”、“样式”、“类”、“窗口”和“消息”。程序界面设计如图。

   

二、探测器制作

准备好两个图标(ico)和一个鼠标指针(cur)文件,分别用于正常状态下的显示、鼠标拖出时的显示以及拖出时的鼠标指针;正常状态下显示一幅有靶的图标。当鼠标在上面按下时,显示内容立刻换为另一幅无靶的图标,同时鼠标指针变为靶状。这样,就给人一种靶心被拖出去的感觉了。通过上面的叙述,我们了解到图片框需要响应MouseDownMouseUp事件。而鼠标左键松开处一般不会在图片框上,所以,要想让图片框的MouseUp来响应,我们要用到一个API函数:SetCapture。这个函数用以对鼠标事件的捕获,我们在图片框的MouseDown事件中SetCapture后,以后即使鼠标指针离开图片框,发生的事件也是由图片框(或指定窗口)来处理。其API函数声明自己用API浏览器查,不再赘述。需强调的是,在MouseUp事件中别忘了释放捕获(另一个APIReleaseCapture)。在鼠标按下时,还涉及到换图标换指针等操作,代码如下:

Private Sub picShot_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)

    Screen.MousePointer = vbCustom

    Screen.MouseIcon = Image1.Picture     '用鼠标指针变为靶状

    picShot.Picture = Image2.Picture     '此时图片框加载另一无靶图标

    '将以后的鼠标输入消息都发送到图片框窗口

    SetCapture (picShot.hWnd)

End Sub

Private Sub picShot_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)

    Screen.MousePointer = vbDefault

    picShot.Picture = Image3.Picture

    ReleaseCapture

End Sub

获取窗口句柄。根据鼠标位置来确定窗口需要用到API函数GetCursorPosWindowFromPoint。此外,我们还想做到像抓图程序那样,鼠标移动到的地方,窗口四周会出现闪烁的矩形。这一点,我们用定时器来实现。在桌面背景上绘图,大致过程如下:用GetDesktopWindow()获取桌面句柄,再用GetWindowDC()获得设备场景(或叫设备上下文)。啥叫设备场景?就当成是画布吧,要画画嘛,就要找找到窗口对应的画布。还有用到一个SetROP2(),用以“设定当前前景色的混合模式”(从MSDN中直译,如果觉得不通,请看MSDN原文),这里采用R2_NOTXORPEN混合模式(其值为10),载入一支反色画笔。GetWindowRect()用以获得窗口的矩形,Rectangle()函数用于画这个矩形,ReleaseDC用于释放设备场景。实现代码如下:

Private Sub tmr_Timer()

    ……Dim XXX……..

    DeskHwnd& = GetDesktopWindow()    '取得桌面句柄

    DeskDC& = GetWindowDC(DeskHwnd&)     '取得桌面设备场景

    oldRop2& = SetROP2(DeskDC&, 10)

    GetCursorPos pnt                '取得鼠标坐标

    PointText.Text = Str(pnt.X) & "," & Str(pnt.Y)

    UnHwnd = WindowFromPoint(pnt.X, pnt.Y)     '取得鼠标指针处窗口句柄

    grayHwnd = GetWindow(UnHwnd, GW_CHILD)

'因为WindowsFromPoint函数对Disabled的窗口无效,所以写了下面这个循环,否则无法选中“灰色按钮”类窗口

    Do While (grayHwnd)

        GetWindowRect grayHwnd, tempRc

        If PtInRect(tempRc, pnt.X, pnt.Y) Then

            FindIt = True

            Exit Do

        Else

            grayHwnd = GetWindow(grayHwnd, GW_HWNDNEXT)

        End If

    Loop

    If FindIt = True Then

        FindIt = False

        SnapHwnd = grayHwnd

    Else

        SnapHwnd = UnHwnd

    End If

    GetWindowRect SnapHwnd, rc        '获得窗口矩形

    If rc.Left < 0 Then rc.Left = 0

    If rc.Top < 0 Then rc.Top = 0

    If rc.Right > Screen.Width / 15 Then rc.Right = Screen.Width / 15

    If rc.Bottom > Screen.Height / 15 Then rc.Bottom = Screen.Height / 15

    newPen& = CreatePen(0, 3, &H0)       '建立新画笔,载入DeskDC

    oldPen& = SelectObject(DeskDC, newPen)

    Rectangle DeskDC, rc.Left, rc.Top, rc.Right, rc.Bottom  '在指示窗口周围显示闪烁矩形

    Sleep tmr.Interval    '设置闪烁时间间隔

    Rectangle DeskDC, rc.Left, rc.Top, rc.Right, rc.Bottom

 

    SetROP2 DeskDC, oldRop2

    SelectObject DeskDC, oldPen

    DeleteObject newPen

ReleaseDC DeskHwnd, DeskDC:

DeskDC = 0

End Sub

三、两个复选框

复选框“总在最上面”用到的API函数是SetWindowPos()。由于比较直观,读者朋友直接看下面代码:

Private Sub chkalwaysontop_Click()

    If(chkAlwaysOnTop.Value= 1)

        SetWindowPos(g_hWnd,HWND_TOPMOST,0,0,0,0,SWP_NOMOVE | SWP_NOSIZE)

    Else

SetWindowPos(g_hWnd,HWND_NOTOPMOST,0,0,0,0,SWP_NOMOVE|SWP_NOSIZE)

    End If

End Sub

第二个复选框决定返回值以16进制还是10进制显示,这对咱VB兄弟很有用,因为我们VB习惯使用的不是16进制。这里我们建立一个全局函数,根据复选框的不同状态有不同的返回值,代码如下:

Function DisplayNum(Num As Long) As String

    If frmMain.chkHex.Value = 1 Then

        DisplayNum = Hex(Num)

    Else

        DisplayNum = LTrim(Str(Num))

    End If

End Function

四.常规标签页

常规标签页负责显示窗口句柄、窗口类名、标题文本、窗口矩形、窗口ID、进程ID和程序路径。获取窗口句柄在第一部分已经介绍,下面介绍一下获取类名和标题文本等。以一个过来人的身分,我回忆我在上世纪90年代末对API一直似懂非懂,对API使用前的一系列代码更是莫名其妙,最后因为查不到资料也就照葫芦画瓢难得糊涂了。直到新世纪来临(夸张啦……),开始学习并使用C++,搞Windows编程,才觉得豁然开朗,明白了以前不曾想通的东西。这里,我以获取类名为例,仔细说明一下用法。先看代码:

    Dim tempstr As String, strlong As Long, rtn As Long

    '获得该窗口的类型并显示在WndClassText文本框中

    tempstr = String(255, Chr$(0))

    strlong = Len(tempstr)

    rtn = GetClassName(SnapHwnd, tempstr, strlong)

    If rtn = 0 Then Exit Sub

tempstr = Left(tempstr, InStr(tempstr, Chr$(0)) - 1)

WndClassText.Text = tempstr

下面解释一下代码。我们习惯于用函数返回值来获取所要的结果,但API中经常用参数来带回所要结果。在这类参数的API声明中会见到ByVal传值关键字。首先给tempstr赋一个长度为255的字符串,其中字符均为空字符(即ASCII码为0的字符,vbNullChar)。它的作用是分配缓存,以备将来获取的类名存入。Windows在读取一个字符串时,以遇到第一个空字符为止。为叙述方便,下面以“/0来表示空字符。假设有个字符串是“abcd/0/0/0/0,此时windows读取它时将把它当作“abcd”了。GetClassName()的第一个参数是窗口句柄,第二个参数是缓存地址,第三个参数是缓存大小。在VB中,我们还需要把字符串结尾的空字符去掉(在其他语言中不需要),所以就有了这一句:tempstr = Left(tempstr, InStr(tempstr, Chr$(0)) - 1),字符串中间是不会出现空字符的。在网上的各类代码中,我们还经常见到用tempstr=Space(255)来分配缓存。这样也是可以的,然而获取完之后不能用相同的方法去除尾部空格(因为一但字符串中间有空格怎么办),这里只需用Trim()Rtrim()即可。个人不推荐使用这种分配缓存方式。

下面说一下获取程序路径。获取进程路径的方法有两种。在NT系统中,我们可以用OpenProcess()函数将进程打开后,再利用EnumProcessModules()函数枚举该进程的模块,最后利用GetModuleFileNameEx()函数就能取得该进程的路径;第二种方法是利用ToolHelp API中的相关函数。而后者兼容容Windows9xNT4.0以后系统,所以采取此法。它的实现代码如下:

    Dim ME32 As MODULEENTRY32

    Dim Pid As Long

    GetWindowThreadProcessId hWnd, Pid

    Dim hSnapshot As Long

    hSnapshot = CreateToolhelp32Snapshot(&H8, Pid)

   

    ME32.dwSize = Len(ME32)

    Module32First hSnapshot, ME32

GetAppNameFromHwnd = (Left$(ME32.szExePath, InStr(ME32.szExePath, vbNullChar) - 1))

这代码也太玄乎了……。先别忙倒,这段代码也不是很复杂。只是用到了结构体。提到结构体我们应该不陌生,像定义POINT啊,RECT啊,都用到了结构体。这里的ME32和它一样。获取的东西得存到它里面。就这样。

 

五.样式标签页

 

 

窗口有个样式的概念,如是否可见,是否有边框,是否是子窗口等;不同类型的窗口还有扩展样式的概念,如是否在最上面,是否是MDI窗口等。它们用API函数GetWindowLong来获取,用参数GWL_STYLEGWL_EXSTYLE来区别。

这里我强调的重点是在于,如何把获取的样式和扩展样式以文字的形式列出来。窗口的样式值是固定的几十种,它们以不同的数字来表示。而且,这些数字之间还有玄机。例如有4种样式a=1b=2c=4d=8,如果我获取到的样式值为s=5,那么它一定是1+4而来,也就是具有样式a和样式c,而不可能是2+3或其他组合,因为样式值中根本没23这些数。那么我如何来确定样式s中是否包含a呢?用“位与”操作即可:

If a And s Then ***此时s中包含a***

邪门了,越来越不明白了。为什么And一下就能判断有无呢?这得从二进制来分析。1就是1,而41005101。从101的字面上,你就能一眼看出其包含1(最后一位数)了吧?其第一位数就表示4啦。至于更详细的位操作,请参考位运算的相关知识,或我的另一篇文章《与、或、非在VB中的应用》。下面简单摘抄几行代码:

    lstWndStyle.Clear

    style& = GetWindowLong&(SnapHwnd&, GWL_STYLE)

 

    If style& And WS_BORDER Then

        lstWndStyle.AddItem "WS_BORDER"

    End If

    If style& And WS_CAPTION Then

        lstWndStyle.AddItem "WS_CAPTION"

    End If

    If style& And WS_CHILD Then

        lstWndStyle.AddItem "WS_CHILD"

    End If

    If style& And WS_CLIPCHILDREN Then

        lstWndStyle.AddItem "WS_CLIPCHILDREN"

    End If

    If style& And WS_CLIPSIBLINGS Then

        lstWndStyle.AddItem "WS_CLIPSIBLINGS"

    End If

 

六.类标签页

 

 

类也有类样式的概念,其使用方法与窗口样式类似,所用的函数是GetClassLong()。具体看所附代码。

七.窗口标签页

 

 

该标签页用于显示和当前窗口相关的各窗口信息。其中,获取上一窗口和下一窗口的API函数是GetNextWindow(),用GW_HWNDPREVGW_HWNDNEXT加以区分。获取父窗口的API函数是GetParent(),获取第一子窗口和所有者窗口用的API函数是GetWindow,分别加上参数GW_CHILDGW_OWNER

这个标签页还有一个非常实用的附加功能,就是当相应窗口存在时(如父窗口存在),此标签可以点击。点击后,相关窗口(如父窗口)变为当前窗口,再来重新获取其窗口的一系列数值。标签可以点击表现为两点:一,文本为蓝色;二,鼠标指针移上去即变为小手状。实现代码如下:

    If txtParentHandle.Text = "0" Then

        lblParentHandle.ForeColor = vbBlack

        lblParentHandle.MousePointer = 0

    Else

        lblParentHandle.ForeColor = vbBlue

        lblParentHandle.MousePointer = 99

        lblParentHandle.MouseIcon = imgPointer.Picture

End If

八.消息标签页

 

   

  该页中用一个列表框列出窗口常见样式,并允许用户通过发消息来改变窗口状态。这个列表框的每个列表项前都有一个复选框。实现方法是在List控件中将其Style属性设置为1-Checkbox      这个列表框的作用不仅仅是显示窗口的状态,还要在发生勾选改动时即时改变窗口状态或激发其行为。这里我们选用MouseUp事件来处理勾选改变动作。另外,为了不使一个勾选的改变就引起所有列表项都激发一遍,我们采用Select Case结构,以使哪个列表项被选中就激发哪个列表项。代码如下:

    Select Case lstStatus.ListIndex

    Case 0:

        If lstStatus.Selected(0) = True Then

            ShowWindow SnapHwnd, SW_SHOW

        Else

            ShowWindow SnapHwnd, SW_HIDE

        End If

    Case 1:

        If lstStatus.Selected(1) = True Then

            ' SendMessage SnapHwnd&, WM_ENABLE, 0, vbNullString

            EnableWindow SnapHwnd, True

        Else

            EnableWindow SnapHwnd, False

        End If

    Case 2:

        If lstStatus.Selected(2) = True Then

            SetOnTop SnapHwnd, 1

        Else

            SetOnTop SnapHwnd, 0

        End If

    Case 3:

        If lstStatus.Selected(3) = True Then

            SendMessage SnapHwnd, EM_SETREADONLY, True, 0

        Else

            SendMessage SnapHwnd, EM_SETREADONLY, False, 0

        End If

    Case 4:

        If lstStatus.Selected(4) = True Then

            ShowWindow SnapHwnd, SW_MAXIMIZE

            lstStatus.Selected(5) = False

        Else

            ShowWindow SnapHwnd, SW_RESTORE

        End If

    Case 5:

        If lstStatus.Selected(5) = True Then

            ShowWindow SnapHwnd, SW_MINIMIZE

            lstStatus.Selected(4) = False

        Else

            ShowWindow SnapHwnd, SW_RESTORE

 

        End If

    Case 6:

        If lstStatus.Selected(6) = True Then

            ShowWindow SnapHwnd, SW_RESTORE

            lstStatus.Selected(6) = False

            lstStatus.Selected(5) = False

            lstStatus.Selected(4) = False

        End If

    Case 7:

        If lstStatus.Selected(7) = True Then

            SendMessage SnapHwnd, WM_CLOSE, 0, 0

            lstStatus.Selected(7) = False

        End If

    Case 8:

        If lstStatus.Selected(8) = True Then

            BringWindowToTop SnapHwnd

            lstStatus.Selected(8) = False

 

        End If

End Select

API函数SendMessage()是个好东西,它完美地诠释了Windows这个基于消息驱动的操作系统。它能做很多事。比如文中提到的GetWindowText,我们也可以用发送消息来实现,如下:

lRet& = SendMessage(hWnd, WM_GETTEXT, 255, tempstr)

 

九.结束语

了解C++的朋友或许会嗅出些许C++的气息来。是位运算?是分配缓存?是消息处理?这些都是,甚至还包括代码的书写格式和流行于C++领域的匈牙利命名法。他山之石,可以攻玉,VB学习同样需要外来的血液。VB.net对类概念的强化更说明了这一点。望本文能对各位读者在编程道路上有所帮助。本文内容在Windows XP+VB6中调试通过。欢迎加入VB技术讨论QQ12960265,和众多VB爱好者共同进步。

最后附上两款VB实用工具。第1款《VB6 MouseWheel Fix》,可以使VB6代码编辑器支持鼠标滚轮;第2款《Smart Indent》是一款VB代码格式化工具,用以自动整理VB代码的行缩进等格式。下载地址:http://www.asanscape.com/soft/mwfix.rarhttp://www.asanscape.com/soft/smidt.rar

 

  • 0
    点赞
  • 17
    收藏
    觉得还不错? 一键收藏
  • 5
    评论

“相关推荐”对你有帮助么?

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 5
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值