GNU ARM汇编--(十三)GNU ARM汇编下的linker script

       在写GNU ARM汇编下的linker script之前,还是有必要看一下ldr指令,以及ldr和adr伪指令.

        ldr指令:

        LDR       load word into a register                                         Rd <- mem32[address]

        ldr伪指令:

        LDR Rd, =constant

        LDR       load constant pseudoinstruction                             Rd=32-bit constant

        adr伪指令:

        ADR Rd, label

        ADR      load address pseudoinstruction                              Rd=32-bit relative address

        我们的程序从nandflash启动,运行在s3c2440的4K大小的SRAM中,linker script的.text放在. = 0x00000000;处.

        测试代码如下:

	ldr pc, _main     @a
	ldr pc, =_main    @b
	ldr pc,main       @c
	ldr pc,=main      @d
	adr pc,_main      @e
	adr pc,main       @e

_main:	.word main

        main中放置的一个流水灯.分别测试这六种情况:

        a.成功跳转,分析下反汇编:

 128:	e51ff004 	ldr	pc, [pc, #-4]	; 12c <_main>

0000012c <_main>:
 12c:	000002d4 	.word	0x000002d4
......

000002d4 <main>:

        0x00000128+8-4=0x0000012c   ldr指令将地址为0x0000012c的word(0x000002d4)放到pc中,那么就跳转到main了.

        b.无法跳转,分析下反汇编:

 128:	e59ff244 	ldr	pc, [pc, #580]	; 374 <fiq+0x40>

0000012c <_main>:
 12c:	000002d4 	.word	0x000002d4
......

000002d4 <main>:

        0x00000128+580+8=0x00000374   ldr指令将地址为 0x00000374的word(374:0000012c.word0x0000012c)放入pc中,自然无法正确跳转

        c.无法跳转,分析下反汇编:

 128:	e59ff1a4 	ldr	pc, [pc, #420]	; 2d4 <main>

0000012c <_main>:
 12c:	000002d4 	.word	0x000002d4
......

000002d4 <main>:

        0x00000128+420+8=0x000002d4  ldr指令将地址为 0x000002d4的word放入pc中,自然也无法跳转

        d.成功跳转,分析下反汇编:

 128:	e59ff244 	ldr	pc, [pc, #580]	; 374 <fiq+0x40>

0000012c <_main>:
 12c:	000002d4 	.word	0x000002d4
......

000002d4 <main>:
......

 374:	000002d4 	.word	0x000002d4

        0x00000128+580+8=0x00000374    ldr指令将地址为 0x00000374的word(000002d4)放入pc中,成功跳转
        e.无法跳转,分析下反汇编:

 128:	e24ff004 	sub	pc, pc, #4	; 0x4

0000012c <_main>:
 12c:	000002d4 	.word	0x000002d4

        pc=pc+8-4=0x0000012c       所以无法跳转

        f.成功跳转,分下下反汇编:

 128:	e28fff69 	add	pc, pc, #420	; 0x1a4

0000012c <_main>:
 12c:	000002d4 	.word	0x000002d4
......

000002d4 <main>:

        pc=pc+420+8=0x00000128+420+8=0x00002d4      所以成功跳转.

      

        完全理解相对跳转和绝对跳转是为了后面的linker script做准备的,linker script的理论只是可以看下gnu.org的官方文档,下面才开始这次的正题.
        

        给出两种linker script的写法:

1.

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(_start)



SECTIONS{


 . = 0x30000000;  
    .text ALIGN(4): {*(.text)}  
    .rodata ALIGN(4) : {*(.rodata)}  
    .data ALIGN(4) : {*(.data)}  
    .bss ALIGN(4) : {*(.bss) *(COMMON)}  
}

vma给的是0x30000000,那么跳转就这么跳:

	ldr pc,=on_sdram  
  
on_sdram:  
  	bl clearsram  

        为了证实后面跑的代码是sdram中的,在跳到sdram后将sram都清除了.

2.

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(_start)



SECTIONS{


 . = 0x00000000;  
    .text ALIGN(4): {*(.text)}  
    .rodata ALIGN(4) : {*(.rodata)}  
    .data ALIGN(4) : {*(.data)}  
    .bss ALIGN(4) : {*(.bss) *(COMMON)}  
}

vma的地址用的是0x00000000,跳转这样写:

	ldr r0,=on_sdram
	add r0,r0,#0x30000000
	mov pc,r0

  
on_sdram:  
  	bl clearsram  

        通过两种链接脚本的对比,这个vma lma,绝对跳转的概念那应该就很清楚了.太晚了,明天给出一个有意思的链接脚本.

       今天晚上有时间,补充一个有点意思的链接脚本:

 

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(_start)


SECTIONS{
  .text1  0x00000000 : 
	{
	start.o(.text)

	}
  .text2  0x30000000 : AT(2048) 
	{
	main.o(.text)
	}

}

        编译出来的二进制文件会大很多,因为.text2段的LMA地址是2048.

        bin档大小为2184

        arm-linux-readelf -a sram2sdram_elf,结果是:

Program Headers:
  Type           Offset   VirtAddr   PhysAddr   FileSiz MemSiz  Flg Align
  LOAD           0x008000 0x00000000 0x00000000 0x003f0 0x003f0 R E 0x8000
  LOAD           0x010000 0x30000000 0x00000800 0x00088 0x00088 R E 0x8000


 Section to Segment mapping:
  Segment Sections...
   00     .text1 
   01     .text2 

第二段.text2的大小是0x88,而.text1的大小是ox3f0,必须要小于2048才行.

        你应该也发现了:2048+0x88 = 2184   这就是最后的bin档大小

       可以vi 最后的bin档看一下, 输入%!xxd后,效果如下:

       从0x3f0到0x800都是0000,这一段都是gap.

        既然是这样,我们的拷贝代码也只能拷贝sram中2048到4096这一部分就可以了.

        有这三个linker script做对比,对linker script和代码跳转可以说理解的比较透了.