【Typora】像用vscode那样用Typora——安装Typora到右键菜单

像用VSCode那样用Typora——安装Typora到右键菜单

1. 引言

Typora 是一款优秀的 Markdown 编辑器，以其所见即所得的编辑模式和简洁的界面而受到许多写作爱好者和程序员的喜爱。然而，每次想要用 Typora 打开一个文件夹时，都需要先打开 Typora，然后再通过文件菜单打开文件夹，这使得 Typora 相比于其他带有仓库功能的笔记软件（如 Obsidian 等），其过程略显繁琐。但反过来 Obsidian 又不具有 Typora 的灵活性，如果我们只是想临时打开一个文件夹修改内容，也没有必要在 Obsidian 中新建仓库。

如果我们能像使用 VSCode 那样，直接在文件夹上或者路径空白处点击右键就能用 Typora 打开，那会方便很多。本文将介绍如何通过一个简单的脚本，将 Typora 添加到 Windows 的右键菜单中，从而提高工作效率。

效果示意图

2. 一键安装批处理脚本

以下是将 Typora 添加到右键菜单的批处理脚本

@echo off
setlocal EnableDelayedExpansion

REM 设置 Typora 程序的路径（根据自己的实际安装位置修改）
set TYPORA_PATH=C:\Program Files\Typora\Typora.exe

REM 创建临时注册表文件
set TEMP_REG_FILE=%TEMP%\install_typora_context_menu.reg

echo Windows Registry Editor Version 5.00 > "%TEMP_REG_FILE%"

REM 为文件夹添加右键菜单项
echo [HKEY_CLASSES_ROOT\Directory\shell\OpenWithTypora] >> "%TEMP_REG_FILE%"
echo @="Open folder with Typora" >> "%TEMP_REG_FILE%"
echo "Icon"="%TYPORA_PATH:\=\\%" >> "%TEMP_REG_FILE%"

echo [HKEY_CLASSES_ROOT\Directory\shell\OpenWithTypora\command] >> "%TEMP_REG_FILE%"
echo @="\"%TYPORA_PATH:\=\\%\" \"%%1\"" >> "%TEMP_REG_FILE%"

REM 为目录背景添加菜单项
echo [HKEY_CLASSES_ROOT\Directory\Background\shell\OpenWithTypora] >> "%TEMP_REG_FILE%"
echo @="Open current folder with Typora" >> "%TEMP_REG_FILE%"
echo "Icon"="%TYPORA_PATH:\=\\%" >> "%TEMP_REG_FILE%"

echo [HKEY_CLASSES_ROOT\Directory\Background\shell\OpenWithTypora\command] >> "%TEMP_REG_FILE%"
echo @="\"%TYPORA_PATH:\=\\%\" \".\"" >> "%TEMP_REG_FILE%"

REM 导入注册表
regedit /s "%TEMP_REG_FILE%"
del "%TEMP_REG_FILE%"

echo Installation complete!
pause

这个脚本主要做了以下几件事：

1. 设定 Typora 的安装路径。
2. 创建一个临时的注册表文件。
3. 在注册表文件中添加必要的键值，包括为文件夹和目录背景（空白处）添加右键菜单项。
4. 使用 regedit 命令导入注册表文件。
5. 然后删除临时注册表文件。

3. 使用方法

按照以下步骤来安装 Typora 到右键菜单：

1. 将上述脚本内容复制到一个文本文件中。
2. 将文件保存为 .bat 格式，例如 “install_typora_context_menu.bat”。注意编码需要为 GBK 一类的中文编码，否则会出现乱码问题。
3. 右击该 .bat 文件，选择"以管理员身份运行"。
4. 等待脚本运行完成，你会看到 “Installation complete!” 的提示。

安装完成后，你就可以：

• 在任何文件夹上右击，选择 “使用Typora打开文件夹” 来用 Typora 打开该文件夹。
• 在任何目录的空白处右击，选择 “使用Typora打开路径” 来用 Typora 打开当前目录。

除了使用上面的一键安装脚本，也可以根据脚本中的内容手动修改相应的注册表项。

4. 注意事项

• 请确保脚本中的 Typora 路径与你的实际安装路径一致。如果 Typora 安装在其他位置，你需要修改脚本中的 TYPORA_PATH 变量。

• 运行脚本需要管理员权限，因为它需要修改注册表。

• 如果将来你想要卸载这个右键菜单项，你可以手动删除注册表中的相应项。路径为：

  • HKEY_CLASSES_ROOT\Directory\shell\OpenWithTypora
  • HKEY_CLASSES_ROOT\Directory\Background\shell\OpenWithTypora

• 如果你不熟悉注册表操作，建议在修改之前备份注册表。

5. 卸载脚本

如果想要移除添加的右键菜单项，可以使用以下卸载脚本：

@echo off
setlocal EnableDelayedExpansion

REM 创建临时注册表文件
set TEMP_REG_FILE=%TEMP%\uninstall_typora_context_menu.reg

echo Windows Registry Editor Version 5.00 > "%TEMP_REG_FILE%"
echo. >> "%TEMP_REG_FILE%"

REM 删除文件夹右键菜单项
echo [-HKEY_CLASSES_ROOT\Directory\shell\OpenWithTypora] >> "%TEMP_REG_FILE%"
echo. >> "%TEMP_REG_FILE%"

REM 删除目录背景（空白处右击）菜单项
echo [-HKEY_CLASSES_ROOT\Directory\Background\shell\OpenWithTypora] >> "%TEMP_REG_FILE%"
echo. >> "%TEMP_REG_FILE%"

REM 导入注册表
regedit /s "%TEMP_REG_FILE%"

REM 删除临时注册表文件
del "%TEMP_REG_FILE%"

echo Uninstallation complete! Typora has been removed from the context menu.
pause

运行这个脚本后，之前添加的 Typora 右键菜单选项将被移除。

6. 安装 Typora 增强插件

Typora 本身的功能已经足够强大，但是相比于插件生态完善的 obsidian，其在这方面还是有所不足，我们可以给自己的 Typora 安装一个插件，打开下面的网址按照说明进行安装即可：

https://github.com/obgnail/typora_plugin?tab=readme-ov-file

此插件作为本文的外延仅简单介绍，更多功能大家可以自行探索。

6. 总结

通过本文介绍的安装脚本，我们可以像使用 VSCode 那样方便地使用 Typora。这不仅节省了打开文件夹的时间，也使得工作流程更加顺畅。特别是对于经常需要编辑多个 Markdown 文件的用户来说，这个小技巧可以显著提高工作效率。

希望本文对大家有所帮助。