mips中分支指令的偏移量计算

在 mips 中，分支指令的低 16 位是相对于当前 PC 的有符号字偏移，用于表示字的距离，偏移量为 0 时，就跳转到分支指令的延迟槽处，因此要想跳转到自身所在的位置，就需要将偏移量设为 -1。

下面来看一个示例，首先有如下汇编源码：

$ cat ./main.s
move       $v0, $a0
sltiu      $t2, $a2, 40
andi       $t0, $a0, 0xf
bnez       $t2, .Lbranch1

ldl        $t1, 3($a1)
ldl        $t2, 4($a1)
ldr        $t1, 3($a1)
ldr        $t2, 4($a1)

ldl        $t0, 23($a1)
ldl        $t3, 31($a1)
daddiu     $a1, $a1, 32

.Lbranch1:
	add $t1, $t2, 50 

其中，bnez 是 mips 的分支跳转指令，跳转的目标是符号 .Lbranch1 处的指令：add $t1, $t2, 50

下面是该源码在汇编后、又反汇编得到的结果：

$ as main.s -o main.o
$ objdump -DS main.o > main.S
$ cat ./main.S

main.o：     文件格式 elf64-tradlittlemips


Disassembly of section .text:

0000000000000000 <.text>:
   0:	00801025 	move	v0,a0
   4:	2cce0028 	sltiu	t2,a2,40
   8:	15c00008 	bnez	t2,0x2c
   c:	308c000f 	andi	t0,a0,0xf
  10:	68ad0003 	ldl	t1,3(a1)
  14:	68ae0004 	ldl	t2,4(a1)
  18:	6cad0003 	ldr	t1,3(a1)
  1c:	6cae0004 	ldr	t2,4(a1)
  20:	68ac0017 	ldl	t0,23(a1)
  24:	68af001f 	ldl	t3,31(a1)
  28:	64a50020 	daddiu	a1,a1,32
  2c:	21cd0032 	addi	t1,t2,50

Disassembly of section .MIPS.options:

0000000000000000 <.MIPS.options>:
   0:	00002801 	0x2801
   4:	00000000 	nop
   8:	0000f074 	teq	zero,zero,0x3c1
	...

从上面反汇编的结果可以看到：

1）汇编器对源码中的汇编指令进行了重排，使得 bnez 指令和 andi 指令调换了顺序；

2）汇编后，源码中 bnez $t2, .Lbranch1 指令的机器码是：15c00008，对应的二进制是：000101 01110 00000 00000000 00001000。根据 mips 指令编码规范可知，第一组 000101 表示指令码（对应 bne s, t, p 指令）；第二组 01110 是寄存器编号，即 14 号寄存器，助记符为 t2（64位 mips ABI）；第三组 00000 也是寄存器编号，即 0 号寄存器（其值始终为0）；第四组 00000000 00001000 是 16 位偏移量，以字为单位，其值为 8。根据上述计算公式可知，该指令将会跳转至：8 + (8 + 1) x 4 = 44 = 0x2c，其中第一个 8 是该指令的地址，第二个 8 是该指令中编码的偏移量，0x2c 正是源码中符号 .Lbranch1 处的指令地址。