bzoj 2762 树状数组

题意：给出一些形如 ax+b<c 的不等式，三种操作：

（1）新加入一个不等式

（2）删除一个不等式

（3）询问当x=k时满足的不等式的个数

对于每一个不等式，通过变形就可以得到使它成立的x的范围

那么就变成区间修改，单点查询，树状数组维护就好

注意：（1）讨论a=0、a>0、a<0的情况

           （2）由于k有非正数，所以要加上10^6+1，树状数组的范围也改为2*10^6+1，而由于满足不等式条件的x可能超过[-10^6,10^6]，所以当他们超过后直接改为10^6或-10^6

           （3）虽然题目说保证合法，但是它认为多次删除同一个不等式也叫合法...

           （4）因为是小于，所以注意解出来的边界，学习了popoqqq神的方法：如果x>y，则x>=floor(y)+1;如果x<y,则x<=ceil(y)-1

uses math;
const
        range=1000000;
var
        q,x,a,b,c,tot   :longint;
        i               :longint;
        s               :string;
        ch              :char;
        l,r             :array[0..100010] of longint;
        flag            :array[0..100010] of boolean;
        t               :array[0..2100010] of longint;

function find(x:longint):longint;
var
        ans:longint;
begin
   ans:=0;
   while x>0 do
   begin
      inc(ans,t[x]);
      dec(x,x and (-x));
   end;
   exit(ans);
end;

procedure add(x,v:longint);
begin
   while x<=range*2+1 do
   begin
      inc(t[x],v);
      inc(x,x and (-x));
   end;
end;

procedure work(x,a,b,c:longint);
var
        tt:longint;
begin
   if a=0 then
   begin
      if b>c then
      begin
         l[x]:=-range; r[x]:=range;
      end else
      begin
         l[x]:=1; r[x]:=0;
      end;
   end else
   if a>0 then
   begin
      tt:=floor((c-b)/a+1);
      if tt<-range then
      begin
         l[x]:=-range; r[x]:=range;
      end else
      if tt>range then
      begin
         l[x]:=1; r[x]:=0;
      end else
      begin
         l[x]:=tt; r[x]:=range-1;
      end;
   end else
   begin
      tt:=ceil((c-b)/a-1);
      if tt>range then
      begin
         l[x]:=-range; r[x]:=range;
      end else
      if tt<-range then
      begin
         l[x]:=1; r[x]:=0;
      end else
      begin
         l[x]:=-range; r[x]:=tt;
      end;
   end;
end;

begin
   readln(q); tot:=0;
   for i:=1 to q do
   begin
      read(ch); s:='';
      while ch<>' 'do
      begin
         s:=s+ch;
         read(ch);
      end;
      if s='Add' then
      begin
         readln(a,b,c);
         inc(tot);
         work(tot,a,b,c);
         add(l[tot]+range+1,1);
         add(r[tot]+2+range,-1);
      end else
      if s='Query' then
      begin
         readln(x);
         writeln(find(x+range+1));
      end else
      begin
         readln(x);
         if flag[x] then continue;
         flag[x]:=true;
         add(l[x]+range+1,-1);
         add(r[x]+2+range,1);
      end;
   end;
end.

——by Eirlys