windows下定时备份数据库

一、windows计划任务程序执行

1. 编写.bat脚本

   @echo off
   
   echo 设置MySQL数据库的连接信息
   set host=127.0.0.1
   set port=3306
   set user=root
   set pass=123456
   
   echo 设置要备份的MySQL数据库名称
   set dbname=test_table
   
   echo 获取当天的日期格式，例如：20221102231300
   
   REM 获取当前日期和时间
   set "hour=%time:~0,2%"
   if "%time:~0,1%"==" " set "hour=0%time:~1,1%"
   
   set "backup_date=%Date:~0,4%%Date:~5,2%%Date:~8,2%%hour%%Time:~3,2%%Time:~6,2%"
   
   REM 设置备份文件的路径
   set "backup_dir=E:\test\sql"
   set "backupfile=%backup_dir%\%dbname%_backup_%backup_date%.sql"
   
   REM 确保备份目录存在，如果不存在则创建
   if not exist "%backup_dir%" mkdir "%backup_dir%"
   
   echo 使用mysqldump对指定的MySQL进行备份
   
   REM 备份数据库
   "D:\phpstudy_pro\Extensions\MySQL5.7.26\bin\mysqldump" -h%host% -P%port% -u%user% -p%pass% -c --add-drop-table %dbname% > "%backupfile%"
   
   REM 检查备份是否成功
   if %errorlevel% neq 0 (
       echo 备份失败，请检查日志
   ) else (
       echo 备份成功，备份文件路径为：%backupfile%
   )
   
   echo 删除过期文件，这里是超过7天就删除
   
   REM 删除7天前的备份文件
   forfiles /p "%backup_dir%" /s /m *.sql /d -7 /c "cmd /c echo 删除 @file && del @file /f"
   
   
   

2. 搜索任务计划程序     

3. 点击创建任务，填写任务名称和描述             

4. 选择触发器

5. 选择操作执行  

6. 选择执行的脚本参数 

7. 确定自己填写或选择执行的方式

二、windows下cmd命令执行         

1. 编写脚本如上面的 .bat脚本

2. 使用 schtasks 命令来在 Windows 中创建定时任务。下面是一个示例命令，用于创建一个每天定时执行的任务：

   schtasks /create /tn "MyBackupTask" /tr "E:\path\to\your\backup_script.bat" /sc daily /st 01:00

   这个命令将创建一个名为 "MyBackupTask" 的任务，它会每天在凌晨 01:00 执行指定的批处理脚本 backup_script.bat。                                                                                                    你需要替换以下部分：                                                                                             "MyBackupTask"：任务名称，可以自定义。

   "E:\path\to\your\backup_script.bat"：你实际的备份脚本的完整路径。

   /sc daily：指定任务的触发器类型，这里是每天触发一次。/st 01:00：指定任务每天触发的时间，这里是凌晨 01:00。

3. 删除定时任务                               

   #输入以下命令来列出所有当前的定时任务
   
   schtasks /query
   
   #找到你想要取消的定时任务的名称，然后使用以下命令来删除该任务
   
   schtasks /delete /tn "TaskName"