VB.net学习笔记(二十一)XML流的读写

版权声明:本文为博主原创文章,遵循 CC 4.0 by-sa 版权协议,转载请附上原文出处链接和本声明。
本文链接:https://blog.csdn.net/dzweather/article/details/51474393

    System.Xml名称空间支持XML的处理,为了生成和浏览XML文档,使用两种访问方式:


一、读写方式

    (一)基于流的方式
    特点:速度快,可连续读写,缺点不能作为节点、元素等进行操作,常用于套接字或文件中获取XML文档。

    (二)基于文档对象模型(DOM)的方式
    特点:使用实体(节点、元素和特性)访问,定位灵活,但速度慢,是存储、读取程序设置首选。(速度慢是因为XML需加载到DOM,故先要将整个文件加载到内存中)

二、基于流的XML读写
          以仅前向的(forward-only)方式读取一块XML,且仅在内存中保存当前节。
          流方式时,程序总是指向文档中的当前节点。
         (一)XML基本认知
           XML以元素(结点)来传输和存储数据,各标签成对出现,大小写敏感,严格对齐。
           例:XML文档如下:

<?xml version="1. 0" encoding="utf-8"?>
<FilmOrder filmId="101”>
<Name>Grease</Name>
<Quantity>10</Quantity>
</FilmOrder>

         上面XML对应的元素及节点如下:

【元 素】             【节点】
XmlDeclaration        <?xml version="1.0" encoding="utf-8"?>
XmlAttribute                            Version               XML 数据中的元素属性
XmlAttribute                            Encoding
XmlElement           FilmOrder                               DOM结构中的元素(节点)
XmlAttribute                            FilmId
XmlElement              Name
XmlText                      Grease                          文本内容
XmlElement              Name
XmlElement              Quantity
XmlText                      10                              文本内容
XmlEndElement           Quantity
XmlWhitespace         Nothing
XmlEndElement        FilmOrder
         (二)XML流的读写
             访问XML流(读取XML)和生成XML流(写入XML)都包含在System.Xml中。

            XmlWriter抽象类:指定一个非缓存的仅前向的流,用于写入一个XML文档(数据和架构);
            XmlReader抽象类:指定一个非缓存的仅前向的流,用于读取个XML文档(数据和架构)。
             (三)写入XML流
             创建XML文档的一种方法是将单独的XML文档组件(架构、特 性、元素等)写入XML流。
            使用单向写入流意味着必须按顺序写入每个元素及其特性--通常是在流的尾部写入数据。
            写入数据需要XML流类(XmlWriter的派生类),生成的XML文档通过流直接被写入文件中。 

          这个被写入的XML文件可以有下面几种状态:
        (1)需创建:使用Create方法来创建XmlWriter类型的实例,使用XmlWriterSettings对象设置实例的所有属性。
        (2)已打开:将文件名传递给XmlWriter的构造函数,可打开已经存在的XML文件。
        (3)已生成:已经生成XML文档。
        (4)已关闭:XmlWriter的Close方法,或者使用Using关键字(Using关键字可确保在Using语句在最后能关闭对象)都可以关闭文件(XML流)。

         创建XmlWriter对象之前,需用XmlWriterSettings对象定义如何处理XML的创建过程,再创建(指明XmlWriterSettings对象与XmlWriter 对象的联系,简言之配置格式)。
Dim FilmOrdersWriter As XmlWriter = XmlWriter.Create(“..\2.xml", myXmlSettings)
‘……..
FilmOrdersWriter.Close()


Using FilmOrdersWriter As XmlWriter =XmlWriter.Create(“\2.xml", myXmlSettings)
‘……..
End Using
           例:创建一个XML文档(2.xml),内容如下:
<?xml version="1.0" encoding="utf-8"?>
<!--Same as generated by serializing, FilmOrder-->
<FilmOrder
  FilmId="101"
  Quantity="10">
  <Title>Grease</Title>
  <Test>
    <clock>ok</clock>
  </Test>
</FilmOrder>
       程序代码如下:
Imports System.Xml
Public Class Form1
    Private Sub btnCreate_Click(sender As Object, e As EventArgs) Handles btnCreate.Click
        Dim xmlWS As New XmlWriterSettings


        xmlWS.Indent = True             '缩进2个字符
        xmlWS.NewLineOnAttributes = True


        Using xmlW As XmlWriter = XmlWriter.Create(Application.StartupPath & "\2.xml", xmlWS)
            xmlW.WriteComment("Same as generated by serializing, FilmOrder") '写入注释
            xmlW.WriteStartElement("FilmOrder")   '必须先写入开始元素,与最后的WriteEndElement配套
            xmlW.WriteAttributeString("FilmId", "101")
            xmlW.WriteAttributeString("Quantity", "10")
            xmlW.WriteElementString("Title", "Grease")
            xmlW.WriteStartElement("Test")
            xmlW.WriteElementString("clock", "ok")
            xmlW.WriteEndElement()
            xmlW.WriteEndElement()
            xmlW.Flush() '强行推入设备(文档)
        End Using
        MessageBox.Show(“完成!”)
    End Sub
End Class
           (四)读取XML流
              从流中读取XML文档,即按顺序遍历流中的数据(首先第一个XML元素,其次第二个XML元素等)。
              因单向向前读取故速度非常快,但缺点是遍历时不支持写入和向后移动等操作。

             用于读取和分析这种XML流的类是XmlReader。

             同XmlWriter一样,创建XMLReader对象前须创建XmlReaderSettings对象,以便指定在由XMLReader.Create方法创建的XmlReader对象上支持的一组功能。

             然后在创建读取对象:

Dim myXmlSettings As New XmlReaderSettings ()
Using readMovielnfo As XmlReader = XmlReader.Create(fileName,myXmlSettings)
           创建后用XmlReader.Read()逐个读取节点,成功则返回True且移动到下一个节点,否则返回false。
           用XmlReader.MoveToNextAttribute逐个读取元素的每一属性。常用的遍历如下:
          (相当于一个指针指向节点,每读一次,指针向前移动一次,指向下一个节点)
            While readMovielnfo.Read()
                '这里处理节点
                While readMovielnfo.MoveToNextAttribute()
                    '这里处理属性
                End While
            End While
         节点的属性介绍:
       (1)Depth:获取 XML 文档中当前节点的深度。例:
<A>
    <B></B>
    <C>
        <D></D>
    </C>
</A>
        元素<A>为根元素,其Depth为0,<B>与<C>子元素的Depth为1,<D>的Depth为2。

      (2)NodeType:节点类型(NodeType),为枚举类型。
成员名称            说明
Attribute         属性(例如,id='123')。
CDATA          CDATA 节(例如,<![CDATA[my escaped text]]>)。
Comment         注释(例如,<!-- my comment -->)。
Document         作为文档树的根的文档对象提供对整个 XML 文档的访问。
DocumentFragment  文档片段。
DocumentType     由以下标记指示的文档类型声明(例如,<!DOCTYPE...>)。
Element          元素(例如,<item>)。
EndElement       末尾元素标记(例如,</item>)。
EndEntity         由于调用 ResolveEntity 而使 XmlReader 到达实体替换的末尾时返回。
Entity            实体声明(例如,<!ENTITY...>)。
EntityReference    实体引用(例如,&num;)。
None            如果未调用 Read 方法,则由 XmlReader 返回。
Notation          文档类型声明中的表示法(例如,<!NOTATION...>)。
ProcessingInstruction  处理指令(例如,<?pi test?>)。
SignificantWhitespace  混合内容模型中标记间的空白或 xml:space="preserve" 范围内的空白。
Text                 节点的文本内容。
Whitespace           标记间的空白。
XmlDeclaration        XML 声明(例如,<?xml version='1.0'?>)。

      (3)Name:节点名称(XmlReader.Name),可以是元.素名(如<FilmOrder>),也可以属性名(如FilmId)。

      (4)AttributeCount:获取当前节点上的属性数。

      (5)Value:获取当前节点的文本值。

       例:仅向前一直读XML文档(前面的2.xml),用遍历方法处理。
                 
Imports System.Xml
Public Class Form1
    Private Sub btnCreate_Click(sender As Object, e As EventArgs) Handles btnCreate.Click
        Dim xmlWS As New XmlWriterSettings


        xmlWS.Indent = True             '缩进2个字符
        xmlWS.NewLineOnAttributes = True


        Using xmlW As XmlWriter = XmlWriter.Create(Application.StartupPath & "\2.xml", xmlWS)
            xmlW.WriteComment("Same as generated by serializing, FilmOrder") '写入注释
            xmlW.WriteStartElement("FilmOrder")   '必须先写入开始元素,与最后的WriteEndElement配套
            xmlW.WriteAttributeString("FilmId", "101")
            xmlW.WriteAttributeString("Quantity", "10")
            xmlW.WriteElementString("Title", "Grease")
            xmlW.WriteStartElement("Test")
            xmlW.WriteElementString("clock", "ok")
            xmlW.WriteEndElement()
            xmlW.WriteEndElement()
            xmlW.Flush() '强行推入设备(文档)
        End Using
        MessageBox.Show(“完成!”)
    End Sub


    Private Sub btnRead_Click(sender As Object, e As EventArgs) Handles btnRead.Click
        Dim xmlRS As New XmlReaderSettings
        Dim strXml As String = ""


        Using xmlR As XmlReader = XmlReader.Create(Application.StartupPath & "\2.xml", xmlRS)
            While xmlR.Read
                strXml &= GetNodeInfo(xmlR) & vbCrLf
                While xmlR.MoveToNextAttribute
                    strXml &= GetNodeInfo(xmlR) & vbCrLf
                End While
            End While
        End Using
        TextBox1.Text = strXml
    End Sub


    Private Function GetNodeInfo(ByVal obj As XmlReader) As String
        Dim strTemp As String = ""


        If obj.Depth > 0 Then   '为了便于显示识别,每增一级下级节点,则前导加4个空格
            For i As Integer = 1 To obj.Depth
                strTemp &= "    "
            Next i
        End If


        If obj.NodeType = XmlNodeType.Whitespace Then
            Return strTemp & obj.NodeType
        ElseIf obj.NodeType = XmlNodeType.Text Then '文本节点无Name
            Return strTemp & obj.NodeType & ":" & obj.Value
        Else
            Return strTemp & obj.Name & ":" & obj.Value & "==" & obj.AttributeCount
        End If


    End Function
End Class
             注意:
              (1)Whitespace也是节点,虽然该类型节点不包含任何名称或属性。该节点的值是空白字符的任意组合(空格、水平制表符和回车等)。图中显示13的即是。
             (2)同一标签的多个属性,处理该节点的下一级,且Depth相同。

           1、XmlReaderSettings 类
             配置包括如何处理空白和架构以及其他注释选项等,这样就不显示一些对程序无用的东西。
              例如,上面程序修改一下:
        Dim xmlRS As New XmlReaderSettings
        Dim strXml As String = ""
        xmlRS.IgnoreComments = True      '忽略注释
        xmlRS.IgnoreWhitespace = True    '忽略空白符
        xmlRS.IgnoreProcessingInstructions = True '忽略处理指令

             对照变化情况的图如下:

     

           2、遍历带来的影响

              遍历会一股脑儿的全查找,XMLReader还有一些方法可以进行技巧处理。


           XmlReader.ReadStartElement 方法 (String)
                检查当前内容节点是否为具有给定 Name 的元素并将读取器推进到下一个节点。
                对此方法的调用相当于调用 IsStartElement 后调用 Read。
               所以产生异常为:IsStartElement 返回 false,或者如果元素的 Name 与给定的 name 不匹配。
          XmlReader.ReadEndElement 方法
               检查当前内容节点是否为结束标记并将读取器推进到下一个节点。
               与前面的相匹配出现。
               异常:当前节点不是一个结束标记,或者如果在输入流中遇到不正确的 XML。
          XmlReader.MoveToContent 方法 ()

               检查当前节点是否是内容(非空白文本、CDATA、Element、EndElement、EntityReference 或 EndEntity)节点。

               如果此节点不是内容节点,则读取器向前跳至下一个内容节点或文件结尾。它跳过以下类型的节点:

               ProcessingInstruction、DocumentType、Comment、Whitespace 或 SignificantWhitespace。

           XmlReader.MoveToElement 方法 ()
                  移动到包含当前属性节点的元素。
          XmlReader.MoveToFirstAttribute 方法 ()
                   移动到第一个属性。
           XmlReader.MoveToNextAttribute 方法 ()
                   移动到下一个属性。

        3、异常处理
              由于Xml文档必须是封闭成对出现,不能混叉;同时对大小写敏感,所以极易出错。最好的办法,就是用程序进行生成,特别注意标签的大小写。
             进行读取时,应先验证Xml文档的正确性。用Try…Catch来捕捉XmlReader.对全部结节进行遍历,从而初步得出是否是一个正确的Xml文档。




展开阅读全文

没有更多推荐了,返回首页