Email techniques in AX 4.0

最新推荐文章于 2015-04-30 10:36:48 发布

再启动

最新推荐文章于 2015-04-30 10:36:48 发布

阅读量2.3k

点赞数

分类专栏： Dynamics AX 开发文章标签： email class templates parameters dll basic

Dynamics AX 开发专栏收录该内容

100 篇文章 3 订阅

订阅专栏

From: http://sumit-theaxfactor.spaces.live.com/blog/cns!596957786228C73F!208.entry

In this article, I am going to demonstrate different email techniques that can be used in AX 4.0. Following classes can be used to send an email

Mapi and its related classes
SysMailer
SysInetMail
SysEmailBatch
SmmOutlookEmail

MAPI technique:

Following code demonstrates the usage of mapi class for sending email. It uses outlook to send mail.

static void emailThruMapi(Args _args)
{
    MapiEx      mapiEx;
    MapiExMail mapiExMail;
    boolean     mapiInitialised;
    COM         outlook;
    COM         item;
    COM         outlookNameSpace;
    COM         folder;
    COM         attachments;
    str         storeId;
    str         entryId;

    #define.outlookapplication('Outlook.Application')
    #define.mapi('Mapi')
    #smmMSOutlook2002ObjectModelConstants
    #define.htmlText('<html><body>Hi There</body></html>')
    ;

    outlook             = new COM (#outlookapplication);
    outlookNameSpace    = outlook.getNameSpace(#mapi);
    outlookNameSpace.logon();

    folder = outlookNameSpace.getDefaultFolder(#olFolderInbox);
    item = outlook.createItem(#olMailItem);
    storeId = folder.storeId();

    mapiEx = new MapiEx();

    if(mapiEx && mapiEx.mapiInitialised())
    {
        mapiInitialised = true;
        if (!mapiEx.logon("","",0) || !mapiEx.openMessageStore(storeId))
        {
            mapiInitialised = false;
            mapiEx.logout();
            mapiEx.finalize();
        }

        //To send mail in HTML format
        item.bodyFormat(#olFormatHTML);
        item.htmlBody(#htmlText);

        //To send mail in plain text format
        //item.body('Hi There');

        item.subject('Test mail');

        //----Attachements-------------------
        attachments = item.attachments();
        attachments.add('E://Test//4000.pdf', 1, 1, '4000.pdf');

        item.saveSentMessageFolder(outlookNameSpace.getDefaultFolder(#olFolderSentMail));
        item.save();
        entryId = item.entryId();

        mapiExMail = mapiEx.getMailFromEntryId(entryId);
        if (!mapiExMail)
        {
            mapiInitialised = false;
            mapiEx.logout();
            mapiEx.finalize();
        }
    }

    if(item)
    {
        if (mapiInitialised && mapiExMail)
        {
            //TO
            mapiExMail.addRecipient('sumit.loya@sumitloya.com', "", #olTo);
            //CC
            mapiExMail.addRecipient('sreenath.girigari@sreenath.com',"",#olCC);
            //BCC
            mapiExMail.addRecipient('ashish.singh@ashishsingh.com',"",#olBCC);

            try
            {
                mapiExMail.save();
                mapiExMail.close();
                mapiExMail.finalize();
                item = outlookNameSpace.getItemFromID(strupr(entryId));

                //This will display the mail item
                //item.display();

                //This will directly send the mail without poping the mail window
                item.send();
            }
            catch
            {
                if (mapiInitialised)
                {
                    mapiEx.logout();
                    mapiEx.finalize();
                }

                // An error occured sending mail from outlook.
                throw error("@SYS97460");
            }
        }
    }
}

SysMailer:

In the following code you can see how to use SysMailer class for sending mails. To use SysMailer class you need to set Relay server or computer name, user name and password in Administration --> Setup --> Email parameters form. This class internally uses CDO.Message dll for communication purposes. Please note in AX 3.0 SysMailer uses Dundas.Mailer dll for communication.

static void emailThruSysMailer(Args _args)
{
    SysMailer   mailer = new SysMailer();
    SysEmailParameters parameters = SysEmailParameters::find();
    ;

    if (parameters.SMTPRelayServerName)
    {
        mailer.SMTPRelayServer(parameters.SMTPRelayServerName,
                           parameters.SMTPPortNumber,
                           parameters.SMTPUserName,
                           SysEmailParameters::password(),
                           parameters.NTLM);
    }
    else
    {
        mailer.SMTPRelayServer(parameters.SMTPServerIPAddress,
                           parameters.SMTPPortNumber,
                           parameters.SMTPUserName,
                           SysEmailParameters::password(),
                           parameters.NTLM);
    }

    mailer.fromAddress('sumit.loya@sumitloya.com');
    mailer.tos().appendAddress('sumit.loya@sumitloya.com');
    mailer.body('hi');
    mailer.sendMail();
}

SysInetMail:

SysInetMail internally uses Mapi framework only. But to use SysInetMail one has to setup email templates from Basic --> Setup --> Email templates. SysInetMail will automatically pick sender id, subject, sender name, email text etc. from the email template that you provide while sending from SysInetMail. If you provide a full email address and not the id from Email templates table then also mail will be sent but in that case you need to provide the details yourself.

static void emailThruSysInetMail(Args _args)
{
    SysInetMail mail = new SysInetMail();
    ;

    //To send to an email address directly
    mail.sendMailAttach('sumit.loya@sumitloya.com', 'sreenath.girigari@sreenath.com', 'Test mail', 'Hi There', false, 'E://Test//4000.pdf');

    //To use an email template to send mail
    SysInetMail::sendEMail('Alerts', 'en-us', 'sumit.loya@sumitloya.com');
}

SysEmailBatch:

SysEmailBatch internally uses SysMailer class and is used to send emails in batch. That is this class is batchable. Here is a small example for the class

static void emailThruSysEmailBatch(Args _args)
{
    SysEmailBatch   batch = new SysEmailBatch();
    ;

    batch.parmSenderAddr('sumit.loya@solugenix.com');
    batch.parmEmailAddr('sumit.loya@solugenix.com');
    batch.parmMessageBody('Hi There');
    batch.parmSubject('Test mail');
    batch.run();
}

SmmOutlookEmail:

This class internally uses Mapi class and is extensively used in HRM module. One feature of this class is that we can specify email groups and it can send mails to all the members defined under this email group. Here is a sample code

static void emailThruSmmOutlookEmail(Args _args)
{
    SmmOutlookEmail smmOutlookEmail = new SmmOutlookEmail();
    ;

    if (smmOutlookEmail.createMailItem())
    {
        smmOutlookEmail.addEMailRecipient('sumit.loya@sumitloya.com');
        smmOutlookEmail.addSubject('Test mail');
        smmOutlookEmail.isHTML(true);
        smmOutlookEmail.addBodyText('<html><body>Hi There</body></html>');
        smmOutlookEmail.sendEMail(smmSaveCopyOfEmail::No);
    }
}

再启动

关注

0
点赞
踩
1

收藏

觉得还不错? 一键收藏
3
评论
Email techniques in AX 4.0

From: http://sumit-theaxfactor.spaces.live.com/blog/cns!596957786228C73F!208.entryIn this article, I am going to demonstrate different email techniques that can be used in AX 4.0. Following classes
复制链接

扫一扫

专栏目录