串行化机制的可定制行很强,因此可以很灵活的控制对象串行化为XML的格式(如:可以用XSD模式来定义在串行化过程中产生的XML文档结构) 。
除了串行化为XML以外还有BinaryFormatter和SoapFormatter格式化类。
s BinaryFormatter将对象串行化为二进制格式。这样可以很高效率的传输到远程应用程序。
s SoapFormatter将对象串行化为简单对象访问协议(SOAP)格式。
SOAP是一种基于XML 的定义方法调用参数以及返回值符号。当将对象参数传递到一个Web服务方法或从一个Web服务方法中返回对象时,SoapFormatter将对象串行化为SOAP格式用于传输,.NET为我们提供了一种简单的方法,以存储一个对象的状态。
总之,.NET串行化机制可以在n层应用系统中,将对象串行化为XML格式来在系统各层之间传递对象数据。
要对对象进行XML串行化,首先定义一个类:
Public Class Book
Public BookID As Integer
Public BookName As String
End Class
这个类必须是一个公共类(Public),如果试图串行化一个非公共类,XMLSerializer将在运行时抛出一个异常。在类的内部将只串行化那些公有成员,非公有成员将不被串行化为XML。如果必须要串行化非公有成员,可以使用BinaryFormatter或SoapFormatter。
'实例化Book类
Dim book As New book
book.BookID = 1
book.BookName = "数学"
'创建一个xml串行化器
Dim serializer As New Xml.Serialization.XmlSerializer(GetType(book))
Dim writer As System.IO.StreamWriter = New System.IO.StreamWriter("E:/serializer/book.xml")
'进行串行化
serializer.Serialize(writer, book)
writer.Close()
这样,便可以将对象串行化为一个XML文件,格式为:
<?xml version="1.0" encoding="utf-8"?>
<Book xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<BookID>1</BookID>
<BookName>数学</BookName>
</Book>
如果有很多类需要进行xml序列化,则可以创建一个XmlSerializer对象数组。
Public Class Book
Public BookID As Integer
Public BookName As String
End Class
Public Class Student
Public StudentID As Integer
Public StudentName As String
End Class
Public Class Shop
Public ShopID As Integer
Public ShopName As String
End Class
Dim types(3) As Type
types(0) = GetType(book)
types(1) = GetType(Student)
types(2) = GetType(Shop)
Dim serializers(3) As Xml.Serialization.XmlSerializer
serializers = Xml.Serialization.XmlSerializer.FromTypes(types)
Dim writer As System.IO.StreamWriter = New System.IO.StreamWriter("E:/serializer/book.xml")
FromTypes()方法返回一个XmlSerializer对象数组。所生成的xml文档元素映射到类名称,其子元素映射到类的公共域,另外还有XSD命名空间。
将串行化为xml的对象复原,则需要并行化xml 数据对象,调用XmlSerializer对象的Deserialize方法,然后按通常的方法使用该对象。
Dim serializer As New Xml.Serialization.XmlSerializer(GetType(book))
Dim reader As System.IO.StreamReader = New System.IO.StreamReader("E:/serializer/book.xml")
Dim a As book = CType(serializer.Deserialize(reader), book)
reader.Close()
Console.WriteLine("Book ID:" & a.BookID)
Console.WriteLine("Book Name:" & a.BookName)
Console.WriteLine("Print Enter to Exit")
Console.ReadLine()
运行情况如下:
可以知道XML的序列化(Serialization)。它是这样一个过程:得到一个对象,把对象转换为一个XML文档,并且保存它以供使用,或者把它传到网络上其他地方以供使用。在.NET中,XML serialization通过检查类的属性是否被标志为read/write来工作。只要有其中一个属性,该类的值就会被取出并插入到一个XML文档里去。反序列化(De-serialization)则是一个相反的过程。
将一个对象串行化为xml后,再并行化,使其还原为原来的对象有时,在并行的xml当中可能存在意外的xml节点。
如果不处理这些意外的xml 的节点,XmlSerializer将忽略这些意外的节点,如果要处理这些意外节点,可以使用XmlSerializer的一下事件进行处理:
¨ UnknownNode
¨ UnknownElement
¨ UnknownAttribute
¨ UnreferencedObject
现在将book.xml的格式更改为:
<?xml version="1.0" encoding="utf-8"?>
<Book id="001" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<BookID>1</BookID>
<BookName>数学</BookName>
<Exception>Some Text</Exception>
</Book>
我们增加了一些意外的节点、属性,然后执行并行化过程:
Dim serializer As New Xml.Serialization.XmlSerializer(GetType(bookShop))
AddHandler serializer.UnknownAttribute, AddressOf myUnknownAttribute
AddHandler serializer.UnknownElement, AddressOf myUnknownElement
AddHandler serializer.UnknownNode, AddressOf myUnknownNode
Dim reader As System.IO.StreamReader = New System.IO.StreamReader("E:/serializer/book.xml")
Dim a As bookShop = CType(serializer.Deserialize(reader), bookShop)
reader.Close()
Console.WriteLine("BookShop Name:" & a.BookName)
Console.WriteLine("BookShop ID:" & a.BookID)
Console.WriteLine("Print Enter to Exit.............")
Console.ReadLine()
我们同样增加了意外节点、属性的处理代码,执行结果为:
这样我们就可以查看那些意外的节点、属性的信息了。
另外,我们还可以灵活的控制串行化xml 的格式,这样可以很方便的与外部应用程序进行交换对象。我们可以在类中加入.NET Framework属性来控制串行化xml 的格式。
Imports System.Xml
Imports System.Xml.Serialization
<XmlRoot(elementname:="Root_Book", namespace:="URI:MylocalURI")> _
Public Class Book
<XmlElement(elementname:="Book_ID", namespace:="URI:MylocalURI")> Public BookID As Integer
<XmlAttributeAttribute(AttributeName:="Name")> _
Public BookName As String
<XmlText()> _
Public test_Text As String
<XmlIgnore()> _
Public IgnoreText As String
‘IgnoreText 将不被串行化
End Class
Module Serialization
<STAThread()> _
Public Sub main()
Dim book As New book
book.BookID = 1
book.BookName = "数学"
book.test_Text = "Some Text"
book.IgnoreText = "IgnoreText"
Dim serializer As New Xml.Serialization.XmlSerializer(GetType(book))
Dim writer As System.IO.StreamWriter = New System.IO.StreamWriter("E:/serializer/book.xml")
serializer.Serialize(writer, book)
writer.Close()
End Sub
End Module
则生成的XML格式为:
<?xml version="1.0" encoding="utf-8"?>
<Root_Book xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" Name="数学" xmlns="URI:MylocalURI">
<Book_ID>1</Book_ID>
Some Text
</ Root_Book >由 串行化XML(一) 、 串行化XML(二) 可以将对象很方便、简单的串行化为XML格式, 除了可以将对象串行化为XML格式以外,还可以将其串行化为二进制、soap格式。
NET Framework通过Reflection提供自动Serialization的机制。当一个对象被序列化(Serialized)的时候,它的类名,Assembly,以及类实例的所有数据成员都将被写入存储介质中。Serialization引擎保持对所有已经被序列化的对象引用的追踪,以确保相同的对象引用最多只被序列化一次。
通常,一个Serialization过程会由formatter(例如BinaryFormatter、SoapFormatter)的Serialize方法引发。
一个类能够被序列化有两种方式:
¨ 将此class简单地标记为Serializable
¨ 为此class实现ISerializable接口,并将此class标记为Serializable。
声明一个可被序列化的类
<Serializable()> _
Public Class Book
Public bookname As String
Public bookID As Integer
End Class
使用BinaryFormatter来将上面的类序列化为二进制格式文件Book.dat,BinaryFormatter位于
System.Runtime.Serialization.Formatters.Binary命名空间
Dim book As New book
book.BookID = 1
book.BookName = "数学"
Dim formatter As BinaryFormatter = New BinaryFormatter
Dim stream As stream = New FileStream("Book.dat", FileMode.Create, FileAccess.Write, FileShare.None)
formatter.Serialize(stream, book)
stream.Close()
经过BinaryFormatter序列化 (serialize)的数据仍然能够通过BinaryFormatter反序列化(deserialize)回来。
Dim formatter As BinaryFormatter = New BinaryFormatter
Dim stream As stream = New FileStream("Book.dat", FileMode.Open, FileAccess.Read, FileShare.None)
Dim book As Book = CType(formatter.Deserialize(stream), Book)
stream.Close()
MessageBox.Show("Book Name:" & book.bookname & vbCrLf & "Book ID:" & book.bookID)
同串行化为xml一样,也可以忽略任意一个域,可以使用NonSerialized属性进行选择
<NonSerialized()> _
Public bookname As String
用类似的方法同样也可以将对象序列化为SOAP格式,我们使用SoapFormatter。
Dim book As New book
book.bookID = 1
book.bookname = "English"
Dim formatter As SoapFormatter = New SoapFormatter
Dim stream As stream = New FileStream("Book.xml", FileMode.Create, FileAccess.Write, FileShare.None)
formatter.Serialize(stream, Book)
stream.Close()
所生成的Book.xml格式为:
<SOAP-ENV:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:SOAP-ENC="http://schemas.xmlsoap.org/soap/encoding/" xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" xmlns:clr="http://schemas.microsoft.com/soap/encoding/clr/1.0" SOAP-ENV:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/">
<SOAP-ENV:Body>
<a1:Book id="ref-1" xmlns:a1="http://schemas.microsoft.com/clr/assem/e%2C%20Version%3D1.0.1.0%2C%20Culture%3Dneutral%2C%20PublicKeyToken%3Dnull">
<bookname id="ref-3">English</bookname>
<bookID>1</bookID>
</a1:Book>
</SOAP-ENV:Body>
</SOAP-ENV:Envelope>
总结:
Serialization是.NET中一种实现对象持久性(Persistent)的机制。它是一个将对象中的数据转换成一个单一元素(通常是Stream)的过程。它的逆过程是Deserialization。Serialization的核心概念是将一个对象的所有数据看作一个独立的单元。
一般说来,在两种情况下非常需要Serialization:
1) 当我们希望能够将对象当前的状态完整地保存到存储介质中,以便我们以后能够精确地还原对象时
2) 当我们希望将对象从一个应用程序空间( Application domain )传递到另一个应用程序空间时。