--动态横表转纵表
--建表语句
if not object_id('Class1') is null
drop table Class1
Go
Create table Class1([student] nvarchar(2),[数学] int,[物理] int,[英语] int,[语文] int)
Insert Class1
select N'李四',77,85,65,65 union all
select N'张三',87,90,82,78
Go
--横表转纵表
declare @sql nvarchar(4000)
select @sql = isnull(@sql+' union all ','')+'select [student] as [姓名],[学科]='+quotename(Name,'''')
+',[分数]='+quotename(Name)+' from Class1'
from syscolumns where ID = object_id('Class1') and Name not in('student')
exec('select * from('+@sql+')t order by 姓名,[学科]')
--动态纵表转横表
--建表语句
if not object_id('Class') is null
drop table Class
Go
Create table Class([student] nvarchar(2),[subject] nvarchar(2),[grade] int)
Insert Class
select N'张三',N'语文',78 union all
select N'张三',N'数学',87 union all
select N'张三',N'英语',82 union all
select N'张三',N'物理',90 union all
select N'李四',N'语文',65 union all
select N'李四',N'数学',77 union all
select N'李四',N'英语',65 union all
select N'李四',N'物理',85
Go
declare @names nvarchar(600)
set @names = 'select student as 姓名 '
select @names = @names+',max(case Subject when '''+Subject+''' then grade else null end) ['+Subject+']' from (select distinct Subject from class) as a
set @names = @names +',sum(grade) as 总成绩 '
set @names = @names + 'from class group by student'
exec(@names)