批量修改文件名的bat批处理文件

在网友 http://blog.163.com/sycdc_j/blog/static/3234244220091199519207/ 基础上,稍加修改的一个批量修改文件名的bat文件。

=============================================

@echo off

 

setlocal

set /p oldname=请输入老名字:
set /p newname=请输入新名字:
set /p wildcard=请输入文件名通配符列表(缺省为所有文件,即“*”):

for /f "usebackq delims=" %%i in (`dir /s/b/a-d %wildcard%`) do (
 setlocal enabledelayedexpansion

 

 set var=%%~nxi
 set "var=!var:%oldname%=%newname%!"

 if not "%%~nxi"=="!var!" (echo 正在改名:"%%i" =》 "!var!")
 echo %%i |find "mutiren.bat" >nul || ren "%%i" "!var!" >nul

 endlocal
)

 

endlocal

=============================================


说明 :

1. 本处理的功能是查找替换文件名。

2. 在for语句中使用到了变量延迟的语句 setlocal  enabledelayedexpansion 和 endlocal。
3. dir /s /b /a-d 是列出当前目录及其子目录(/s)的文件(/a-d)的名称(/b),/a-d是指文件属性非目录,即文件。

4. '|'是用来传递参数的管道,'||'则是当前面的句子执行失败后才能执行的。

5. >nul,成功的不提示。

6. multiren.bat为本批处理的文件名,不会修改的。

7. 增加了输入文件名通配符过滤,例如"*.c *.h"(输入不包括双引号)。

8. 开头的setlocal是将变量作用域限制在局部,以防修改外部全局变量混淆。

评论 1
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值