VCL类学习之(四) TClassFinder

1. { TClassFinder }
3.   TGetClass = procedure (AClass: TPersistentClass) of object;
5.   TClassFinder = class
6.   private
7.     FGroups: TList;
8.   public
9.     constructor Create(AClass: TPersistentClass = nil;
10.       AIncludeActiveGroups: Boolean = False);
11.     destructor Destroy; override;
12.     function GetClass(const AClassName: string): TPersistentClass;
13.     procedure GetClasses(Proc: TGetClass);
14.   end;
17. { TClassFinder }
19. constructor TClassFinder.Create(AClass: TPersistentClass;
20.   AIncludeActiveGroups: Boolean);
21. var
22.   I: Integer;
23.   Group: TRegGroup;
24. begin
25.   inherited Create;
26.   FGroups := TList.Create;
27.   RegGroups.Lock;
28.   try
29.     if AClass = nil then AClass := RegGroups.ActiveClass;
30.     for I := 0 to RegGroups.FGroups.Count - 1 do
31.     begin
32.       Group := RegGroups.FGroups[I];
33.       if Group.InGroup(AClass) then
34.         FGroups.Add(Group);
35.     end;
36.     if AIncludeActiveGroups then
37.       for I := 0 to RegGroups.FGroups.Count - 1 do
38.       begin
39.         Group := RegGroups.FGroups[I];
40.         if Group.Active then
41.           FGroups.Add(Group);
42.       end;
43.   finally
44.     RegGroups.Unlock;
45.   end;
46. end;
48. destructor TClassFinder.Destroy;
49. begin
50.   FGroups.Free;
51.   inherited;
52. end;
54. function TClassFinder.GetClass(const AClassName: string): TPersistentClass;
55. var
56.   I: Integer;
57. begin
58.   Result := nil;
59.   RegGroups.Lock;
60.   try
61.     for I := 0 to FGroups.Count - 1 do
62.       with TRegGroup(FGroups[I]) do
63.       begin
64.         Result := GetClass(AClassName);
65.         if Result <> nil then Exit;
66.       end;
67.   finally
68.     RegGroups.Unlock;
69.   end;
70. end;
72. procedure TClassFinder.GetClasses(Proc: TGetClass);
73. var
74.   I: Integer;
75. begin
76.   RegGroups.Lock;
77.   try
78.     for I := 0 to FGroups.Count - 1 do
79.       TRegGroup(FGroups[I]).GetClasses(Proc);
80.   finally
81.     RegGroups.Unlock;
82.   end;
83. end;