【寒假任务】 洛谷1583 魔法照片

问题描述
一共有n（n≤20000）个人（以1–n编号）向佳佳要照片，而佳佳只能把照片给其中的k个人。佳佳按照与他们的关系好坏的程度给每个人赋予了一个初始权值W[i]。然后将初始权值从大到小进行排序，每人就有了一个序号D[i]（取值同样是1–n）。按照这个序号对10取模的值将这些人分为10类。也就是说定义每个人的类别序号C[i]的值为(D[i]-1) mod 10 +1，显然类别序号的取值为1–10。第i类的人将会额外得到E[i]的权值。你需要做的就是求出加上额外权值以后，最终的权值最大的k个人，并输出他们的编号。在排序中，如果两人的W[i]相同，编号小的优先。
输入
第一行输入用空格隔开的两个整数，分别是n和k。
第二行给出了10个正整数，分别是E[1]到E[10]。
第三行给出了n个正整数，第i个数表示编号为i的人的权值W[i]。
输出
只需输出一行用空格隔开的k个整数，分别表示最终的W[i]从高到低的人的编号。
样例输入
10 10
1 2 3 4 5 6 7 8 9 10
2 4 6 8 10 12 14 16 18 20
样例输出
10 9 8 7 6 5 4 3 2 1
算法讨论
数据较大，选用快排。先排序一遍，再求出每个人的分类，加上各自的附加值后再快排一次。

const
  maxn=20000;
var
  a:array[1..maxn,1..3] of longint;
  e:array[1..maxn] of longint;
  i,j,n,k:longint;

procedure qsort(l,r:longint);
var
  i,j,t,m,m1:longint;
begin
  i:=l; j:=r;
  m:=a[(l+r) div 2,1];
  m1:=a[(l+r) div 2,2];
  repeat
    while (a[i,1]>m) or (a[i,1]=m) and (a[i,2]<m1) do
      inc(i);
    while (a[j,1]<m) or (a[j,1]=m) and (a[j,2]>m1) do
      dec(j);
    if i<=j
      then begin
             t:=a[i,1]; a[i,1]:=a[j,1]; a[j,1]:=t;
             t:=a[i,2]; a[i,2]:=a[j,2]; a[j,2]:=t;
             t:=a[i,3]; a[i,3]:=a[j,3]; a[j,3]:=t;
             inc(i); dec(j)
           end;
  until i>j;
  if l<j
    then qsort(l,j);
  if i<r
    then qsort(i,r)
end;

begin
  read(n,k);
  for i:=1 to 10 do
    read(e[i]);
  for i:=1 to n do
    begin
      read(a[i,1]);
      a[i,2]:=i
    end;
  qsort(1,n);
  for i:=1 to n do
    a[i,3]:=((i-1) mod 10)+1;
  for i:=1 to n do
    a[i,1]:=a[i,1]+e[a[i,3]];
  qsort(1,n);
  for i:=1 to k do
    write(a[i,2],' ')
end.

Pixiv ID：59382010