EBS调用webservice

最新推荐文章于 2023-03-31 15:59:43 发布
最新推荐文章于 2023-03-31 15:59:43 发布
阅读量723 收藏
点赞数
分类专栏： # 常用sql和技巧 文章标签： sql oracle
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/biqidaoer/article/details/128408487
版权

EBS调用外部系统webservice服务，传递报文的程序包。

包头

CREATE OR REPLACE PACKAGE Xxcus_Int_Set_Send_Pkg IS
  -- Author  : BRAYDEN.LIU
  -- Created : 2021/11/5 15:21:15
  -- Purpose : 
  --发送http报文,会被频繁调用，需要独立出来避免锁
  PROCEDURE Send_Http(p_Access_Token    IN VARCHAR2
                     ,p_Url             IN VARCHAR2
                     ,p_Http_Request    IN CLOB
                     ,p_Method          IN VARCHAR2 DEFAULT 'POST'
                     ,p_Http_Timeout    IN NUMBER DEFAULT NULL
                     ,p_Http_Proxy      IN VARCHAR2 DEFAULT NULL
                     ,p_Content_Type    IN VARCHAR2 DEFAULT NULL
                     ,p_Wallet_Path     IN VARCHAR2 DEFAULT NULL
                     ,Lv_Password       IN VARCHAR2 DEFAULT NULL
                     ,p_Wallet_Password IN VARCHAR2 DEFAULT ''
                      --,p_Auth_String     IN VARCHAR2 DEFAULT NULL
                     ,x_Http_Response  OUT NOCOPY CLOB
                     ,x_Return_Status  OUT NOCOPY VARCHAR2
                     ,x_Return_Message OUT NOCOPY VARCHAR2);

  PROCEDURE Send_Rest(Pv_Url           IN VARCHAR2
                     ,p_Http_Timeout   IN NUMBER DEFAULT NULL
                     ,p_Http_Request   IN CLOB
                     ,x_Http_Response  OUT NOCOPY CLOB
                     ,x_Return_Status  OUT NOCOPY VARCHAR2
                     ,x_Return_Message OUT NOCOPY VARCHAR2);

  FUNCTION Get_Url(Pv_Intsys_Code IN VARCHAR2) RETURN VARCHAR2 Result_Cache;

  PROCEDURE Send_Interface(Pv_Intsys_Code   IN VARCHAR2
                          ,p_Http_Timeout   IN NUMBER DEFAULT NULL
                          ,p_Http_Request   IN CLOB
                          ,x_Http_Response  OUT NOCOPY CLOB
                          ,x_Return_Status  OUT NOCOPY VARCHAR2
                          ,x_Return_Message OUT NOCOPY VARCHAR2);

END Xxcus_Int_Set_Send_Pkg;

包体

CREATE OR REPLACE PACKAGE BODY Xxcus_Int_Set_Send_Pkg IS

  PROCEDURE Log(Pv_Message IN VARCHAR2) IS
  BEGIN
    Dbms_Output.Put_Line(Pv_Message);
    Fnd_File.Put_Line(Fnd_File.Log, Pv_Message);
  END Log;

  PROCEDURE Log(Pv_Message IN CLOB) IS
    Ln_Long   NUMBER := 1000; --读取长度
    Ln_Start  NUMBER := 1; --开始读取位置
    Ln_Length NUMBER;
    Lv_Str    VARCHAR2(2000);
  BEGIN
    Ln_Length := Dbms_Lob.Getlength(Pv_Message);
    FOR i IN 1 .. Ceil(Ln_Length / Ln_Long) LOOP
      Ln_Start := (1 + Ln_Long * (i - 1));
      Dbms_Lob.Read(Pv_Message, Ln_Long, Ln_Start, Lv_Str);
      Dbms_Output.Put_Line(Lv_Str);
      Fnd_File.Put_Line(Fnd_File.Log, Lv_Str);
      Ln_Long := Least(Ln_Long, (Ln_Length - Ln_Long));
    END LOOP;
    Dbms_Output.Put_Line(' ');
  
  END Log;

  --发送http报文
  PROCEDURE Send_Http(p_Access_Token    IN VARCHAR2
                     ,p_Url             IN VARCHAR2
                     ,p_Http_Request    IN CLOB
                     ,p_Method          IN VARCHAR2 DEFAULT 'POST'
                     ,p_Http_Timeout    IN NUMBER DEFAULT NULL
                     ,p_Http_Proxy      IN VARCHAR2 DEFAULT NULL
                     ,p_Content_Type    IN VARCHAR2 DEFAULT NULL
                     ,p_Wallet_Path     IN VARCHAR2 DEFAULT NULL
                     ,Lv_Password       IN VARCHAR2 DEFAULT NULL
                     ,p_Wallet_Password IN VARCHAR2 DEFAULT ''
                      --,p_Auth_String     IN VARCHAR2 DEFAULT NULL
                     ,x_Http_Response  OUT NOCOPY CLOB
                     ,x_Return_Status  OUT NOCOPY VARCHAR2
                     ,x_Return_Message OUT NOCOPY VARCHAR2) IS
    Http_Req  Utl_Http.Req;
    Http_Resp Utl_Http.Resp;
  
    l_Pos  NUMBER := 1;
    l_Leng NUMBER := 0;
  
    TYPE Rec_Req IS RECORD(
       p_Req VARCHAR2(4000));
    TYPE Rec_Req_Array IS TABLE OF Rec_Req INDEX BY BINARY_INTEGER;
    l_Res_Line  VARCHAR2(32767);
    l_Req_Array Rec_Req_Array;
    l_End_Flag  VARCHAR2(1);
    l_Uuid      VARCHAR2(100);
    l_Guid      VARCHAR2(100);
    l_Auth      VARCHAR2(100);
    l_Db_Name   VARCHAR2(100);
    l_Password  VARCHAR2(100);
  
    Lc_Http_Response CLOB;
  BEGIN
  
    x_Return_Status := Fnd_Api.g_Ret_Sts_Success;
    --Log('Send_Http:' || p_Http_Request);
  
    BEGIN
      SELECT Upper(Instance_Name)
        INTO l_Db_Name
        FROM V$instance;
    EXCEPTION
      WHEN OTHERS THEN
        l_Db_Name := 'EBSDEV';
    END;
  
    IF Lv_Password IS NULL THEN
      IF l_Db_Name = 'PROD' THEN
        l_Password := 'ERP:4cDQ8$*M';
      ELSE
        l_Password := 'ERP:ERP123456';
      END IF;
    
    ELSE
      l_Password := Lv_Password;
    
    END IF;
  
    IF p_Wallet_Path IS NOT NULL THEN
      Utl_Http.Set_Wallet(Path => p_Wallet_Path, Password => p_Wallet_Password);
    END IF;
  
    IF p_Http_Timeout IS NOT NULL THEN
      Utl_Http.Set_Transfer_Timeout(p_Http_Timeout);
    ELSE
      Utl_Http.Set_Transfer_Timeout(600);
    END IF;
  
    IF p_Http_Proxy IS NOT NULL THEN
      Utl_Http.Set_Proxy(p_Http_Proxy);
    END IF;
  
    IF p_Http_Request IS NOT NULL THEN
      FOR i IN 1 .. Ceil(Dbms_Lob.Getlength(p_Http_Request) / 2400) LOOP
        l_Req_Array(i).p_Req := Dbms_Lob.Substr(p_Http_Request, 2400, l_Pos);
      
        l_Pos  := l_Pos + 2400;
        l_Leng := l_Leng + Lengthb(l_Req_Array(i).p_Req);
      END LOOP;
    END IF;
    --self.log('开始发送http请求');
    Utl_Http.Set_Body_Charset('UTF-8');
  
    Http_Req := Utl_Http.Begin_Request(p_Url, p_Method, 'HTTP/1.1');
  
    IF p_Access_Token IS NOT NULL THEN
      Utl_Http.Set_Header(r     => Http_Req
                         ,NAME  => 'Authorization'
                         ,VALUE => 'Bearer ' || p_Access_Token);
    END IF;
  
    --ESB第二版规范要求
    l_Guid := Lower(Rawtohex(Sys_Guid()));
    l_Uuid := Substr(l_Guid, 1, 8) || '-' || Substr(l_Guid, 9, 4) || '-' || Substr(l_Guid, 13, 4) || '-' ||
              Substr(l_Guid, 17, 4) || '-' || Substr(l_Guid, 21, 12);
  
    --生成BASIC认证信息，规则"Basic"+"空格"+“Base64(用户名+英文冒号+密码)”
    l_Auth := Utl_Raw.Cast_To_Varchar2(Utl_Encode.Base64_Encode(Utl_Raw.Cast_To_Raw(l_Password)));
    l_Auth := 'Basic ' || l_Auth;
    --在HTTP协议头增加四个集成平台要求字段
    Utl_Http.Set_Header(Http_Req, 'reqFrom', 'ERP'); --服务消费方ID
    Utl_Http.Set_Header(Http_Req, 'Authorization', l_Auth); --认证字段，HttpBasic认证头信息
    Utl_Http.Set_Header(Http_Req, 'reqTime', ''); --提交时间
    Utl_Http.Set_Header(Http_Req, 'reqId', l_Uuid); --实例ID
    --END 第二版规范
    --self.log('1');
    Utl_Http.Set_Header(Http_Req
                       ,'Content-Type'
                       ,Nvl(p_Content_Type, 'application/xml; charset=UTF-8'));
    Utl_Http.Set_Header(Http_Req, 'Content-Length', l_Leng);
    IF p_Http_Request IS NOT NULL THEN
      FOR i IN 1 .. Ceil(Dbms_Lob.Getlength(p_Http_Request) / 2400) LOOP
        Utl_Http.Write_Text(Http_Req, l_Req_Array(i).p_Req);
      END LOOP;
    END IF;
    Http_Resp := Utl_Http.Get_Response(Http_Req);
  
    Dbms_Output.Put_Line(Http_Resp.Reason_Phrase || '' || Http_Resp.Http_Version);
    Dbms_Lob.Createtemporary(Lc_Http_Response, FALSE);
    BEGIN
      LOOP
        l_Res_Line := NULL;
        Utl_Http.Read_Text(Http_Resp, l_Res_Line, 800);
      
        Dbms_Lob.Writeappend(Lc_Http_Response, Length(l_Res_Line), l_Res_Line);
      END LOOP;
    EXCEPTION
      WHEN Utl_Http.End_Of_Body THEN
        l_End_Flag := 'Y';
        Utl_Http.End_Response(Http_Resp);
    END;
  
    x_Http_Response := Lc_Http_Response;
    IF Nvl(l_End_Flag, 'N') <> 'Y' THEN
      Utl_Http.End_Response(Http_Resp);
    END IF;
    --Log('send_http send success!!!');
  EXCEPTION
    WHEN OTHERS THEN
      x_Return_Status  := Fnd_Api.g_Ret_Sts_Error;
      x_Return_Message := 'http send error:' || SQLERRM;
      --Log('Send_Http error :' || x_Return_Status || ',' || x_Return_Message);
  END Send_Http;

  PROCEDURE Send_Rest(Pv_Url           IN VARCHAR2
                     ,p_Http_Timeout   IN NUMBER DEFAULT NULL
                     ,p_Http_Request   IN CLOB
                     ,x_Http_Response  OUT NOCOPY CLOB
                     ,x_Return_Status  OUT NOCOPY VARCHAR2
                     ,x_Return_Message OUT NOCOPY VARCHAR2) IS
    Lv_Url VARCHAR2(2000) := Pv_Url;
  BEGIN
    Send_Http(p_Access_Token   => NULL
             ,p_Url            => Lv_Url
             ,p_Http_Timeout   => p_Http_Timeout
             ,p_Http_Request   => p_Http_Request
             ,p_Content_Type   => NULL --'application/json'
             ,x_Http_Response  => x_Http_Response
             ,x_Return_Status  => x_Return_Status
             ,x_Return_Message => x_Return_Message);
    --Log('Send_Rest:' || x_Return_Status || ',' || x_Return_Message);
  END Send_Rest;

  FUNCTION Get_Url(Pv_Intsys_Code IN VARCHAR2) RETURN VARCHAR2 Result_Cache IS
    Lv_Url VARCHAR2(2000);
  BEGIN
    SELECT Env_Set.To_System_Url
      INTO Lv_Url
      FROM V$database Databse
           --,Xxcus_Int_Set_Intsys_t Xisi
          ,Xxcus_Int_Set_Intenv_t      Env_Set
          ,Xxcus_Int_Set_Environment_t Env_To
          ,Xxcus_Int_Set_Environment_t Env_From
          ,Xxcus_Int_Set_Intsys_t      Xisi
     WHERE 1 = 1
       AND Env_From.Environment_Code = Databse.Name
       AND Env_Set.To_Environment_Id = Env_To.Environment_Id
       AND Env_Set.From_Environment_Id = Env_From.Environment_Id
       AND Env_Set.Intsys_Id = Xisi.Intsys_Id
       AND Xisi.Intsys_Code = Pv_Intsys_Code;
  
    RETURN Lv_Url;
  
  EXCEPTION
    WHEN OTHERS THEN
      RETURN NULL;
    
  END Get_Url;

  PROCEDURE Send_Interface(Pv_Intsys_Code   IN VARCHAR2
                          ,p_Http_Timeout   IN NUMBER DEFAULT NULL
                          ,p_Http_Request   IN CLOB
                          ,x_Http_Response  OUT NOCOPY CLOB
                          ,x_Return_Status  OUT NOCOPY VARCHAR2
                          ,x_Return_Message OUT NOCOPY VARCHAR2) IS
    Lv_Url VARCHAR2(2000);
  
  BEGIN
    x_Return_Status := Fnd_Api.g_Ret_Sts_Success;
  
    Lv_Url := Get_Url(Pv_Intsys_Code);
    IF Lv_Url IS NULL THEN
      x_Return_Status  := Fnd_Api.g_Ret_Sts_Error;
      x_Return_Message := '获取接口“' || Pv_Intsys_Code || '”的url 异常';
    
    END IF;
  
    Send_Rest(Pv_Url           => Lv_Url
             ,p_Http_Timeout   => p_Http_Timeout
             ,p_Http_Request   => p_Http_Request
             ,x_Http_Response  => x_Http_Response
             ,x_Return_Status  => x_Return_Status
             ,x_Return_Message => x_Return_Message);
    --Log('Send_Interface:' || x_Return_Status || ',' || x_Return_Message);
  END Send_Interface;

BEGIN
  -- Initialization
  NULL;
END Xxcus_Int_Set_Send_Pkg;
 

刘文钊1
关注
专栏目录
EBS WEBSERVICE接口简单部署
04-26
EBS-WEBSERVICE
ebs发布webservice详解
12-11
详细讲解ebs中发布webservice的步骤
Oracle EBS接口开发之通过DBWS包实现WEBSERVICE
苏南生的CSDN博客
06-14 5022
文档目录 1. Webservice 2 1.1 一个案例 2 1.2 模拟测试 3 1.3 什么是WebService 3 1.4 WebService平台技术 4 2. DBWS包 6 2.1 DBWS 6 2.2 下载安装 6 3. XML 10 苏南生 3.1 为什么要说XML 10 3.2 命名空间的引入 10 3.3 命名空间的声明与使用 11 4. XPa
EBS并发请求调用CXF webservice 总结
better Life
01-16 1881
最近一直在忙webservice 的工作，一共完成了两个外部系统调用EBS数据的项目，从中获得了一些经验和教训，随手写下来，以便以后的使用。 1、很少能出现一次调通的接口，在我工作的这两个项目中，有一个接口很简单，但是也出现了各种各样的问题。所以若希望问题少最好先在SOUP UI里调试， 由于开发人员、使用工具等等一系列的问题，webservice的头信息会有很大的区别，有时候一个符号不对就会
使用WebService与Oracle EBS进行集成（上）
weixin_33726318的博客
04-14 226
一、概述     OracleEBS是Oracle公司的ERP产品，这个产品非常庞大，可以对企业的各个方面进行强大的管理功能，一般大型企业都会用到它的部分模块，根据公司的性质不同，选择的模块也会有所不同。对于生产型企业，所采购的模块中都会包括产品及价格等管理模块。     ERP属于大型系统，能选择Oracle ERP的企业，规模一般也不会太小，所以在IT方面，除了ERP产品本身，一般还会...
Oracle EBS 通过PLSQL Package 方式发布WebService
最新发布
fhy920703的博客
03-31 1118
编译保存后，cux_wz_connect_pkg.bdy另存为后缀名为plb的文件，或直接修改保存文件的后缀名为pls：cux_wz_connect_pkg.plb。编译保存后，cux_wz_connect_pkg.spc另存为后缀名为pls的文件，或直接修改保存文件的后缀名为pls：cux_wz_connect_pkg.pls。此处可以在公用块码中搜索lookup_type“BUSINESS_ENTITY”，将对应的信息维护进去，此处就会显示为自定义的meaning。将以上内容copy出来就可以测试了。
python调用webservice接口的实现
12-31
使用suds这个第三方模块 from suds.client import ...之前查看接口信息时，未发现tns=”http://Localhost:4567/Interface.wsdl”，这个被设置成Localhost，导致通过接口调用时，只能在webservice接口本地服务器上
分享XmlHttpRequest调用Webservice的一点心得
11-30
首先，因为JSON对于JS的便利性，考虑通过JSON来请求和返回数据。在JS中实例化一个xmlHttpRequest对象，然后根据网上的说明POST的地址为：asmx页面地址/Web方法名。在RequestHeader中设置Content-Type为application/...
C#调用webservice接口的最新方法教程
01-01
Web Service也叫XML Web Service WebService是一种可以接收从Internet或者Intranet上的其它系统中传递过来的请求，轻量级的独立的通讯技术。是:通过SOAP在Web上提供的软件服务，使用WSDL文件进行说明，并通过UDDI...
C#动态webservice调用接口
12-26
C#动态webservice调用接口 using System; using System.Collections; using System.IO; using System.Net; using System.Text; using System.Xml; using System.Xml.Serialization; namespace Hishop.Plugins { //...
webservice学习笔记【一】——接收远程调用webservice返回的数组
热门推荐
Rising Sun
07-16 1万+
      最近突然想学习webservice，作为一个初学者没想着一开始开发webservice，想先练练手，使用axis2 1.4 调用webservice，虽然只是调用webservice客户端，但是遇到的麻烦还真不少。      其中折磨我最久的问题就是如何处理远程调用返回的数组了，我照着网上的讲解调用一些网上公开的webservice，返回类型为String或者为schema.xml
EBS中PLSQL程序包发布成WEBSERVICE
weixin_46130307的博客
01-02 655
问题描述： 如何将PLSQL程序包发布成WEBSERVICE 前提条件： 本文不涉及注册产品家族/产品/业务实体（Product Family/Product/BUSINESS ENTITY) 发布步骤： 1 编写PLSQL包头和包体，包头要添加特定的注释如下： /* $Header: cux_xxx_invws_pkg.pls 120.16.12010000.1 2016/12/07 11:...
HTTP接口调用（EBS获取数据 ）
zgliulin
09-23 1414
开发背景 一开始使用了联通接口的相同调用方式【联通接口调用】，发现NameValuePair的方式传过去的参数EBS方接受不到，故采取以下方式。 接口说明 代码部分 因业务需求不同，请求地址，参数有所变化，将请求地址放在配置文件中 /** *@param url:请求地址 *@param token:密钥1 *@param key:密钥2 *@param data:参数 *...
ORACLE EBS WebService推送报文例子 XML格式
huangwenkangz的博客
04-16 660
PROCEDURE call_web_service(x_return_status OUT NOCOPY VARCHAR2, x_msg_count OUT NOCOPY NUMBER, x_msg_data OUT NOCOPY VARCHA...
EBS 查看调试日志
u012779110的博客
04-03 1329
EBS 查看调试日志
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值