有趣的ABAP游戏3-砖块消除

最新推荐文章于 2023-08-22 08:40:36 发布
最新推荐文章于 2023-08-22 08:40:36 发布
阅读量903 收藏
点赞数
文章标签： 游戏 table integer random header function
 REPORT  zz_jawbreaker NO STANDARD PAGE HEADING.

TYPE-POOLS: icon.

TYPES:
  ty_farbe(2) TYPE n.

DATA:
  g_max_x(3)      TYPE n,
  punkte(5)       TYPE n,
  punkte1         TYPE i,
  punkte_undo     TYPE i,
  punktec(5)      TYPE c,
  l_x(2)          TYPE n,
  l_y(2)          TYPE n,
  l_line          TYPE i,
  l_feld(20)      TYPE c,
  l_tabix         TYPE i,
  l_anzahl        TYPE i,
  l_farbe         TYPE ty_farbe,
  l_spalte(2)     TYPE n,
  t_spalte        TYPE STANDARD TABLE OF ty_farbe,

  BEGIN OF spielfeld OCCURS 0,
    x(2)          TYPE n,
    y(2)          TYPE n,
    farbe(2)      TYPE n,
    mark          TYPE c,
  END OF spielfeld,
  spielfeld2      LIKE spielfeld OCCURS 0 WITH HEADER LINE,
  spielfeld_undo  LIKE spielfeld OCCURS 0 WITH HEADER LINE,
  l_spiel         LIKE spielfeld.

*** Spielfeld ***
SELECTION-SCREEN BEGIN OF BLOCK sfeld WITH FRAME TITLE text-fld.
PARAMETERS:
  p_x(2)          TYPE n DEFAULT 15,
  p_y(2)          TYPE n DEFAULT 15,
  p_farben(1)     TYPE c DEFAULT 5.
SELECTION-SCREEN END OF BLOCK sfeld.

*** Spielmodus ***
SELECTION-SCREEN BEGIN OF BLOCK modus WITH FRAME TITLE text-mod.
PARAMETERS:
  p_norm          RADIOBUTTON GROUP mod DEFAULT 'X',
  p_fort          RADIOBUTTON GROUP mod.
SELECTION-SCREEN END OF BLOCK modus.

AT SELECTION-SCREEN.
  IF p_farben > 7.
    p_farben = 7.
    MESSAGE w000(su) WITH 'Nur 7 Farben m?glich!'.
  ENDIF.

START-OF-SELECTION.

  PERFORM init.

  PERFORM spielfeld_malen.

AT LINE-SELECTION.

  GET CURSOR FIELD l_feld LINE l_y.

  IF l_feld = 'ICON_SYSTEM_UNDO'.
*** Undo-Funktion
    spielfeld[] = spielfeld_undo[].
    SUBTRACT punkte_undo FROM punkte.
    CLEAR punkte_undo.
  ELSE.
    l_x = ( sy-cucol  - 1 ) / 2.


    READ TABLE spielfeld WITH KEY x = l_x
                                  y = l_y.
    IF sy-subrc = 0.
      l_tabix = sy-tabix.
      l_farbe = spielfeld-farbe.
      CASE spielfeld-mark.

        WHEN 1.
*** Erster Klick:
*-- Alte Auswahl l?schen
          LOOP AT spielfeld INTO l_spiel WHERE mark = 0.
            l_spiel-mark = 1.
            MODIFY spielfeld FROM l_spiel.
          ENDLOOP.

*-- Undo
          spielfeld_undo[] = spielfeld[].

*-- Neue Auswahl
          CLEAR punkte1.
          spielfeld-mark = 0.
          MODIFY spielfeld INDEX l_tabix.
          PERFORM suchen USING l_x l_y l_farbe.
          l_anzahl = 0.
          LOOP AT spielfeld INTO l_spiel WHERE mark = 0.
            ADD 1 TO l_anzahl.
          ENDLOOP.
          IF l_anzahl < 2.
            READ TABLE spielfeld INDEX l_tabix.
            IF sy-subrc = 0.
              spielfeld-mark = 1.
              MODIFY spielfeld INDEX l_tabix.
            ENDIF.
          ELSE.
            punkte1 = l_anzahl * l_anzahl.
          ENDIF.

        WHEN 0.
*** Zweiter Klick: L?schen der markierten felder.
          LOOP AT spielfeld WHERE mark = 0.
            spielfeld-farbe = 0.
            spielfeld-mark  = 2.
            MODIFY spielfeld.
          ENDLOOP.
          ADD punkte1 TO punkte.
          punkte_undo = punkte1.
          CLEAR punkte1.
          PERFORM rutschen.
          PERFORM rechts_sammeln.
          PERFORM auffuellen.
          PERFORM ende_pruefen.
        WHEN OTHERS.
      ENDCASE.
    ENDIF.
  ENDIF.

  PERFORM spielfeld_malen.

*&--------------------------------------------------------------------*
*&      Form  suchen
*&--------------------------------------------------------------------*
*      -->F_X        text
*      -->F_Y        text
*      -->F_FARBE    text
*---------------------------------------------------------------------*
FORM suchen USING f_x f_y f_farbe.

  DATA:
    u_x(2) TYPE n,
    u_y(2) TYPE n.

  u_y = f_y.
  u_x = f_x - 1.
  PERFORM test USING u_x u_y f_farbe 'X'.

  u_x = f_x + 1.
  PERFORM test USING u_x u_y f_farbe 'X'.

  u_x = f_x.
  u_y = f_y - 1.
  PERFORM test USING u_x u_y f_farbe 'X'.

  u_y = f_y + 1.
  PERFORM test USING u_x u_y f_farbe 'X'.


ENDFORM.                                                    "suchen

*&--------------------------------------------------------------------*
*&      Form  test
*&--------------------------------------------------------------------*
*      -->F_X        text
*      -->F_Y        text
*      -->F_FARBE    text
*---------------------------------------------------------------------*
FORM test USING value(f_x) value(f_y) f_farbe f_rekursiv.

  IF f_x = 0 OR f_x > p_x OR f_y = 0 OR f_y > p_y.
    EXIT.
  ELSE.
    READ TABLE spielfeld INTO l_spiel
         WITH KEY x = f_x  y = f_y.
    IF sy-subrc      = 0 AND
       l_spiel-farbe = f_farbe AND
       l_spiel-mark  = 1.
      l_spiel-mark = 0.
      MODIFY spielfeld FROM l_spiel INDEX sy-tabix.
      IF f_rekursiv = 'X'.
        PERFORM suchen USING f_x f_y f_farbe.
      ENDIF.
    ENDIF.
  ENDIF.

ENDFORM.                                                    "test

*&--------------------------------------------------------------------*
*&      Form  init
*&--------------------------------------------------------------------*
FORM init.

  g_max_x = p_x * 3 + 1.

  DO p_x TIMES.
    l_x = sy-index.

    DO p_y TIMES.
      l_y = sy-index.

      spielfeld-x = l_x.
      spielfeld-y = l_y.
      PERFORM zufallsfarbe CHANGING spielfeld-farbe.
      spielfeld-mark = 1.
      APPEND spielfeld.

    ENDDO.

  ENDDO.

  spielfeld_undo[] = spielfeld[].

ENDFORM.                                                    "init

*&--------------------------------------------------------------------*
*&      Form  spielfeld_malen
*&--------------------------------------------------------------------*
FORM spielfeld_malen.

  DATA l_pos TYPE i.

  SET BLANK LINES ON.
  sy-lsind = 0.
  SKIP TO LINE 1.

  IF punkte =  0.
    punktec = 'null'.
  ELSE.
    WRITE punkte TO punktec NO-ZERO LEFT-JUSTIFIED.
  ENDIF.
*** Titel: "Jawbreaker: & Punkte"
  SET TITLEBAR 'JAW' WITH punktec.

  DO p_y TIMES.
    l_y = sy-index.
    l_pos = 1.
    DO p_x TIMES.
      l_x = sy-index.
      READ TABLE spielfeld WITH KEY x = l_x
                                    y = l_y.
      IF sy-subrc = 0.
        IF spielfeld-farbe = 2.
          WRITE: '..' NO-GAP HOTSPOT OFF.
        ELSEIF spielfeld-mark = 1.
          WRITE: '  ' COLOR = spielfeld-farbe NO-GAP
                    HOTSPOT ON INTENSIFIED = spielfeld-mark.
        ELSE.
          WRITE: '**' COLOR = spielfeld-farbe NO-GAP
                    HOTSPOT ON INTENSIFIED ON .
        ENDIF.
      ENDIF.
      ADD 2 TO l_pos.
    ENDDO.
    NEW-LINE.
  ENDDO.

  SKIP 1.
  WRITE: / 'Punkte:', punkte1 NO-ZERO.
  WRITE AT 30 icon_system_undo AS ICON HOTSPOT ON.

ENDFORM.                    "spielfeld_aufbauen

*&--------------------------------------------------------------------*
*&      Form  zufallsfarbe
*&--------------------------------------------------------------------*
FORM zufallsfarbe CHANGING f_farbe.

  DATA:
    l_min TYPE i,
    l_max TYPE i,
    l_rnd TYPE i.

  l_min = 3.
  l_max = p_farben + 2.

  CALL FUNCTION 'QF05_RANDOM_INTEGER'
       EXPORTING
            ran_int_max   = l_max
            ran_int_min   = l_min
       IMPORTING
            ran_int       = l_rnd
       EXCEPTIONS
            invalid_input = 1
            OTHERS        = 2.

  f_farbe = l_rnd.

ENDFORM.                    "zufallsfarbe

*&--------------------------------------------------------------------*
*&      Form  rutschen
*&--------------------------------------------------------------------*
FORM rutschen.

  DATA:
    l_y2(2)  TYPE n.

  DO p_x TIMES.
    l_x = sy-index.
    l_y = p_y.
    CLEAR t_spalte.
    DO p_y TIMES.
      READ TABLE spielfeld WITH KEY x = l_x y = l_y.

      IF spielfeld-farbe <> 0.
        APPEND spielfeld-farbe TO t_spalte.
      ENDIF.
      SUBTRACT 1 FROM l_y.

    ENDDO.
    l_y2 = p_y.
    DO p_y TIMES.
      READ TABLE spielfeld WITH KEY x = l_x y = l_y2.
      l_tabix = sy-tabix.
      READ TABLE t_spalte INTO spielfeld-farbe INDEX sy-index.
      IF sy-subrc = 0.
        spielfeld-mark = 1.
      ELSE.
        spielfeld-farbe = 2.
        spielfeld-mark  = 1.
      ENDIF.
      MODIFY spielfeld INDEX l_tabix.
      SUBTRACT 1 FROM l_y2.
    ENDDO.

  ENDDO.

ENDFORM.                                                    "rutschen

*&--------------------------------------------------------------------*
*&      Form  rechts_sammeln
*&--------------------------------------------------------------------*
FORM rechts_sammeln.

  DATA:
    l_y2(2)  TYPE n.

*** Rechts beginnen
  l_x = p_x.
  DO p_x TIMES.
    DO p_x TIMES.
*** Prüfen, ob die Spalte leer ist
      LOOP AT spielfeld WHERE x = l_x
                          AND farbe <> 2.
        EXIT.
      ENDLOOP.
      IF sy-subrc = 0.
*** spalte nicht leer; schleife verlassen
        EXIT.                                               "from do
      ELSE.
** spalte ist leer
        l_spalte = l_x - 1.
        DO l_x TIMES.
          PERFORM verschiebe_spalte USING l_spalte.
          SUBTRACT 1 FROM l_spalte.
        ENDDO.
      ENDIF.
    ENDDO.
    SUBTRACT 1 FROM l_x.
  ENDDO.

ENDFORM.                    "rechts_sammeln


*&--------------------------------------------------------------------*
*&      Form  verschiebe_spalte
*&--------------------------------------------------------------------*
FORM verschiebe_spalte USING f_spalte.

  DATA: l_spalte2(2) TYPE n.
  CLEAR t_spalte.

  LOOP AT spielfeld WHERE x = f_spalte.

    APPEND spielfeld-farbe TO t_spalte.
    spielfeld-farbe = 2.
    spielfeld-mark  = 1.
    MODIFY spielfeld.
  ENDLOOP.

  l_spalte2 = f_spalte + 1.
  l_tabix = 0.
  LOOP AT spielfeld WHERE x = l_spalte2.
    ADD 1 TO l_tabix.
    READ TABLE t_spalte INTO spielfeld-farbe INDEX l_tabix.
    MODIFY spielfeld.

  ENDLOOP.

ENDFORM.                    "verschiebe_spalte

*---------------------------------------------------------------------*
*       FORM ende_pruefen                                             *
*---------------------------------------------------------------------*
FORM ende_pruefen.

  DATA:
      u_x(2)  TYPE n,
      u_y(2)  TYPE n,

      v_x(2)  TYPE n,
      v_y(2)  TYPE n,

      v_farbe TYPE ty_farbe.


  spielfeld2[] = spielfeld[].


  DO p_x TIMES.
    v_x = sy-index.
    DO p_y TIMES.
      v_y = sy-index.
      READ TABLE spielfeld2 WITH KEY x = v_x y = v_y.
      CHECK spielfeld2-farbe > 2.
      v_farbe = spielfeld2-farbe.
      u_x = v_x - 1.
      u_y = v_y.
      PERFORM test USING u_x u_y v_farbe ' '.

      u_x = v_x + 1.
      PERFORM test USING u_x u_y v_farbe ' '.

      u_x = v_x.
      u_y = v_y - 1.
      PERFORM test USING u_x u_y v_farbe ' '.

      u_y = v_y + 1.
      PERFORM test USING u_x u_y v_farbe ' '.
    ENDDO.
  ENDDO.

  LOOP AT spielfeld WHERE mark = 0.

  ENDLOOP.
  IF sy-subrc > 0.
    SKIP p_y.
    SKIP 4.
    WRITE: / 'Spiel ist zuende! Gewinnpunkte:', punkte NO-ZERO.
  ELSE.
    spielfeld[] = spielfeld2[].
  ENDIF.

ENDFORM.

*---------------------------------------------------------------------*
*       FORM spalte_auffuellen                                        *
*---------------------------------------------------------------------*
FORM spalte_auffuellen USING value(fx).

  DATA:
    l_frb TYPE ty_farbe,
    l_anz TYPE i,
    l_min TYPE i,
    l_max TYPE i,
    l_rnd TYPE i,
    l_row TYPE i.

  l_max = p_y.
  l_min = 1.

  CALL FUNCTION 'QF05_RANDOM_INTEGER'
       EXPORTING
            ran_int_max   = l_max
            ran_int_min   = l_min
       IMPORTING
            ran_int       = l_rnd
       EXCEPTIONS
            invalid_input = 1
            OTHERS        = 2.

  l_row = p_y.
  DO l_rnd TIMES.
    READ TABLE spielfeld WITH KEY x = fx y = l_row.
    l_tabix = sy-tabix.
    PERFORM zufallsfarbe USING spielfeld-farbe.
    MODIFY spielfeld INDEX l_tabix.
    SUBTRACT 1 FROM l_row.
  ENDDO.

ENDFORM.

*---------------------------------------------------------------------*
*       FORM auffuellen                                               *
*---------------------------------------------------------------------*
FORM auffuellen.

  DATA l_spalte(2) TYPE n.

  IF p_fort = 'X'.

    l_spalte = p_x.
    DO p_x TIMES.
      LOOP AT spielfeld WHERE x = l_spalte AND farbe <> 2.
      ENDLOOP.
      IF sy-subrc > 0.
        PERFORM spalte_auffuellen USING l_spalte.
      ENDIF.
      SUBTRACT 1 FROM l_spalte.
    ENDDO.
  ENDIF.

ENDFORM.
fanweijun
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
abap写的小游戏 数字移动小游戏
forever_crazy的专栏
06-13 1786
项目后期维护，没什么事情干，闲着无聊，今天写了个小游戏玩玩：(注：由于代码不能从客户那边带回来，回家用记事本写的，注释也比较少，但是代码实现的逻辑很简单，不解释。。。。。 如有编译错误请谅解，    灰常感谢！！！！) report ......selection-screen pushbutton 2(10)  pb11 user-command pb11.selecti
有趣的ABAP游戏2-拼图
SAP冲击波的专栏
11-26 1194
REPORT z_number_puzzle.* Declarations.DATA: v_first TYPE xfeld,      v_won   TYPE xfeld.DATA: BEGIN OF v_name,       name TYPE char4,       num  TYPE char1,      END OF v_name.DATA: v_blank_push LIKE
SAP ABAP ALV开发坦克大战小游戏
最新发布
qq_32349893的博客
08-22 1407
我自己尝试用ALV报表去做坦克大战，因为只能工作间隙的时间的去开发，所以开发时间比较长，而且我的初衷不是为了开发游戏，而是通过开发游戏加深理解OO编程思想，在游戏代码，能尽量用OO的都用OO，开发的中间自己还去查询相关技术文档，经过这次开发，我理解到OO确实好用，但是强行使用的话，也会使开发者感觉碍手碍脚。下图是可以自己设置游戏场景的墙体部分的位置，大家也可以自己去开发新的对战场景，如下图确定每個点的坐标，A点在2行3列则坐标是（2，3），同理可以确定B点坐标（2，8），C点坐标（6，8）
ABAP编写的小游戏
Joshua's SAP territory
05-29 2355
*&---------------------------------------------------------------------* *& Report  Z_BUTTON_GAME                                               * *&
ABAP小游戏：消灭星星Pop star
少年休闲海
06-04 2099
推荐一款ABAP小游戏，搔搔哒！！！ 熟悉ABAP开发的童鞋可能很容易能够看出该程序的构造，它其实就是一个上下分的split container，上面部分是TOP-OF-PAGE,下面部分是一个ALV。 http://mp.weixin.qq.com/s?__biz=MzI3MzAwMzM4NA==&mid=401875250&idx=1&sn=c7bfbb112ac1ec
ABAP游戏：扫雷_SAP刘梦_新浪博客
森林木的博客
06-03 330
代码 *&---------------------------------------------------------------------* *&ReportZLM_GAME2 *&---------------------------------------------------------------------* *&a...
ABAP开发 扫雷小游戏
SAP自学之路
11-12 959
*&---------------------------------------------------------------------* *&ReportZGAME_SAOLEI *&---------------------------------------------------------------------* *& *&--------------------------------------------------------------..
《ABAP开发要点---PP模块》
06-07
### ABAP开发要点——PP模块 #### 概述 在SAP系统中，PP（Production Planning）模块主要用于处理企业的生产规划与控制业务。对于从事ABAP（Advanced Business Application Programming）开发的技术人员而言，掌握...
eclipse-abap-keywordcolors-master.rar
05-17
eclipse-abap-keywordcolors eclipse-abap-关键字颜色
abap-metrics-provider:让我们使用预定义或自定义指标通过您选择的监视工具来监视abap堆栈
05-17
abap-metrics提供者 兼容性 建筑学 组件图 类图 提供者 刮刀 文件资料 本地测试 本地测试文件夹 影片播放清单 基于 https://github.com/pacroy/abap-prometheus
ABAP程序的8种类型
03-25
我们在用事务码 SE38 创建新程序时，总是被要求指定一个程序类型，这些程序类型分别完成不同的功能，如果选择错误，程序就可能无法运行。下面一一介绍这些程序类型：
abap-openapi-client:ABAP中的ABAP OpenAPI客户端生成器
05-19
abap-openapi-client ABAP中的ABAP 客户端生成器 通过命令行运行的可能性（NodeJS） 有可能针对不同的ABAP版本（例如Steampunk）生成 每个OpenAPI定义一个独立的全局类+接口 可以在ABAP堆栈上运行生成 最终支持...
ABAP751 ABAP - Keyword Documentation
10-23
ABAP - Keyword Documentation This documentation describes the syntax and meaning of the keywords of the ABAP language and its object-oriented part ABAP Objects. Alongside this, language frameworks ...
ABAP屏幕实战之24点小游戏
a24244的博客
09-18 347
先放图，做一个简单的屏幕实战，主要实现24点小游戏。 好的，让我们分解步骤。 1，创建一个屏幕。 2，往上拖元素，界面如上，没什么特别值得注意的地方。 3，写程序。 好的，做完了，我们下期再见。 Emmm.... 还是说下程序的点，虽然是个简单的小程序，但是写起来需要注意的地方还是很多的。 1，四个随机的数字的给出，这里把2-10以及...
ABAP-神奇程序在这里（持续跟新）
u012232542的博客
06-26 949
程序BALVBUFDEL：清除ALV缓存，在数据字典变动时，若ALV输入不一致，可使用该函数 函数模块CTVB_COMPARE_TABLES：对比新旧两个内表，获得变更的条目 类CL_GUI_PROPS_CONSUMER: 获取window系统&GUI的属性，比如分辨率，屏幕大小 类CL_SHDB_SELTAB：将selection table转换为where condition ...
abap game2
SAPHOME的专栏
11-10 725
REPORT z_number_puzzle. * Declarations. DATA: v_first TYPE xfeld,       v_won   TYPE xfeld. DATA: BEGIN OF v_name,        name TYPE char4,        num  TYPE char1,       END OF v_name. DATA: v_
ABAP小游戏数字华容道（拼图游戏）
qq_32349893的博客
08-11 212
其实就是拼图游戏的简化版，拼图游戏是将每個方块移动组合，组成完整拼图，现在是改成按数字大小从左到右排列，顺序对了就成功，然后记录花费时间，我是只做了9个拼图的数字拼图，大家可以下载后，自己尝试修改扩展成16个或25个的拼图。点击EXIT按钮，可以看到数据排名，既然是有数据库记录，当然可以把游戏分享给你的同事一起比赛，看看谁的游戏时间更快。2，然后打开SE38，复制下面程序代码，激活后就可以开始游戏了，代码量不多，只有700行。点解START按钮，会出现随机打乱的数字，移动数字，让数字按从小到大排序。
使用ABAP Push Channel(APC)开发的乒乓球游戏，可双打
weixin_34183910的博客
04-06 120
url： https://&lt;host>:<port>/sap/bc/apc_test/ping_pong/game 或者事务码SICF, 输入ping_pong, 按F8： 选中搜索结果，点右键选择Test，即可打开url。 两个玩家分别通过执行report RS_APC_PING_PONG加入游戏。通...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值