Linux0.11操作系统（哈工大李治军老师）实验楼实验1-引导

最新推荐文章于 2024-06-22 21:29:58 发布
最新推荐文章于 2024-06-22 21:29:58 发布
阅读量3k 收藏 35
点赞数 8
文章标签： linux ubuntu
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/camouflagerainy/article/details/123505420
版权

Linux0.11操作系统（哈工大李治军老师）实验楼实验1-引导

实验源地址： https://www.lanqiao.cn/courses/115/learning/

1.完成bootsect.s屏幕输出功能

bootsect.s 能在屏幕上打印一段提示信息“XXX is booting…”，其中 XXX 是你给自己的操作系统起的名字，例如 LZJos、Sunix 等（可以上论坛上秀秀谁的 OS 名字最帅，也可以显示一个特色 logo，以表示自己操作系统的与众不同(.)

此处需要用到的中断：0x10，参考：0x10详解

1.读入光标位置，设置AH = 0x03，BH = 0x00，进入中断；

mov ah,#0x03
xor bh,bh
int 0x10

2.此处，bootsect.s必须以0xAA55结尾，占2KB大小，所以前面要设置成510KB

! msg1 处放置字符串
msg1:
! 换行 + 回车
    .byte   13,10
    .ascii  "Hello OS world, my name is LZJ"
! 两对换行 + 回车
    .byte   13,10,13,10

! boot_flag 必须在最后两个字节
.org 510
! 设置引导扇区标记 0xAA55
! 必须有它，才能引导
boot_flag:
    .word   0xAA55

3.将字符串的长度赋值给cx;bx为0x10中断调用AH = 0x13时，设置字符串的属性；bp指向字符串的地址；然后设置段地址es；这时根据AH = 0x13，显示的数据是串地址ES:BP。

! 显示字符串 “Hello OS world, my name is ZXH”
! 要显示的字符串长度
    mov cx,#36
    mov bx,#0x0007
    mov bp,#msg1
! es:bp 是显示字符串的地址
! 相比与 linux-0.11 中的代码，需要增加对 es 的处理，因为原代码中在输出之前已经处理了 es
    mov ax,#0x07c0
    mov es,ax
    mov ax,#0x1301
    int 0x10

4.设置死循环，使其停留在这里

inf_loop:
    jmp inf_loop

下列为完整代码：

entry _start
_start:
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#36
    mov bx,#0x0007
    mov bp,#msg1
    mov ax,#0x07c0
    mov es,ax
    mov ax,#0x1301
    int 0x10
inf_loop:
    jmp inf_loop
msg1:
    .byte   13,10
    .ascii  "Hello OS world, my name is ZXH"
    .byte   13,10,13,10
.org 510
boot_flag:
    .word   0xAA55

5.编译，链接

as86 -0 -a -o bootsect.o bootsect.s
ld86 -0 -s -o bootsect bootsect.o

然后使用命令ls -l显示刚生成的文件属性

在这里插入图片描述

但是我们bootsect.s文件的大小必须占用一个磁盘扇区512KB，并且按照之前我们编写的文件，其大小应该正好是512KB，具体原因请参考实验楼李老师的说明。

6.我们需要用命令去掉文件头

dd bs=1 if=bootsect of=Image skip=32

关于指令dd，请参考：dd

7.运行

./run

在这里插入图片描述

2.改写setup.s的主要功能

2.1 bootsect.s 能完成 setup.s 的载入，并跳转到 setup.s 开始地址执行。而 setup.s 向屏幕输出一行"Now we are in SETUP"

此处需要用到的中断：0x10,0x13;有关0x13中断，参考此处：0x13

2.1.1 编写setup.s

同bootsect.s，只需将寄存器和字符串更改即可；

在这里插入图片描述

2.1.2 完成bootsect.s对setup.s的载入

在原bootsect.s中，就存在此功能，并且无需更改；

此处解释下为何setup.s的段地址是0x7ce0?

bootsect.s从ES = 0x7c00处开始读入，大小为512KB，后面开始运行setup.s，则，setup.s的段地址应该是ES : 512KB。

load_setup:
! 设置驱动器和磁头(drive 0, head 0): 软盘 0 磁头
    mov dx,#0x0000
! 设置扇区号和磁道(sector 2, track 0): 0 磁头、0 磁道、2 扇区
    mov cx,#0x0002
! 设置读入的内存地址：BOOTSEG+address = 512，偏移512字节
    mov bx,#0x0200
! 设置读入的扇区个数(service 2, nr of sectors)，
! SETUPLEN是读入的扇区个数，Linux 0.11 设置的是 4，
! 我们不需要那么多，我们设置为 2（因此还需要添加变量 SETUPLEN=2）
    mov ax,#0x0200+SETUPLEN
! 应用 0x13 号 BIOS 中断读入 2 个 setup.s扇区
    int 0x13
! 读入成功，跳转到 ok_load_setup: ok - continue
    jnc ok_load_setup
! 软驱、软盘有问题才会执行到这里。我们的镜像文件比它们可靠多了
    mov dx,#0x0000
! 否则复位软驱 reset the diskette
    mov ax,#0x0000
    int 0x13
! 重新循环，再次尝试读取
    jmp load_setup
ok_load_setup:
! 接下来要干什么？当然是跳到 setup 执行。
! 要注意：我们没有将 bootsect 移到 0x9000，因此跳转后的段地址应该是 0x7ce0
! 即我们要设置 SETUPSEG=0x07e0
2.1.3跳转到setup.s

要完成跳转，需要将bootsect.s之前设置的循环去掉，并jmpi到段地址SETUPSEG处

ok_load_setup:
    jmpi    0,SETUPSEG

bootsect.s完整代码：

SETUPLEN=2
SETUPSEG=0x07e0
entry _start
_start:
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#36
    mov bx,#0x0007
    mov bp,#msg1
    mov ax,#0x07c0
    mov es,ax
    mov ax,#0x1301
    int 0x10
load_setup:
    mov dx,#0x0000
    mov cx,#0x0002
    mov bx,#0x0200
    mov ax,#0x0200+SETUPLEN
    int 0x13
    jnc ok_load_setup
    mov dx,#0x0000
    mov ax,#0x0000
    int 0x13
    jmp load_setup
ok_load_setup:
    jmpi    0,SETUPSEG
msg1:
    .byte   13,10
    .ascii  "Hello OS world, my name is LZJ"
    .byte   13,10,13,10
.org 510
boot_flag:
    .word   0xAA55
2.1.4 编译，链接

因为要对两个文件均编译，链接，所以采用Makefile的方式。

从oslab进入到linux-0.11目录下后，使用下述命令：

make BootImage

但是会报错，原因在于Makefile中执行了./tools/build.c。

build.c 从命令行参数得到 bootsect、setup 和 system 内核的文件名，将三者做简单的整理后一起写入 Image。其中 system 是第三个参数（argv[3]）。当 “make all” 或者 “makeall” 的时候，这个参数传过来的是正确的文件名，build.c 会打开它，将内容写入 Image。

而 “make BootImage” 时，传过来的是字符串 “none”。所以，改造 build.c 的思路就是当 argv[3] 是"none"的时候，只写 bootsect 和 setup，忽略所有与 system 有关的工作，或者在该写 system 的位置都写上 “0”。

打开Makefile

vim Makefile

在这里插入图片描述

修改build.c文件即可；

在这里插入图片描述

将~/linux-0.11/boot/中原本的所有bootsect和setup文件全部删掉

在这里插入图片描述

再将我们写的两个文件复制过来

在这里插入图片描述
再次./run运行

在这里插入图片描述

2.2 setup.s 能获取至少一个基本的硬件参数（如内存参数、显卡参数、硬盘参数等），将其存放在内存的特定地址，并输出到屏幕上

获取硬件参数放到内存的0x90000处。在原版的setup.s中，已经完成了光标位置、内存大小显存大小、显卡参数、第一和第二硬盘参数的保存。

2.2.1读取光标位置

mov [0],dx表示，在偏移地址0处写入光标位置；

在完整代码中，下面可看大，已经设置了基地址ds = 0x9000，所以完整写法应该是ds:[0]。

mov    ah,#0x03
! 读入光标位置
xor    bh,bh
! 调用 0x10 中断
int    0x10
! 将光标位置写入 0x90000.
mov    [0],dx
2.2.2读取内存大小

此处所需中断：0x15

! 读入内存大小位置
mov    ah,#0x88
int    0x15
mov    [2],ax
2.2.3 读取磁盘参数表

有些硬件参数的获取要稍微复杂一些，如磁盘参数表。

在 PC 机中 BIOS 设定的中断向量表中 int 0x41 的中断向量位置(4*0x41 = 0x0000:0x0104)存放的并不是中断程序的地址，而是第一个硬盘的基本参数表。第二个硬盘的基本参数表入口地址存于 int 0x46 中断向量位置处。每个硬盘参数表有 16 个字节大小。

也就是说我们只要读取int 0x41的中断向量位置，就可以读取硬盘参数表。

位移大小说明
0x00字柱面数
0x02字节磁头数
.……
0x0E字节每磁道扇区数
0x0F字节保留

每个中断向量表长4KB,我们要显示0x41的中断的地址，所以要用4 * 0x41。

movsb（点击链接）：是数据传送指令，将数据但从源地址DS : SI传到目的地址ES : DI。

此处即：将硬盘参数表从DS : SI处，传到了ES : DI处，即0x90004的位置。

! 从 0x41 处拷贝 16 个字节（磁盘参数表）
mov    ax,#0x0000
mov    ds,ax
lds    si,[4*0x41]
mov    ax,#INITSEG
mov    es,ax
mov    di,#0x0004
mov    cx,#0x10
! 重复16次
rep
movsb
2.2.4获取光标位置

关于print_hex函数，参考2.3节。

! Cursor Position
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#18
    mov bx,#0x0007
    mov bp,#msg_cursor
    mov ax,#0x1301
    int 0x10
    mov dx,[0]
    call    print_hex
2.2.5 获取内存大小并打印KB两个字
! Memory Size
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#14
    mov bx,#0x0007
    mov bp,#msg_memory
    mov ax,#0x1301
    int 0x10
    mov dx,[2]
    call    print_hex
！打印KB两个字
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#2
    mov bx,#0x0007
    mov bp,#msg_kb
    mov ax,#0x1301
    int 0x10
2.2.6 打印参数
! Cyles
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#7
    mov bx,#0x0007
    mov bp,#msg_cyles
    mov ax,#0x1301
    int 0x10
    mov dx,[4]
    call    print_hex
! Heads
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#8
    mov bx,#0x0007
    mov bp,#msg_heads
    mov ax,#0x1301
    int 0x10
    mov dx,[6]
    call    print_hex
! Secotrs
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#10
    mov bx,#0x0007
    mov bp,#msg_sectors
    mov ax,#0x1301
    int 0x10
    mov dx,[12]
    call    print_hex

2.3setup.s 不再加载 Linux 内核，保持上述信息显示在屏幕上即可

现在已经将硬件参数（只包括光标位置、内存大小和硬盘参数，其他硬件参数取出的方法基本相同，此处略去）取出来放在了 0x90000 处，接下来的工作是将这些参数显示在屏幕上。这些参数都是一些无符号整数，所以需要做的主要工作是用汇编程序在屏幕上将这些整数显示出来

以十六进制方式显示比较简单。这是因为十六进制与二进制有很好的对应关系（每 4 位二进制数和 1 位十六进制数存在一一对应关系），显示时只需将原二进制数每 4 位划成一组，按组求对应的 ASCII 码送显示器即可。

而ASCII 码与十六进制数字的对应关系为：0x30 ～ 0x39 对应数字 0 ～ 9，0x41 ～ 0x46 对应数字 a ～ f。从数字 9 到 a，其 ASCII 码间隔了 7h，这一点在转换时要特别注意。为使一个十六进制数能按高位到低位依次显示，实际编程中，需对 bx 中的数每次循环左移一组（4 位二进制），然后屏蔽掉当前高 12 位，对当前余下的 4 位（即 1 位十六进制数）求其 ASCII 码，要判断它是 0 ～ 9 还是 a ～ f，是前者则加 0x30 得对应的 ASCII 码，后者则要加 0x37 才行，最后送显示器输出。以上步骤重复 4 次，就可以完成 bx 中数以 4 位十六进制的形式显示出来。

关于ROL:ROL

代码解释参考注释。

! 以 16 进制方式打印栈顶的16位数
print_hex:
! 4 个十六进制数字
    mov cx,#4
! 将(bp)所指的值放入 dx 中，如果 bp 是指向栈顶的话
    mov dx,(bp)
print_digit:
! 循环以使低 4 比特用上 !! 取 dx 的高 4 比特移到低 4 比特处。
    rol dx,#4
! ah = 请求的功能值，al = 半字节(4 个比特)掩码。
    mov ax,#0xe0f
! 取 dl 的低 4 比特值。进行`与`的第四位比较，f 在二进制中是 1111，所以就是显示dl的值
    and al,dl
! 给 al 数字加上十六进制 0x30
    add al,#0x30
！参考上述关于ASCII的解释，0 ~ 9 对应 0x30 ~ 0x39,而a ~ f 对应0x41 ~ 0x46, 0x41 - 0x39 = 0x08,所以中间差了7h
！所以这里和0x3a比较，小于它的话，直接输出；
！所以这里功能即使判断是数字还是字母
    cmp al,#0x3a	
! 是一个不大于十的数字
    jl  outp
! 是a～f，要多加 7
    add al,#0x07
outp:
    int 0x10
    loop    print_digit
    ret
! 这里用到了一个 loop 指令;
! 每次执行 loop 指令，cx 减 1，然后判断 cx 是否等于 0。
! 如果不为 0 则转移到 loop 指令后的标号处，实现循环；
! 如果为0顺序执行。
!
! 另外还有一个非常相似的指令：rep 指令，
! 每次执行 rep 指令，cx 减 1，然后判断 cx 是否等于 0。
！ 如果不为 0 则继续执行 rep 指令后的串操作指令，直到 cx 为 0，实现重复。

! 打印回车换行
print_nl:
! CR
    mov ax,#0xe0d
    int 0x10
! LF
    mov al,#0xa
    int 0x10
    ret

完整代码

INITSEG  = 0x9000
entry _start
_start:
! Print "NOW we are in SETUP"
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#25
    mov bx,#0x0007
    mov bp,#msg2
    mov ax,cs
    mov es,ax
    mov ax,#0x1301
    int 0x10

    mov ax,cs
    mov es,ax
! init ss:sp
    mov ax,#INITSEG
    mov ss,ax
    mov sp,#0xFF00

! Get Params
    mov ax,#INITSEG
    mov ds,ax
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov [0],dx
    mov ah,#0x88
    int 0x15
    mov [2],ax
    mov ax,#0x0000
    mov ds,ax
    lds si,[4*0x41]
    mov ax,#INITSEG
    mov es,ax
    mov di,#0x0004
    mov cx,#0x10
    rep
    movsb

! Be Ready to Print
    mov ax,cs
    mov es,ax
    mov ax,#INITSEG
    mov ds,ax

! Cursor Position
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#18
    mov bx,#0x0007
    mov bp,#msg_cursor
    mov ax,#0x1301
    int 0x10
    mov dx,[0]
    call    print_hex
! Memory Size
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#14
    mov bx,#0x0007
    mov bp,#msg_memory
    mov ax,#0x1301
    int 0x10
    mov dx,[2]
    call    print_hex
! Add KB
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#2
    mov bx,#0x0007
    mov bp,#msg_kb
    mov ax,#0x1301
    int 0x10
! Cyles
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#7
    mov bx,#0x0007
    mov bp,#msg_cyles
    mov ax,#0x1301
    int 0x10
    mov dx,[4]
    call    print_hex
! Heads
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#8
    mov bx,#0x0007
    mov bp,#msg_heads
    mov ax,#0x1301
    int 0x10
    mov dx,[6]
    call    print_hex
! Secotrs
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#10
    mov bx,#0x0007
    mov bp,#msg_sectors
    mov ax,#0x1301
    int 0x10
    mov dx,[12]
    call    print_hex

inf_loop:
    jmp inf_loop

print_hex:
    mov    cx,#4
print_digit:
    rol    dx,#4
    mov    ax,#0xe0f
    and    al,dl
    add    al,#0x30
    cmp    al,#0x3a
    jl     outp
    add    al,#0x07
outp:
    int    0x10
    loop   print_digit
    ret
print_nl:
    mov    ax,#0xe0d     ! CR
    int    0x10
    mov    al,#0xa     ! LF
    int    0x10
    ret

msg2:
    .byte 13,10
    .ascii "NOW we are in SETUP"
    .byte 13,10,13,10
msg_cursor:
    .byte 13,10
    .ascii "Cursor position:"
msg_memory:
    .byte 13,10
    .ascii "Memory Size:"
msg_cyles:
    .byte 13,10
    .ascii "Cyls:"
msg_heads:
    .byte 13,10
    .ascii "Heads:"
msg_sectors:
    .byte 13,10
    .ascii "Sectors:"
msg_kb:
    .ascii "KB"

.org 510
boot_flag:
    .word 0xAA55

修改setup.s后，重复2.1.4编译链接的命令，运行./run.
在这里插入图片描述

class-object
关注
操作系统实验一到实验九合集(哈工大李治军)
leoabcd12的博客
01-01 4万+
操作系统实验一到实验九合集(哈工大李治军) 有详细代码及注释，程序已在本地测试，均能跑通
操作系统实验四 进程运行轨迹的跟踪与统计(哈工大李治军)
leoabcd12的博客
09-04 3821
实验4 进程运行轨迹的跟踪与统计 实验目的 掌握 Linux 下的多进程编程技术； 通过对进程运行轨迹的跟踪来形象化进程的概念； 在进程运行轨迹跟踪的基础上进行相应的数据统计，从而能对进程调度算法进行实际的量化评价，更进一步加深对调度和调度算法的理解，获得能在实际操作系统上对调度算法进行实验数据对比的直接经验。 实验内容 进程从创建（Linux 下调用 fork()）到结束的整个过程就是进程的生命期，进程在其生命期中的运行轨迹实际上就表现为进程状态的多次切换，如进程创建以后会成为就绪态；当该进程被调度以
linux0.11实验楼,哈工大oslab Linux-0.11 实验一 熟悉实验环境 实验报告
weixin_34119722的博客
05-15 657
实验一 熟悉实验环境 实验报告一、实验目标认识实验平台和实验工具；认识实验环境的目录结构；掌握编译、运行、调试、文件交换等操作命令。二、实验内容和结果0. 了解实验平台和工具\quad 本实验采用的环境为实验楼虚拟机平台， 主要软件环境如下：GCC 编译器。GDB 调试器。Ubuntu。Bochs ：一个 IA-32 (X86) 架构PC机模拟器，可以模拟出多种操作系统的环境，如Linux、DOS...
哈工大操作系统linux0.11实验
最新发布
weixin_66430194的博客
06-22 232
（可以在本地进行环境配置，不想配的话直接在这里进行实验，也有操作步骤指导（但不够详细，没有完整代码），缺点是不能保存，但实验之间相互独立，每次最好保证有足够的时间持续做完单独一个实验，否则下次登陆就要重新来了）Linux完全内核注释：有助于深入理解实验，但完全根据参考一步步来，不看也没关系，里面内容很多。（其中也包含了修改完后的实验代码，可以直接用，当然也可以自己写，自己写难度还是比较大的）根据个人尝试，记录一下不错的操作指导，通过这些文章，顺利地完成了实验（前三个）实验一：操作系统的引导实验。
linux 入门笔记_实验楼
张旭的博客
06-16 1072
基本按键及命令操作按键 作用 Ctrl+d 键盘输入结束或退出终端 Ctrl+s 暂定当前程序，暂停后按下任意键恢复运行 Ctrl+z 将当前程序放到后台运行，恢复到前台为命令fg创建文件 touch 例： touch test.c touch lesson_{1..10}.txt 查看当前目录下的文件 ls 例： ls -a //显示所有文件包括隐
Linux基础-实验楼
井井酒的博客
02-27 581
Linux简单使用 快捷键 Tab：补全命令、目录、命令参数 Ctrl + c：强行终止当前程序 Ctrl+d：键盘输入结束或退出终端 Ctrl+s：暂停当前程序，暂停后按下任意键恢复运行 Ctrl+z：将当前程序放到后台运行，恢复到前台为命令fg Ctrl+a：将光标移至输入行头，相当于Home键 Ctrl+e：将光标移至输入行末，相当于End键 Ctrl+k：删除从光标所在位置到行末 Alt+Backspace：向前删除一个单词 Shift+PgUp：将终端显示向上滚动 Shift+PgDn：将终端显示
LINUX系统实验楼总结,实验楼 -- (Linux)
weixin_33158363的博客
04-29 282
1. 允许用户SSH登陆# 打开ssh配置文件, 一般在/etc/ssh/sshd_configsudo vim /etc/ssh/sshd_config# 在文件最后添加:# 其中shiyanlou是一个用户名AllowUsers shiyanlou2. mysql启动不了了总结发现有余下两个原因:1. mysql的重要文件丢失 如: sock, pid2. mysql root密码忘记了解决:...
操作系统基础教程——基于Linux0.11
11-01
#### 深度解析Linux 0.11操作系统 Linux 0.11 是一个早期版本的操作系统内核，它标志着Linux的发展历程中的一个重要阶段。在这个版本中，许多核心特性得到了实现，包括但不限于： - **进程管理**：通过引入进程的...
实验二-系统调用.zip
06-26
1.从 Linux 0.11 现在的机制看，它的系统调用最多能传递几个参数？你能想出办法来扩大这个限制吗？ 答：Linux-0.11的系统调用通过寄存器ebx、ecx、edx传递参数，最多能传递3个参数。 扩大传递参数的数量的方法： 1....
哈工大操作系统实验一——操作系统的引导
chan___的博客
09-06 7770
写在前面 哈尔滨工业大学李治军老师的《操作系统》课程实验，相关资源： 哈工大操作系统实验手册 实验资源与参考 不配环境懒人福利：实验楼 在线课程：操作系统，李治军，哈工大（网易云课堂） 参考阅读：《Linux内核完全注释》——赵炯，《操作系统原理、实现与实践》——李治军，刘宏伟 实验内容 改写bootsect.s，功能：能在屏幕上打印一段提示信息“XXX is booting....
逐行解读Linux0.11系统引导（一）
多皮哦的博客
08-30 307
本文内容的重点是x86硬件架构下Linux0.11的引导代码部分，不讨论BIOS本身及其加载，简略介绍BIOS加载引导扇区的部分。 和现在流行的UEFI不同，这个古老的系统由BIOS引导。 BIOS是英文"Basic Input Output System"的缩略词，直译过来后中文名称就是"基本输入输出系统"。——百度百科 1. 加载硬盘数据之前 我们都知道，CPU只能执行内存中的代码。如果代...
linux入门--实验楼
努力的小硬币
05-08 154
加粗样式 加粗样式 另一个实验： 用户：lilei 密码：lilei
linux 实验楼Linux 基础入门 作业
Half-up的博客
11-18 2607
实验楼实验界面 课程很好 用户及文件权限管理： 添加一个用户 loutest，使用 sudo 创建文件 /opt/forloutest，设置成用户 loutest 可以读写。截图并把操作过程写入实验报告。 提示： 如何创建一个文件呢？可以考虑 touch 命令，执行 sudo touch /opt/forloutest 这个命令可以创建一个空文件，但前提是执行这个命令的 loutest 用户需要具备 sudo 权限。 进入loutest 给他sudo权限 然后进入 改写权限 Linux权
学习实验楼Linux
weixin_43916372的博客
12-16 200
第一次使用实验楼，不知道自己使用的方法有没有问题。 实验一开始实验之后一脸懵逼，不知道该干什么，然后就退出去看了实验步骤，是私房菜里讲过的理论知识，还是不知道该干什么，收获0分钟学习时长。 实验二看完之后终于发现有作业了，先安装了bannner试了一下，然后发现toilet，figlet并没有告诉我下载方法，好在最后我还是搞出来了 $ sudo apt-get install toilet $ s...
实验楼：Linux 基础入门（新版） 实验四
m0_52102143的博客
09-23 108
这一节主要讲解文件常用的基本操作，包括：新建（touch mkdir）、复制(cp)、删除(rm)、移动文件与文件重命名(mv)、查看文件(cat)、查看文件类型(file)、以及编辑文件。要多动手实践，熟能生巧。
【实验楼】Linux基础入门（实验一 Linux系统简介）
qq_44622401的博客
01-14 437
Linux简介： Linux 内核最初只是由芬兰人林纳斯·托瓦兹（Linus Torvalds）在赫尔辛基大学上学时出于个人爱好而编写的。 Linux 是一套免费使用和自由传播的类 Unix 操作系统，是一个基于 POSIX 和 UNIX 的多用户、多任务、支持多线程和多 CPU 的操作系统。 Linux 能运行主要的 UNIX 工具软件、应用程序和网络协议。它支持 32 位和 64 位硬件。Li...
实验楼 Linux 学习笔记
keqiwww的博客
07-08 507
实验楼 Linux 学习笔记1.1 Linux 历史的历史早期操作系统能够处理批处理程序，它从文件或者穿孔卡片读取数据，然后输出到另一个文件或者打印机，称为批处理操作系统。后来，出现了能够支持多个用户从不同终端同时操作主机的系统，称为分时操作系统。然后许多人纷纷尝试开发分时操作系统，UNIX 就如此诞生，实现了 TCP/IP 协议栈。UXIX 系统在服务器市场上广受欢迎，但是它开始商业化，价格非常昂
linux学习笔记（实验楼） 实验2 基本概念和操作
qq_39117008的博客
01-29 465
一、实验介绍 1.1 实验内容 实验楼环境介绍 常用 Shell 命令及快捷键 Linux 使用小技巧 1.2 实验知识点 Linux 基本命令 通配符的使用 查看帮助文档   二、桌面环境 2.1  Linux 桌面环境介绍       相对于现在的 Windows 系统，UNIX/Linux 本身是没有图形界面的，我们通常在 ...
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值