游标科普编辑本段回目录
游标字面理解就是游动的光标。游标是SQL的一个内存工作区，由系统或用户以变量的形式定义。在某些情况下，需要把数据从存放在磁盘的表中调到计算机内存中进行处理，最后将处理结果显示出来或最终写回数据库。这样数据处理的速度才会提高，否则频繁的磁盘数据交换会降低效率。用数据库语言来描述游标就是映射在结果集中一行数据上的位置实体，有了游标，用户就可以访问结果集中的任意一行数据了，将游标放置到某行后，即可对该行数据进行操作，例如提取当前行的数据等。
游标类型编辑本段回目录
游标有两种类型：显式游标和隐式游标。游标一旦打开，数据就从数据库中传送到游标变量中，然后应用程序再从游标变量中分解出需要的数据，并进行处理。
当系统使用一个隐式游标时，可以通过隐式游标的属性来了解操作的状态和结果，进而控制程序的流程。隐式游标可以使用名字SQL来访问，但要注意，通过SQL游标名总是只能访问前一个处理操作或单行SELECT操作的游标属性。所以通常在刚刚执行完操作之后，立即使用SQL游标名来访问属性。
游标属性编辑本段回目录
游标的属性有四种,分别是SQL %ISOPEN，SQL %FOUND，SQL %NOTFOUND，SQL %ROWCOUNT。
SQL%ISOPEN返回的类型为布尔型,判断游标是否被打开，如果打开%ISOPEN等于true,否则等于false,即执行过程中为真,结束后为假。
SQL%NOTFOUND返回值为布尔型,判断游标所在的行是否有效，如果有效，则%FOUNDD等于true，否则等于false,即与%FOUND属性返回值相反。
SQL%FOUND返回值的类型为布尔型，值为TRUE代表插入删除更新或单行查询操作成功。
SQL%ROWCOUNT返回值类型为整型，返回当前位置为止游标读取的记录行数,即成功执行的数据行数（补充说明：这里在刚open游标时为null，没循环结束一行记录加1）。
示例代码如下：
declare v_person_oid number(12); v_person_name nvarchar2(50); cursor mycur(unit_oid_i number) is select p.person_oid, p.name from person p where p.unit_oid = unit_oid_i; begin if mycur%isopen = false then open mycur(1); end if; fetch mycur into v_person_oid, v_person_name; while mycur%found loop dbms_output.put_line(v_person_oid || ',' || v_person_name); if mycur%rowcount = 2 then exit; end if; fetch mycur into v_person_oid, v_person_name; end loop; close mycur; end;
记录并不保存在数据库中，它与变量一样，保存在内存空间中，在使用记录时候，要首先定义记录结构，然后声明记录变量。可以把PL/SQL记录看作是一个用户自定义的数据类型。
显示游标编辑本段回目录
在DECLEAR部分按以下格式声明游标：
CURSOR 游标名[(参数1 数据类型[参数2 数据类型...])]
IS SELECT语句;
参数是可选部分，所定义的参数可以出现在SELECT语句的WHERE子句中。如果定义了参数，则必须在打开游标时传递相应的实际参数。
SELECT语句是对表或视图的查询语句，甚至也可以是联合查询。可以带WHERE条件、ORDER BY或GROUP BY等子句，但不能使用INTO子句。在SELECT语句中可以使用在定义游标之前定义的变量。
例：
cursor mycur(unit_oid_i number) is
select p.person_oid, p.name
from person p
where p.unit_oid = unit_oid_i;
在游标定义中SELECT语句中不一定非要表可以是视图，也可以从多个表或视图中选择.
使用游标中的值之前应该首先打开游标，打开游标初始化查询处理。打开游标的语法
OPEN 游标名[(实际参数1[实际参数2，...])];
打开游标时，SELECT语句的查询结果就被传送到了游标工作区。
例：
open mycur(1);
从游标得到一行数据使用FETCH命令。每一次提取数据后，游标都指向结果集的下一
FETCH cursor_name INTO variable[,variable,...]
对于SELECT定义的游标的每一列，FETCH变量列表都应该有一个变量与之相对应，变
在可执行部分，按以下格式将游标工作区中的数据取到变量中。提取操作必须在打开游标之后进行。
FETCH 游标名 INTO 变量名1[变量名2，...];
或
FETCH 游标名 INTO 记录变量;
游标打开后有一个指针指向数据区，FETCH语句一次返回指针所指的一行数据，要返回多行需重复执行，可以使用循环语句来实现。控制循环可以通过判断游标的属性来进行。
下面对这两种格式进行说明：
第一种格式中的变量名是用来从游标中接收数据的变量，需要事先定义。变量的个数和类型应与SELECT语句中的字段变量的个数和类型一致。
--显示游标-提取数据-第一种格式
declare
v_person_oid number(12);
v_person_name nvarchar2(50);
cursor mycur(un it_oid_i number) is
select p.person_oid, p.name
from person p
where p.unit_oid = unit_oid_i;
begin
open mycur(1);
fetch mycur
into v_person_oid, v_person_name;
while mycur%found loop
dbms_output.put_line('Id:' || v_person_oid || ',姓名:' || v_person_name);
fetch mycur
into v_person_oid, v_person_name;
end loop;
close mycur;
end;
第二种格式一次将一行数据取到记录变量中，需要使用%ROWTYPE事先定义记录变量，这种形式使用起来比较方便，不必分别定义和使用多个变量。
--显示游标-提取数据-第二种格式
declare
v_person person%rowtype;
cursor mycur(unit_oid_i number) is
select * from person p where p.unit_oid = unit_oid_i;
begin
open mycur(1);
fetch mycur
into v_person;
while mycur%found loop
dbms_output.put_line('Id:' || v_person.person_oid || ',姓名:' ||
v_person.name);
fetch mycur
into v_person;
end loop;
close mycur;
end;
定义记录变量的方法如下：
变量名表名|游标名%ROWTYPE;
其中的表必须存在，游标名也必须先定义。
CLOSE 游标名;
例：
close mycur;
显式游标打开后，必须显式地关闭。游标一旦关闭，游标占用的资源就被释放，游标变成无效，必须重新打开才能使用。
游标查询语句时可使用FOR UPDATE选项，以便在打开游标时锁定游标结果集合在表中对应数据行的所有列和部分列。
如果另一个会话已对活动集中的行加了锁，那么SELECT FOR UPDATE操作一直等待到其它的会话释放这些锁后才继续自己的操作；如果使用SELECT FOR UPDATE NOWAIT操作，则OPEN立即返回并抛出异常：
ORA-0054 ：resource busy and acquire with nowait specified.
--显示游标-更新或删除当前游标数据 declare cursor mycur(unit_oid_i number) is --1、for update select * from person p where p.unit_oid = unit_oid_i for update nowait; begin for v_person in mycur(1) loop if v_person.person_oid = 244 then --2、where current of cursor_name子句(注：这里是1行的记录，不是所有的) update person set name = '职员' || person_oid where current of mycur; end if; end loop; end;
使用loop 循环
declare
v_person_oid number(12);
v_person_name nvarchar2(50);
cursor mycur(unit_oid_i number) is
select p.person_oid, p.name
from person p
where p.unit_oid = unit_oid_i;
begin
open mycur(1);
loop
fetch mycur
into v_person_oid, v_person_name;
exit when mycur%notfound;
dbms_output.put_line('Id:' || v_person_oid || ',姓名:' || v_person_name);
end loop;
close mycur;
end;这里需要注意，exit when语句一定要紧跟在fetch之后。避免多余的数据处理。
而且处理逻辑需要跟在exit when之后。
使用while循环
--显示游标-游标循环-使用while循环
declare
v_person_oid number(12);
v_person_name nvarchar2(50);
cursor mycur(unit_oid_i number) is
select p.person_oid, p.name
from person p
where p.unit_oid = unit_oid_i;
begin
open mycur(1);
fetch mycur
into v_person_oid, v_person_name;
while mycur%found loop
dbms_output.put_line('Id:' || v_person_oid || ',姓名:' || v_person_name);
fetch mycur
into v_person_oid, v_person_name;
end loop;
close mycur;
end;
注意，这里用到了两个fetch语句！
第一个fetch语句是把游标的第一行记录赋值给相关变量，第二个fetch语句是让游标指向下一条记录。
如果没有第二个语句的话，即为死循环，不停地执行loop内的代码。
使用for循环
--显示游标-游标循环-使用for循环
declare
cursor mycur(unit_oid_i number) is
select p.person_oid, p.name
from person p
where p.unit_oid = unit_oid_i;
begin
for person in mycur(1) loop
dbms_output.put_line('Id:' || person.person_oid || ',姓名:' ||
person.name);
end loop;
end;
游标for循环是显示游标的一种快捷使用方式，它使用for循环依次读取结果集中的行数据，当for循环开始时，游标自动打开(不需要open)，每循环一次系统自动读取游标当前行的数据(不需要fetch)，当退出for循环时，游标被自动关闭(不需要使用close)。使用游标for循环的时候不能使用open语句，fetch语句和close语句，否则会产生错误。
隐式游标编辑本段回目录
显式游标主要是用于对查询语句的处理，尤其是在查询结果为多条记录的情况下；
而对于非查询语句，如修改、删除操作，则由ORACLE 系统自动地为这些操作设置游标并创建其工作区，隐式游标的名字为SQL，这是由ORACLE 系统定义的。
对于隐式游标的操作，如定义、打开、取值及关闭操作，都由ORACLE 系统自动地完成，无需用户进行处理。用户只能通过隐式游标的相关属性，来完成相应的操作。在隐式游标的工作区中，所存放的数据是与用户自定义的显示游标无关的、最新处理的一条SQL 语句所包含的数据。
格式调用为： SQL%
--隐式游标
declare
v_rows number;
begin
--更新数据
update person set name = name || ' 单位1' where unit_oid = 1;
--获取默认游标的属性值
v_rows := sql%rowcount;
dbms_output.put_line('更新了' || v_rows || '个人员的姓名');
--修改人员ID为14222，单位ID为1的人员名称，
--如果没有找到则修改人员ID为142，单位ID为1的人员名城
update person
set name = '职员' || person_oid
where unit_oid = 1
and person_oid = 14222;
if sql%notfound then
update person
set name = '职员' || person_oid
where unit_oid = 1
and person_oid = 142;
end if;
end;
动态游标（游标变量）编辑本段回目录
与游标一样，动态游标（游标变量）也是一个指向多行查询结果集合中当前数据行的指针。但与游标不同的是，游标变量是动态的，而游标是静态的。
游标只能与指定的查询相连，即固定指向一个查询的内存处理区域，而游标变量则可与不同的查询语句相连，它可以指向不同查询语句的内存处理区域（但不能同时指向多个内存处理区域，在某一时刻只能与一个查询语句相连），只要这些查询语句的返回类型兼容即可。
--动态游标（游标变量）
declare
--定义游标数据类型
type cursor_c is ref cursor;
--声明游标变量
person_c cursor_c;
--声明记录变量
person_row person%rowtype;
begin
open person_c for
select * from person p where p.unit_oid = 1;
loop
fetch person_c
into person_row;
exit when person_c%notfound;
dbms_output.put_line('Id：' || person_row.person_oid || 'Name:' ||
person_row.name);
end loop;
--将同一个游标变量对应到另一个select语句
open person_c for
select *
from person p
where p.unit_oid in
(select b.unit_oid from base_unit b where b.area_code = '440300')
and rownum < 101;
loop
fetch person_c
into person_row;
exit when person_c%notfound;
dbms_output.put_line('Id：' || person_row.person_oid || 'Name:' ||
person_row.name);
end loop;
close person_c;
end;
将动态游标作为参数传入过程中TestPck.pck：--将动态游标作为参数传入过程中TestPck.pck：
create or replace package TestPck is
--定义游标类型
type cursor_c is ref cursor;
--第一个过程，根据区域查询人员
procedure test1(area_code_i varchar2);
--第二个过程，根据单位查询人员
procedure test2(unit_oid_i varchar2);
--第三个过程，根据传入的动态游标处理人员信息
procedure test3(person_c cursor_c);
end TestPck;
/
create or replace package body TestPck is
procedure test1(area_code_i varchar2) is
person_c cursor_c;
begin
DBMS_OUTPUT.ENABLE(buffer_size => null);
open person_c for
select *
from person p
where p.unit_oid in (select b.unit_oid
from base_unit b
where b.area_code = area_code_i);
test3(person_c);
close person_c;
end;
procedure test2(unit_oid_i varchar2) is
person_c cursor_c;
begin
DBMS_OUTPUT.ENABLE(buffer_size => null);
open person_c for
select * from person p where p.unit_oid = unit_oid_i;
test3(person_c);
close person_c;
end;
procedure test3(person_c cursor_c) is
person_row person%rowtype;
begin
loop
fetch person_c
into person_row;
exit when person_c%notfound;
dbms_output.put_line('Id：' || person_row.person_oid || 'Name:' ||
person_row.name);
end loop;
end;
end TestPck;
/
测试代码：
--测试代码：
begin
TestPck.test1('440300');
TestPck.test2(1);
end;
1695
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
