基于IntelliJ IDEA将MySQL库表生成自定义实体

前言

作为一名服务端开发人员，跟数据库打交道是无法避免的，所以也是需要把数据库中的表生成实体，也就是逆向工程，本文章主要是基于MySQL数据库和Mybatis框架。
现在Mybatis官网也提供了一套自动生成的框架，对于一般的开发来说已经够用，但是我们有时候需要添加一些自定义的属性或者其他功能，就显得十分鸡肋，IntelliJ IDEA真的强大，它已经为我们提供了一套非常强大的逆向工程工具，让我们可以随心所欲去生成自己需要的实体。

实战

第一步 首先，数据库连接如下，对于如何调出这个窗口和连接数据库，请自行百度。

第二步 在已连接的数据库中右击，找到Scripted Extesions,点开之后默认只有一个Generate POJOs.groovy，这个默认的如果不满足我们的需求，那么就可以将它复制一份来修改我们自己需要生成的格式。

第三步 如何修改里面的配置文件呢？这里不做太复杂的说明，对于用到的配置会做一个简单的说明，其他不了解的百度就能解决。

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.io.*
import java.text.SimpleDateFormat

packageName = ""
// 类型映射，主要是将数据库中的字段和Java中的类型对应，可以参考着修改
typeMapping = [
  (~/(?i)int/)                      : "Long",
  (~/(?i)float|double|decimal|real/): "Double",
  (~/(?i)datetime|timestamp/)       : "java.sql.Timestamp",
  (~/(?i)date/)                     : "java.sql.Date",
  (~/(?i)time/)                     : "java.sql.Time",
  (~/(?i)/)                         : "String"
]


FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = db2Java(table.getName(), true)
    def fields = calcFields(table)
    packageName = getPackageName(dir)
    PrintWriter printWriter = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "UTF-8"))
    printWriter.withPrintWriter {out -> generate(out, className, fields,table)}
}

// 获取包所在文件夹路径
def getPackageName(dir) {
    return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

def generate(out, className, fields,table) {
    out.println "package $packageName"
    out.println ""
    out.println "import java.io.Serializable;"
    out.println "import lombok.Getter;"
    out.println "import lombok.Setter;"
    out.println "import lombok.ToString;"
    Set types = new HashSet()

    fields.each() {
        types.add(it.type)
    }

    if (types.contains("Date")) {
        out.println "import java.util.Date;"
    }

    if (types.contains("InputStream")) {
        out.println "import java.io.InputStream;"
    }
    out.println ""
   // 下面这块是类注释说明信息
    out.println "/**\n" +
            " * @Description  \n" +
            " * @Author  xxxx\n" +
            " * @Date "+ new SimpleDateFormat("yyyy-MM-dd").format(new Date()) + " \n" +
            " */"
    out.println ""
    out.println "@Setter"
    out.println "@Getter"
    out.println "@ToString"
    out.println "public class $className implements Serializable {"
    out.println ""
    out.println genSerialID()
    fields.each() {
        out.println ""
        // 生成注释
        if (isNotEmpty(it.commoent)) {
            out.println "\t/**"
            out.println "\t * ${it.commoent.toString()}"
            out.println "\t */"
        }

        if (it.annos != "") {
            out.println "   ${it.annos.replace("[@Id]", "")}"
        }

        // 生成成员变量
        out.println "\tprivate ${it.type} ${it.name};"
    }
    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        def comm =[
                colName : col.getName(),
                name :  db2Java(col.getName(), false),
                type : typeStr,
                commoent: col.getComment(),
                annos: ""
        ]
        fields += [comm]
    }
}

// 这里主要是对于字段和类名做了处理，例如数据库中的表是tb_user，去掉前面的“tb”操作，实际生成就是User.java
// 这里是类名和成员变量做了统一处理，如果表和字段的前缀不一致，那么可以在在这里修改，或者重新写一个各自处理
// capitalize是否首字母大写
def db2Java(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")

    // 2 代表截取前两个单词，后面减去1代表去掉后缀单词个数，没有后缀默认1
    s = s[2..s.size() - 1]
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def javaName(str, capitalize) {
  def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
    .collect { Case.LOWER.apply(it).capitalize() }
    .join("")
    .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
  capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}
static String changeStyle(String str, boolean toCamel){
    if(!str || str.size() <= 1)
        return str
    if(toCamel){
        String r = str.toLowerCase().split('_').collect{cc -> Case.LOWER.apply(cc).capitalize()}.join('')
        return r[0].toLowerCase() + r[1..-1]
    }else{
        str = str[0].toLowerCase() + str[1..-1]
        return str.collect{cc -> ((char)cc).isUpperCase() ? '_' + cc.toLowerCase() : cc}.join('')
    }
}
static String genSerialID() {
    return "\tprivate static final long serialVersionUID =  " + Math.abs(new Random().nextLong()) + "L;"
}

注意：

1. 复制的文件可能会报一些检验的错误，可以不需要理会并不会影响使用；
2. 该配置文件中引入了lombok插件，所以省略了setter/getter方法，如果没引入这个插件，参考默认的配置
3. 修改的时候默认的配置最好备份，避免出现问题无法恢复。

第五步 最后只要保存好修改的配置信息，在指定的表中右击，选择我们自己定义的配置文件，在弹出的窗口中选择需要存放的路径即可。

总结

主要步骤：
1.连接数据库，查看对应表
2.修改逆向工程工具配置
3.执行自定义工具，生成自定义Java代码
在这个配置文件中，其实还有很多强大的功能，针对于不通的持久层框架最好是添加不同的配置，避免多次修改，相对于JPA、Hibernate、mybatis、mybatis-plus都可以做不同的配置。
后续还有其他实用的功能将会继续更新上去。