交流--数据库备份/恢复方案

转载 2004年08月13日 10:28:00

/*--备份数据库

--邹建 2003.10--*/

/*--调用示例

--备份当前数据库
exec p_backupdb @bkpath='c:/',@bkfname='db_/DATE/_db.bak'

--差异备份当前数据库
exec p_backupdb @bkpath='c:/',@bkfname='db_/DATE/_df.bak',@bktype='DF'

--备份当前数据库日志
exec p_backupdb @bkpath='c:/',@bkfname='db_/DATE/_log.bak',@bktype='LOG'

--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_backupdb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_backupdb]
GO

create proc p_backupdb
@dbname sysname='',   --要备份的数据库名称,不指定则备份当前数据库
@bkpath nvarchar(260)='', --备份文件的存放目录,不指定则使用SQL默认的备份目录
@bkfname nvarchar(260)='', --备份文件名,文件名中可以用/DBNAME/代表数据库名,/DATE/代表日期,/TIME/代表时间
@bktype nvarchar(10)='DB', --备份类型:'DB'备份数据库,'DF' 差异备份,'LOG' 日志备份
@appendfile bit=1   --追加/覆盖备份文件
as
 declare @sql varchar(8000)
 if isnull(@dbname,'')='' set @dbname=db_name()
 if isnull(@bkpath,'')='' set @bkpath=dbo.f_getdbpath(null)
 if isnull(@bkfname,'')='' set @bkfname='/DBNAME/_/DATE/_/TIME/.BAK'
 set @bkfname=replace(replace(replace(@bkfname,'/DBNAME/',@dbname)
  ,'/DATE/',convert(varchar,getdate(),112))
  ,'/TIME/',replace(convert(varchar,getdate(),108),':',''))
 set @sql='backup '+case @bktype when 'LOG' then 'log ' else 'database ' end +@dbname
  +' to disk='''+@bkpath+@bkfname
  +''' with '+case @bktype when 'DF' then 'DIFFERENTIAL,' else '' end
  +case @appendfile when 1 then 'NOINIT' else 'INIT' end
 print @sql
 exec(@sql)
go

----------------------------------------------------------------------
/*--恢复数据库

--邹建 2003.10--*/

/*--调用示例
--完整恢复数据库
exec p_RestoreDb @bkfile='c:/db_20031015_db.bak',@dbname='db'

--差异备份恢复
exec p_RestoreDb @bkfile='c:/db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:/db_20031015_df.bak',@dbname='db',@retype='DF'

--日志备份恢复
exec p_RestoreDb @bkfile='c:/db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:/db_20031015_log.bak',@dbname='db',@retype='LOG'

--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_RestoreDb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_RestoreDb]
GO

create proc p_RestoreDb
@bkfile nvarchar(1000),  --定义要恢复的备份文件名
@dbname sysname='',      --定义恢复后的数据库名,默认为备份的文件名
@dbpath nvarchar(260)='', --恢复后的数据库存放目录,不指定则为SQL的默认数据目录
@retype nvarchar(10)='DB', --恢复类型:'DB'完事恢复数据库,'DBNOR' 为差异恢复,日志恢复进行完整恢复,'DF' 差异备份的恢复,'LOG' 日志恢复
@filenumber int=1,   --恢复的文件号
@overexist bit=1,        --是否覆盖已经存在的数据库,仅@retype为
@killuser bit=1       --是否关闭用户使用进程,仅@overexist=1时有效
as
declare @sql varchar(8000)

--得到恢复后的数据库名
if isnull(@dbname,'')=''
 select @sql=reverse(@bkfile)
  ,@sql=case when charindex('.',@sql)=0 then @sql
   else substring(@sql,charindex('.',@sql)+1,1000) end
  ,@sql=case when charindex('/',@sql)=0 then @sql
   else left(@sql,charindex('/',@sql)-1) end
  ,@dbname=reverse(@sql)

--得到恢复后的数据库存放目录
if isnull(@dbpath,'')='' set @dbpath=dbo.f_getdbpath('')

--生成数据库恢复语句
set @sql='restore '+case @retype when 'LOG' then 'log ' else 'database ' end+@dbname
 +' from disk='''+@bkfile+''''
 +' with file='+cast(@filenumber as varchar)
 +case when @overexist=1 and @retype in('DB','DBNOR') then ',replace' else '' end
 +case @retype when 'DBNOR' then ',NORECOVERY' else ',RECOVERY' end
print @sql
--添加移动逻辑文件的处理
if @retype='DB' or @retype='DBNOR'
begin
 --从备份文件中获取逻辑文件名
 declare @lfn nvarchar(128),@tp char(1),@i int

 --创建临时表,保存获取的信息
 create table #tb(ln nvarchar(128),pn nvarchar(260),tp char(1),fgn nvarchar(128),sz numeric(20,0),Msz numeric(20,0))
 --从备份文件中获取信息
 insert into #tb exec('restore filelistonly from disk='''+@bkfile+'''')
 declare #f cursor for select ln,tp from #tb
 open #f
 fetch next from #f into @lfn,@tp
 set @i=0
 while @@fetch_status=0
 begin
  select @sql=@sql+',move '''+@lfn+''' to '''+@dbpath+@dbname+cast(@i as varchar)
   +case @tp when 'D' then '.mdf''' else '.ldf''' end
   ,@i=@i+1
  fetch next from #f into @lfn,@tp
 end
 close #f
 deallocate #f
end

--关闭用户进程处理
if @overexist=1 and @killuser=1
begin
 declare @spid varchar(20)
 declare #spid cursor for
  select spid=cast(spid as varchar(20)) from master..sysprocesses where dbid=db_id(@dbname)
 open #spid
 fetch next from #spid into @spid
 while @@fetch_status=0
 begin 
  exec('kill '+@spid)
  fetch next from #spid into @spid
 end 
 close #spid
 deallocate #spid
end

--恢复数据库
exec(@sql)

go
/*--创建作业

--邹建 2003.10--*/

/*--调用示例

--每月执行的作业
exec p_createjob @jobname='mm',@sql='select * from syscolumns',@freqtype='month'

--每周执行的作业
exec p_createjob @jobname='ww',@sql='select * from syscolumns',@freqtype='week'

--每日执行的作业
exec p_createjob @jobname='a',@sql='select * from syscolumns'

--每日执行的作业,每天隔4小时重复的作业
exec p_createjob @jobname='b',@sql='select * from syscolumns',@fsinterval=4

--*/
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_createjob]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_createjob]
GO

create proc p_createjob
@jobname varchar(100),  --作业名称
@sql varchar(8000),   --要执行的命令
@dbname sysname='',   --默认为当前的数据库名
@freqtype varchar(6)='day', --时间周期,month 月,week 周,day 日
@fsinterval int=1,   --相对于每日的重复次数
@time int=170000   --开始执行时间,对于重复执行的作业,将从0点到23:59分
as
if isnull(@dbname,'')='' set @dbname=db_name()

--创建作业
exec msdb..sp_add_job @job_name=@jobname

--创建作业步骤
exec msdb..sp_add_jobstep @job_name=@jobname,
 @step_name = '数据处理',
 @subsystem = 'TSQL',
 @database_name=@dbname,
 @command = @sql,
 @retry_attempts = 5, --重试次数
 @retry_interval = 5  --重试间隔

--创建调度
declare @ftype int,@fstype int,@ffactor int
select @ftype=case @freqtype when 'day' then 4
     when 'week' then 8
     when 'month' then 16 end
 ,@fstype=case @fsinterval when 1 then 0 else 8 end
if @fsinterval<>1 set @time=0
set @ffactor=case @freqtype when 'day' then 0 else 1 end

EXEC msdb..sp_add_jobschedule @job_name=@jobname,
 @name = '时间安排',
 @freq_type=@ftype ,      --每天,8 每周,16 每月
 @freq_interval=1,     --重复执行次数
 @freq_subday_type=@fstype,   --是否重复执行
 @freq_subday_interval=@fsinterval,  --重复周期
 @freq_recurrence_factor=@ffactor,
 @active_start_time=@time     --下午17:00:00分执行

go

/*-----------------------------------------------------------------------
知识点: 备份/恢复语句的用法,作业的创建

-------------------------------------------------------------------------*/
/*--应用案例--备份方案:
完整备份(每个星期天一次)+差异备份(每天备份一次)+日志备份(每2小时备份一次)

调用上面的存储过程来实现
--*/

declare @sql varchar(8000)
--完整备份(每个星期天一次)
set @sql='exec p_backupdb @dbname=''要备份的数据库名'''
exec p_createjob @jobname='每周备份',@sql,@freqtype='week'

--差异备份(每天备份一次)
set @sql='exec p_backupdb @dbname=''要备份的数据库名'',@bktype='DF''
exec p_createjob @jobname='每天差异备份',@sql,@freqtype='day'

--日志备份(每2小时备份一次)
set @sql='exec p_backupdb @dbname=''要备份的数据库名'',@bktype='LOG''
exec p_createjob @jobname='每2小时日志备份',@sql,@freqtype='day',@fsinterval=2
--上面的还少了一个函数

/*--得到数据库的文件目录
 
 @dbname 指定要取得目录的数据库名
   如果指定的数据不存在,返回安装SQL时设置的默认数据目录
   如果指定NULL,则返回默认的SQL备份目录名
--邹建 2003.10--*/

/*--调用示例
 select 数据库文件目录=dbo.f_getdbpath('tempdb')
  ,[默认SQL SERVER数据目录]=dbo.f_getdbpath('')
  ,[默认SQL SERVER备份目录]=dbo.f_getdbpath(null)
--*/
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[f_getdbpath]') and xtype in (N'FN', N'IF', N'TF'))
drop function [dbo].[f_getdbpath]
GO

create function f_getdbpath(@dbname sysname)
returns nvarchar(260)
as
begin
 declare @re nvarchar(260)
 if @dbname is null or db_id(@dbname) is null
  select @re=rtrim(reverse(filename)) from master..sysdatabases where name='master'
 else
  select @re=rtrim(reverse(filename)) from master..sysdatabases where name=@dbname

 if @dbname is null
  set @re=reverse(substring(@re,charindex('/',@re)+5,260))+'BACKUP'
 else
  set @re=reverse(substring(@re,charindex('/',@re),260))
 return(@re)
end
go


--共计一个函数,三个存储过程

-------------------------------------------------------------------------------
--/*--得到数据库的文件目录:f_getdbpath
/*--调用示例
 select 数据库文件目录=dbo.f_getdbpath('tempdb')
  ,[默认SQL SERVER数据目录]=dbo.f_getdbpath('')
  ,[默认SQL SERVER备份目录]=dbo.f_getdbpath(null)
--*/
-------------------------------------------------------------------------------


-------------------------------------------------------------------------------
--/*--备份数据库:p_backupdb
--/*--调用示例
--备份当前数据库
exec p_backupdb @bkpath='c:/',@bkfname='db_/DATE/_db.bak'

--差异备份当前数据库
exec p_backupdb @bkpath='c:/',@bkfname='db_/DATE/_df.bak',@bktype='DF'

--备份当前数据库日志
exec p_backupdb @bkpath='c:/',@bkfname='db_/DATE/_log.bak',@bktype='LOG'

--*/
/*--参数说明
@dbname sysname='', --要备份的数据库名称,不指定则备份当前数据库
@bkpath nvarchar(260)='', --备份文件的存放目录,不指定则使用SQL默认的备份目录
@bkfname nvarchar(260)='', --备份文件名,文件名中可以用/DBNAME/代表数据库名,/DATE/代表日期,/TIME/代表时间
@bktype nvarchar(10)='DB', --备份类型:'DB'备份数据库,'DF' 差异备份,'LOG' 日志备份
@appendfile bit=1  --追加/覆盖备份文件
--*/
-------------------------------------------------------------------------------


-------------------------------------------------------------------------------
--/*--恢复数据库:p_RestoreDb
--/*--调用示例
--完整恢复数据库
exec p_RestoreDb @bkfile='c:/db_20031015_db.bak',@dbname='db'

--差异备份恢复
exec p_RestoreDb @bkfile='c:/db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:/db_20031015_df.bak',@dbname='db',@retype='DF'

--日志备份恢复
exec p_RestoreDb @bkfile='c:/db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:/db_20031015_log.bak',@dbname='db',@retype='LOG'

--*/

/*--参数说明
@bkfile nvarchar(1000), --定义要恢复的备份文件名
@dbname sysname='',     --定义恢复后的数据库名,默认为备份的文件名
@dbpath nvarchar(260)='', --恢复后的数据库存放目录,不指定则为SQL的默认数据目录
@retype nvarchar(10)='DB', --恢复类型:'DB'完事恢复数据库,'DBNOR' 为差异恢复,日志恢复进行完整恢复,'DF' 差异备份的恢复,'LOG' 日志恢复
@filenumber int=1,  --恢复的文件号
@overexist bit=1,        --是否覆盖已经存在的数据库,仅@retype为
@killuser bit=1   --是否关闭用户使用进程,仅@overexist=1时有效
--*/
-------------------------------------------------------------------------------


-------------------------------------------------------------------------------
--/*--创建作业:p_createjob

--/*--调用示例
--每月执行的作业
exec p_createjob @jobname='mm',@sql='select * from syscolumns',@freqtype='month'

--每周执行的作业
exec p_createjob @jobname='ww',@sql='select * from syscolumns',@freqtype='week'

--每日执行的作业
exec p_createjob @jobname='a',@sql='select * from syscolumns'

--每日执行的作业,每天隔4小时重复的作业
exec p_createjob @jobname='b',@sql='select * from syscolumns',@fsinterval=4
--*/

/*--参数说明:
@jobname varchar(100),  --作业名称
@sql varchar(8000),  --要执行的命令
@dbname sysname='',  --默认为当前的数据库名
@freqtype varchar(6)='day',  --时间周期,month 月,week 周,day 日
@fsinterval int=1,   --相对于每日的重复次数
@time int=170000   --开始执行时间,对于重复执行的作业,将从0点到23:59分
*/--
/*--应用案例2

生产数据核心库:PRODUCE

备份方案如下:
1.设置三个作业,分别对PRODUCE库进行每日备份,每周备份,每月备份
2.新建三个新库,分别命名为:每日备份,每周备份,每月备份
3.建立三个作业,分别把三个备份库还原到以上的三个新库。

目的:当用户在produce库中有任何的数据丢失时,均可以从上面的三个备份库中导入相应的TABLE数据。
--*/

declare @sql varchar(8000)

--1.建立每月备份和生成月备份数据库的作业,每月每1天下午16:40分进行:
set @sql='
declare @path nvarchar(260),@fname nvarchar(100)
set @fname=''PRODUCE_''+convert(varchar(10),getdate(),112)+''_m.bak''
set @path=dbo.f_getdbpath(null)+@fname

--备份
exec p_backupdb @dbname=''PRODUCE'',@bkfname=@fname

--根据备份生成每月新库
exec p_RestoreDb @bkfile=@path,@dbname=''PRODUCE_月''

--为周数据库恢复准备基础数据库
exec p_RestoreDb @bkfile=@path,@dbname=''PRODUCE_周'',@retype=''DBNOR''

--为日数据库恢复准备基础数据库
exec p_RestoreDb @bkfile=@path,@dbname=''PRODUCE_日'',@retype=''DBNOR''
'
exec p_createjob @jobname='每月备份',@sql,@freqtype='month',@time=164000

--2.建立每周差异备份和生成周备份数据库的作业,每周日下午17:00分进行:
set @sql='
declare @path nvarchar(260),@fname nvarchar(100)
set @fname=''PRODUCE_''+convert(varchar(10),getdate(),112)+''_w.bak''
set @path=dbo.f_getdbpath(null)+@fname

--差异备份
exec p_backupdb @dbname=''PRODUCE'',@bkfname=@fname,@bktype=''DF''

--差异恢复周数据库
exec p_backupdb @bkfile=@path,@dbname=''PRODUCE_周'',@retype=''DF''
'
exec p_createjob @jobname='每周差异备份',@sql,@freqtype='week',@time=170000

--3.建立每日日志备份和生成日备份数据库的作业,每周日下午17:15分进行:
set @sql='
declare @path nvarchar(260),@fname nvarchar(100)
set @fname=''PRODUCE_''+convert(varchar(10),getdate(),112)+''_l.bak''
set @path=dbo.f_getdbpath(null)+@fname

--日志备份
exec p_backupdb @dbname=''PRODUCE'',@bkfname=@fname,@bktype=''LOG''

--日志恢复日数据库
exec p_backupdb @bkfile=@path,@dbname=''PRODUCE_日'',@retype=''LOG''
'
exec p_createjob @jobname='每周差异备份',@sql,@freqtype='day',@time=171500

--先执行:
declare @dbname sysname
set @dbname='dbName'  --修改为要恢复的数据库名
declare @spid varchar(20)
 declare #spid cursor for
  select spid=cast(spid as varchar(20)) from master..sysprocesses where dbid=db_id(@dbname)
 open #spid
 fetch next from #spid into @spid
 while @@fetch_status=0
 begin 
  exec('kill '+@spid)
  fetch next from #spid into @spid
 end 
 close #spid
 deallocate #spid

--再执行你的恢复
restore log dbName from disk='fileName'
with stopat='date_time'
我也来转一个贴子:

/***************  http://www.csdn.net/develop/article/21/21304.shtm
标题     使用SQLSERVER的扩展存储过程实现远程备份与恢复    happy_david(原作)
 
关键字     扩展存储过程,远程,备份,恢复
 


标题很长,但内容简单。。这是小弟的第一篇习作,写的不好,望大家海涵。

   最近我在为公司的框架程序(以数据应用为导向的应用体系)做数据管理模块,这个模块的需求比较简单:备份、恢复和清理日志。我公司的软件基本上以C/S为基本架构,所以数据管理模块中两个主要的功能‘备份与恢复’都可能会在Client端操作,备份与恢复’的文件也都有可能存储在client端,因而这个数据管理模块就必须能够实现在远程备份与恢复数据库。

  文章的前提阐述完了,就该说说如何具体实现吧。其实都很简单,我想写个远程备份的测试实例
给大家看,就能够很清楚的描述吧!
  实例说明:
           环境:win2k+sqlserver 2K+查询分析器
           SQLSERVER服务实例名称:mainserver
           需要备份的数据库名称: msdb
           本地机器名称(Client端):david
           本地用户:zf 密码:123
           本地域名:domain
           本地提供备份需求的文件夹:e:/test

  第一步: 建立共享文件夹
     在程序代码中调用(或者CMD窗口)  net share test=e:/test
     或者用NetShareAdd这个API
     简要说明:
            net share     : 是WINDOWS内部的网络命令。
                            作用:建立本地的共享资源,显示当前计算机的共享资源信息。
                            语法:参见 net share /? 
  第二步: 建立共享信用关系
     master..xp_cmdshell 'net use  //david/test 123 /user:domain/zf'
     简要说明:
           1:xp_cmdshell :是SQLSERVER的扩展存储过程。
                            作用,以操作系统命令行解释器的方式执行给定的命令字符串,
                            并以文本行方式返回任何输出。
                            语法:参见SQLSERVER联机帮助
           2:net use      : 是WINDOWS内部的网络命令。
                            作用,将计算机与共享资源连接或断开,或者显示关于计算机
                            连接的信息。该命令还控制持久网络连接。
                            语法:参见 net use /?

  第三步:备份数据库
     backup database msdb to disk='//david/test/msdb.bak'
     这个不需要说明吧,语法参见SQLSERVER联机帮助

  第四步: 删除共享文件夹
     在程序代码中调用(或者CMD窗口)  net share test /delete
     或者用NetShareDel这个API
  结果:
      已处理 1376 页,这些页属于数据库 'msdb' 的文件 'MSDBData'(位于文件 1 上)。
      已处理 1 页,这些页属于数据库 'msdb' 的文件 'MSDBLog'(位于文件 1 上)。
      BACKUP DATABASE 操作成功地处理了 1377 页,花费了 3.653 秒(3.086 MB/秒)。

  这样mainserver服务器上的msdb就备份到了david机器的E:/test/msdb.bak文件了,使用起来很简单吧?恢复数据库操作也是一样,只要将第三个步骤的语句改为'restore database msdb from disk='//david/test/msdb.bak'就可以啦。。你看完了也可以试试呀?!(最简单的测试工具查询分析器+CMD窗口)

备注:xp_cmdshell 这个扩展存储过程只能SA级别的用户调用,而且是SQLSERVER的安全隐患之
      一,许多DBA都喜欢将其删除或者禁用,所以开发人员使用时要倍加小心哦。
     文章中的例子只是简要的说明了应如何利用扩展存储过程实现远程备份与恢复,没有涉及安全以及其他方面的考虑,希望读者在代码中自行完善。

 
/**************************************************
SQL异地备份失败,归根结底是权限问题!!!
如:
   SQLServer备到FileServer上
   那你的SQLServer的启动用户必须在FileServer上有足够的权限!
--------------------^^^---------------------------------
1、SQLServer上新建一SQLUser用户权限大一点。
2、FileServer上建同一用户对某一文件夹有足够权限。
3、两机的SQLUser密码相同(方便一点)
4、将SQLServer改为SQLUser启动
   (管理工具-->服务-->mssql项-->属性-->指定用户及密码)
5、//192.168.*.*/文件夹/ShareBak.Bak就可以了
-----------------------------------------------------------
简单一点就是:
如果你两台都是windows2ks
你的机器也用同样的Administrator密码,且sql服务器用administrator启动
那你写设备时就可以写://ip/.......

如果对方是98那你要完全共享一下!
你写设备时就可以写://ip/.......

 

 

对于如下错误:因为数据库正在使用,所以未能获得对数据库的排它访问权。
最好如下处理:

use  master     -- 请注意建在master数据库里
go
create  proc  killspid  (@dbname  varchar(20)) 
as 
begin 
declare  @sql  nvarchar(500),@temp varchar(1000)
declare  @spid  int 
set  @sql='declare  getspid  cursor  for   
select  spid  from  sysprocesses  where  dbid=db_id('''+@dbname+''')' 
exec  (@sql) 
open  getspid 
fetch  next  from  getspid  into  @spid 
while  @@fetch_status =0
begin 
  set @temp='kill  '+rtrim(@spid)
  exec(@temp)
fetch  next  from  getspid  into  @spid 
end 
close  getspid 
deallocate  getspid 
end 

--用法 
use  master                    -- 请注意在master数据库下运行
go
exec  killspid  '数据库名'

Oracle9i数据库备份和恢复方案

  • 2010年03月04日 21:59
  • 12KB
  • 下载

中小型数据库 RMAN CATALOG 备份恢复方案(三)

在前两篇文章中描述了中小型数据库使用RMAN catalog设计备份与恢复方案,并给出了所有相关的脚本来从某种车程度上模拟Oracle Data Guard以减少硬件故障带来Prod服务器上数据库损失...
  • robinson_0612
  • robinson_0612
  • 2013-08-13 10:13:11
  • 5238

数据库备份方案

数据库备份,是在数据丢失的情况下,能及时恢复重要数据,防止数据丢失的一种重要手段。一个合理的数据库备份方案,应该能够在数据丢失时,有效地恢复重要数据,同时需要考虑技术实现难度和有效地利用资源。1.1....
  • feixiangVB
  • feixiangVB
  • 2006-12-20 13:30:00
  • 11401

Oracle数据库备份与恢复方案

任何数据库在长期使用过程中,都会存在安全隐患。对于数据库管理员来说不能仅寄希望于计算机操作系统的安全运行,而是要建立一整套的数据库备份与恢复机制。当任何人为的或是自然的灾难一旦出现,而导致数据库崩溃、...
  • benfenge
  • benfenge
  • 2014-10-30 15:22:13
  • 2948

中小型数据库 RMAN CATALOG 备份恢复方案(一)

对于数据库的稳定性,高可用,跨平台以及海量数据库的处理,Oracle 数据库通常是大型数据库和大企业的首选。尽管如此,仍然不乏很多中小企业想要品尝一下Oracle腥味,因此在Oracle环境中也有不少...
  • robinson_0612
  • robinson_0612
  • 2013-08-07 12:06:14
  • 7638

MongoDB——数据备份与还原

数据备份: 打开命令提示符,进入安装好的MongoDB的bin目录下: 位置如下: 输入命令:mongodump -h 127.0.0.1:27017 -d runoob -o D:\mong...
  • Shiyaru1314
  • Shiyaru1314
  • 2016-09-07 15:03:23
  • 1377

某公司SQL Server 数据库备份方案

概述 为了保证XXX公司物业系统数据库的安全,稳定性,数据库管理员应定期备份数据库,采用良好的备份策略,一方面维持数据的安全性;另一方面要保证数据库稳定,顺畅,高效的运行。尽最大的努力减少由于数据丢...
  • ren6370
  • ren6370
  • 2017-06-17 15:34:28
  • 936

数据库备份和恢复

  • 2017年12月19日 21:17
  • 2.21MB
  • 下载

数据库备份/恢复方案

  • zgqtxwd
  • zgqtxwd
  • 2008-05-01 02:36:00
  • 166

zabbix数据库备份问题

今早来公司发现zabbix监控没有数据,然后登陆server端,发现如下: [root@1-199-HP~]# df -h Filesystem            Size  Used Ava...
  • wudinghua082
  • wudinghua082
  • 2014-03-27 21:48:06
  • 737
收藏助手
不良信息举报
您举报文章:交流--数据库备份/恢复方案
举报原因:
原因补充:

(最多只允许输入30个字)