SET QUOTED_IDENTIFIER ON
GO
SET ANSI_NULLS ON
GO
--@Type=4 每日备份 =8每周备份
--@Used=0 不启用 =1 启用
--@Num 从周日开始排 1,2,4,8,16,32,64 如果是每日备份则必须为1
-- exec p_swt_DataBackUp 'swtpro4','D:/BaseData',174000,4,1,0
-- exec p_swt_DataBackUp 'swtpro4','D:/BaseData',174000,8,16,1
ALTER PROCEDURE p_swt_DataBackUp
(
@DataBaseName nvarchar(50),
@PathFile nvarchar(100),
@DateTime int,
@Type int,
@Num int,
@Used int
)
as
BEGIN TRANSACTION
DECLARE @JobID BINARY(16)
DECLARE @ReturnCode INT
--DECLARE @DataBaseName nvarchar(50)
DECLARE @Name nvarchar(50)
--Declare @PathFile nvarchar(100)
Declare @commandText nvarchar(1000)
--select @DataBaseName='swtpro4'
select @PathFile=@PathFile + '/' + @DataBaseName
select @Name='DataBackUp'
select @commandText='DECLARE @Path nvarchar(100)
select @Path='''+ @PathFile +'_''+replace(replace(convert(nvarchar(20),getdate(),120),'' '',''''),'':'','''')
Backup database '+ @DataBaseName +' To disk=@Path with Init'
SELECT @ReturnCode = 0
IF (SELECT COUNT(*) FROM msdb.dbo.syscategories WHERE name = N'[Uncategorized (Local)]') < 1
EXECUTE msdb.dbo.sp_add_category @name = N'[Uncategorized (Local)]'
-- 删除同名的警报(如果有的话)。
SELECT @JobID = job_id
FROM msdb.dbo.sysjobs
WHERE (name = @Name)
IF (@JobID IS NOT NULL)
BEGIN
-- 检查此作业是否为多重服务器作业
IF (EXISTS (SELECT *
FROM msdb.dbo.sysjobservers
WHERE (job_id = @JobID) AND (server_id <> 0)))
BEGIN
-- 已经存在,因而终止脚本
RAISERROR (N'无法导入作业,因为已经有相同名称的多重服务器作业。', 16, 1)
GOTO QuitWithRollback
END
ELSE
-- 删除[本地]作业
EXECUTE msdb.dbo.sp_delete_job @job_name = @Name
SELECT @JobID = NULL
END
BEGIN
-- 添加作业
EXECUTE @ReturnCode = msdb.dbo.sp_add_job @job_id = @JobID OUTPUT , @job_name = @Name, @owner_login_name = N'sa', @description = N'没有可用的描述。', @category_name = N'[Uncategorized (Local)]', @enabled = @Used, @notify_level_email = 0, @notify_level_page = 0, @notify_level_netsend = 0, @notify_level_eventlog = 3, @delete_level= 0
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
-- 添加作业步骤
EXECUTE @ReturnCode = msdb.dbo.sp_add_jobstep @job_id = @JobID, @step_id = 1, @step_name = N'1', @command =@commandText , @database_name = @DataBaseName, @server = N'', @database_user_name = N'', @subsystem = N'TSQL', @cmdexec_success_code = 0, @flags = 0, @retry_attempts = 0, @retry_interval = 1, @output_file_name = N'', @on_success_step_id = 0, @on_success_action = 1, @on_fail_step_id = 0, @on_fail_action = 2
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXECUTE @ReturnCode = msdb.dbo.sp_update_job @job_id = @JobID, @start_step_id = 1
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
-- 添加作业调度
if @Type=4
begin
EXECUTE @ReturnCode = msdb.dbo.sp_add_jobschedule @job_id = @JobID, @name = N'11', @enabled = 1, @freq_type = @Type,
@active_start_date = 20081231, @active_start_time = @DateTime, @freq_interval = 1, @freq_subday_type = 1,
@freq_subday_interval = 2, @freq_relative_interval = 0, @freq_recurrence_factor = 0, @active_end_date = 99991231,
@active_end_time = 235959
end
else if @Type=8
begin
EXECUTE @ReturnCode = msdb.dbo.sp_add_jobschedule @job_id = @JobID, @name = N'11', @enabled = 1, @freq_type = @Type,
@active_start_date = 20081231, @active_start_time = @DateTime, @freq_interval = @Num, @freq_subday_type = 1,
@freq_subday_interval = 2, @freq_relative_interval = 0, @freq_recurrence_factor = 1, @active_end_date = 99991231,
@active_end_time = 235959
end
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
-- 添加目标服务器
EXECUTE @ReturnCode = msdb.dbo.sp_add_jobserver @job_id = @JobID, @server_name = N'(local)'
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
END
COMMIT TRANSACTION
GOTO EndSave
QuitWithRollback:
IF (@@TRANCOUNT > 0) ROLLBACK TRANSACTION
EndSave:
GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON
GO