u-boot移植（一）---u-boot启动流程分析

U-Boot为2阶段启动的Bootloader:

    第一阶段文件为U-Boot解压目录中的：cpu/arm920t/start.S和board/smdk2410/lowlevel.S（基于ARM平台），主要完成硬件初始化工作，为第二阶段准备RAM存储空间.

   第二阶段文件为lib_arm(ARM平台相关文件目录)/board.c中的start_armboot函数开始.主要完成初始化IRQ/FIQ, 系统时钟，定时器，等以及外围设备的初始化工作.

 

U-Boot第一阶段代码分析：

    1.主要是在cpu/arm920t/start.S完成第一部分的硬件初始化部分的工作，主要的是设置CPU 工作模式为svc（管理模式），关闭WATCHDOG, 设置FCLK,HCLK,PCLK,的比例，关闭MMU，CACHE等.(额～看的有些晕,翠花上代码...)

 

 /*cpu/arm920t/start.S*
 *************************************************************************
 *
 * Jump vector table as in table 3.1 in [1]
 *
 *************************************************************************
 */
.globl _start
_start: b       reset     //跳转到reset处运行.
 ldr pc, _undefined_instruction
 ldr pc, _software_interrupt
 ldr pc, _prefetch_abort
 ldr pc, _data_abort
 ldr pc, _not_used
 ldr pc, _irq
 ldr pc, _fiq

_undefined_instruction: .word undefined_instruction
_software_interrupt: .word software_interrupt
_prefetch_abort: .word prefetch_abort
_data_abort:  .word data_abort
_not_used:  .word not_used
_irq:   .word irq
_fiq:   .word fiq

 .balignl 16,0xdeadbeef

.......省略N行.具体文件请参考cpu/arm920t/start.S源文件

reset:
 /*
  * set the cpu to SVC32 mode 第一步运行设置cup为SVC工作模式;
  */
 mrs r0,cpsr   
 bic r0,r0,#0x1f   //BIC 位清除指令,清楚cpsr的0～4共5位;
 orr r0,r0,#0xd3  //逻辑或指令;11010011
 msr cpsr,r0

 /*讲些小废话：（老鸟别笑，您可以把我完全忽略.）

  *关于CPSR寄存器:CPSR寄存器为当前程序状态寄存器，那他有什么作用呢 具体的作用大家google之随便查都有，这里只跟大家聊一下他的几个控制位，他的M[4:0]位的变化可以修改ARM芯片存在7中工作模式：10000--用户模式， 10001--快速中断模式（FIQ）, 10010--终端模式， 10011--管理模式（SVC）， 10111--数据访问中止模式， 11111-- 系统模式在不同的工作模式下ARM芯片会对访问的寄存器的权限有所差别. 代码分析： mrs r0, cpsr 将当前程序状态寄存器的值传到通用寄存器R0中， bic r0, r0, #0x1f 清除cpsr的0～4共5位, orr r0,r0, #0xd3 将11010011的值赋予r0，msr cpsr,r0, 赋值cpsr0～7位 低5位为10011对应svc*/

 

/*关闭看门狗*/

/*定义WTCON, INTMSK CLKDIVN 等寄存器地址*/
#if defined(CONFIG_S3C2400)
# define pWTCON  0x15300000
# define INTMSK  0x14400008 /* Interupt-Controller base addresses */
# define CLKDIVN 0x14800014 /* clock divisor register */
#elif defined(CONFIG_S3C2410)
# define pWTCON  0x53000000
# define INTMSK  0x4A000008 /* Interupt-Controller base addresses */
# define INTSUBMSK 0x4A00001C
# define CLKDIVN 0x4C000014 /* clock divisor register */
#endif

#if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)
 ldr     r0, =pWTCON
 mov     r1, #0x0
 str     r1, [r0]

/*怎样才能关闭看门口？额～！往WTCON（看门狗时间控制寄存器）写0即可，*/

 

 /*
  * 屏蔽所有IRQ终端服务
  */
 mov r1, #0xffffffff
 ldr r0, =INTMSK
 str r1, [r0]

/*INTMSK寄存器说明：当某一位被设置为 1时，INTMSK寄存器不会对当前相应位的中断请求响应提供服务，设置为0 恰好相反.*/
# if defined(CONFIG_S3C2410)
 ldr r1, =0x3ff
 ldr r0, =INTSUBMSK
 str r1, [r0]
# endif

/*INTSUBMSK寄存器说明：当某一位被设置为 1时，INTSUBMSK寄存器不会对当前相应位的中断请求响应提供服务，设置为0 恰好相反.*/

/* FCLK:HCLK:PCLK = 1:2:4 */
 /* default FCLK is 120 MHz ! */
 ldr r0, =CLKDIVN
 mov r1, #3
 str r1, [r0]
#endif /* CONFIG_S3C2400 || CONFIG_S3C2410 */（ing~!）