Clojure中的宏生命周期

如果您仍然难以理解Clojure中的宏是什么，以及为什么它们如此有用，那么今天我将指导您完成另一个示例。 我们将学习何时识别，评估，扩展和执行宏。 我认为最重要的概念是它们与正常功能的相似性。 正如我上次描述的那样，宏是普通函数，但在编译时执行，并以代码而不是值作为参数。 第二个差异是人为的，因为Clojure代码是一个可以传递的值。 因此，让我们关注宏实际何时扩展和执行。 我们将从Clojure中的普通GCD实现作为正常功能开始：

(defn gcd [a b]
    (if (zero? b)
        a
        (recur b (mod a b))))

调用此函数将导致执行尾递归循环
在运行时每次遇到：

user=> (gcd 18 12)
6
user=> (gcd 9 2)
1
user=> (gcd 9 (inc 2))
3

不太令人兴奋。 但是，如果我们在宏中包装对gcd引用怎么办？

(defmacro runtime-gcd [a b] (list 'gcd a b))

或更简洁的语法：

(defmacro runtime-gcd-quote [a b] `(gcd ~a ~b))

现在看一下runtime-gcd的声明，但是用defmacro代替defn ，就像它是一个普通函数一样：

(defn runtime-gcd-fun [a b] (list 'gcd a b))

每次在Clojure代码中调用runtime-gcd-fun时，它将替换为以下列表： (gcd 12 8) 。 如您所见，它基本上是gcd函数调用。 它被引用，因此保留为列表，而不是调用实际功能。 您可以通过运行(eval)评估此数据结构：

user=> (eval '(gcd 12 8))
4
user=> (eval (list 'gcd 12 8))
4
user=> (eval (runtime-gcd-fun 12 8))
4

如您所见， runtime-gcd-fun是一个函数，它产生的数据结构（ list ）恰好是有效的Clojure 代码 ！ runtime-gcd-fun不调用(gcd ab) ，它返回调用gcd代码（表达式）。 好的，但是它与宏有什么关系？ 让我们回到原始的runtime-gcd宏：

user=>     (defmacro runtime-gcd [a b] (list 'gcd a b))
#'user/runtime-gcd
user=> (runtime-gcd 12 8)
4
user=> (runtime-gcd 12 (inc 7))
4

如此…有什么区别？ 没地方 (defmacro)在编译时执行（ 扩展 ）。 它基本上是在编译过程中调用的函数。 就像普通函数的调用在运行时被其值替换一样，从宏返回的值也会替换该宏在代码中的所有出现。 甚至还没有编译成字节码。 因此，如果遇到runtime-gcd ，编译器将对其进行调用并将其替换为其结果，即： (gcd ab) 。 这意味着我们可以简单地将(runtime-gcd 12 8)替换为(gcd 12 8) –这就是编译器为我们所做的。

那有什么大不了的？ 到目前为止，宏仅仅是在编译过程中执行的功能。 但是，如果我们跳过引号并定义
compile-time-gcd如下？

user=> (defmacro compile-time-gcd [a b] (gcd a b))
#'user/compile-time-gcd
user=> (compile-time-gcd 12 8)
4

我们住我，你是如此接近启示。 注意，我们不再引用gcd调用。 这具有巨大的后果。 这次，当编译器遇到compile-time-gcd宏时，它将执行其主体（ 将其展开 ）。 在runtime-gcd主体调用list函数（因此返回列表）的同时， compile time-gcd主体立即调用gcd并记住这是在编译时发生的！ (gcd 12 8)由编译器执行，其值（ 4 ）作为宏扩展结果返回。 这意味着在(compile-time-gcd 12 8)将整个(compile-time-gcd 12 8)替换为数字4 。 换句话说，计算是在编译期间完成的，并且gcd开销在运行时不存在。 检出macroexpand的输出，该输出显示了返回的宏而不进行评估：

user=> (macroexpand '(runtime-gcd 12 8))
(gcd 12 8)
 
user=> (macroexpand '(compile-time-gcd 12 8))
4

这是您应该真正考虑的事情。 宏不仅仅是内置于编译器中的高级搜索和替换功能。 它们是可以包含逻辑和条件的“真实” Clojure函数。 唯一的区别是它们在编译时起作用，并在代码而不是值上操作。 那么，如果宏可以在编译时运行程序并避免运行时计算，那么为什么不一直使用宏呢？ 请记住，宏仅存在于编译器中，它们对您的运行时环境一无所知：

user=> (compile-time-gcd 12 (inc 7))
ClassCastException clojure.lang.PersistentList cannot be cast to java.lang.Number 
    clojure.lang.Numbers.isZero (Numbers.java:90)

该错误实际上将在编译期间弹出，而不是在运行时弹出！ 编译器尝试运行(gcd 12 '(inc 7)) 。 引用的'(inc 7)列表不等于8。这是一个list ！ 当编译器执行条件(zero? '(inc 7))将抛出熟悉的ClassCastException 。 请勿将其与看似相似(zero? (inc 7))混淆–增量7不加引号，因此计算结果为8 。

你还在困惑吗？ 让我们更加明确：

(defmacro printer [s]
    (println "Compile time:" s)
    (list 'println "Runtime:" s))

该宏是带有两个表达式的函数。 现在编译以下Clojure文件：

(printer "buzz")
(printer (str "foo" "bar"))

仔细查看编译器输出，您将看到以下两行：

Compile time: buzz
Compile time: (str foo bar)

这证明了宏是在编译时扩展并执行的。 但是第二行发生了什么？ 好吧，任何函数的最后一个表达式的值（这里不是宏）都不是那个函数的值。 因此，每次出现(printer s)宏都将替换为(println "Runtime:" s) 列表 –这段代码将像println从一开始就被编译。

为了确保您真正了解宏，请在printer宏中切换语句，并尝试弄清该宏在编译时和运行时的作用（提示： println值为nil ）：

(defmacro broken-printer [s]
    (list 'println "Runtime:" s)
    (println "Compile time:" s))

我们甚至还不能解释Clojure中宏的所有方面。 我们还没有涉及各种引号的怪癖， gensym ，splicing等。但是，我希望本文（与初学者的Clojure宏一起）将为您提供一些基本概念，为什么宏在Lisp语言家族中如此重要。

参考：来自Java和社区博客的JCG合作伙伴 Tomasz Nurkiewicz提供的Clojure宏生命周期 。

翻译自: https://www.javacodegeeks.com/2013/07/macro-lifecycle-in-clojure.html