汇编INT中断和I/O指令【获取主板时钟】

1. 中断向量表

        中断是一种使CPU挂起正在执行的程序去处理特殊的事件的操作，处理特殊事件的服务程序称为中断程序，即处理中断的程序。

        为了便于处理，每一种中断有 一个编号，称为中断号，中断号的取值范围是0到255，如属于内部中断的除法出错的中断号是0，属于外部中断的键盘中断的中断号是9。

        中断向量是指中断处理程序的入口地址，相当于执行中断程序的指针。为了使系统在响应中断时，CPU能够快速地转入对应的中断程序，用一张表来保持中断向量，这张表称为中断向量表，中断向量表的每一项也依次编号为0到255。

2. 内部中断

        内部中断是CPU在执行某些指令时产生的中断，包括：

• 除法出错中断
• 单步中断
• 断点中断
• 溢出中断
• 中断指令INT n引起的中断。n的取值是0到255，如INT 10H表示调用BIOS显示I/O程序，INT 21H表示调用DOS系统功能等。

3. 外部中断

        外部中断是发生在CPU内部某个事件引起的中断，IA-32 CPU有两条外部中断线，INTR和NMI，INTR可屏蔽，NMI不可屏蔽。

        鼠标键盘等外设的中断请求通过8259A中断控制器（或者IO APIC和LOCAL APIC）传给CPU，8259A初始化时规定了16个中断请求即IRO至IR15，操作系统在初始化时通过建立中断向量表，并设置8259A或者APIC的相关寄存器实现中断处理程序和中断号的映射，当发送外部中断时系统通过调用相应的中断处理程序实现外设IO操作。

4. I/O

        虽然可以通过BIOS的I/O程序实现键盘、硬盘等外设的访问，但是这种方式访问I/O设备的一个缺点是依赖BIOS。曾经流行的DOS操作系统在BIOS的基础上实现对外设的访问，感兴趣的朋友可以看看freedos系统的源码(https://github.com/FDOS/kernel）。

        计算机的I/O设备（输入输出设备，鼠标键盘等）是通过一个硬件接口或控制器与CPU相连，我们可以在汇编程序中通过一组寄存器或存储单元实现对I/O设备的访问，通过I/O指令、寄存器和端口地址实现对外部设备的访问。

         I/O输入指令从一个端口输入字节、字或者双字到累加寄存器，端口地址可以直接方式表示也可以间接方式表示，输入指令的格式为：

IN 累加器，端口地址

        端口地址采用直接方式表示时长度是8比特，地址的取值范围是0到FFH，采用间接方式表示时，端口地址的长度是16比特，通过DX寄存器寻址。

        输出指令的格式为：

OUT 端口地址，累加器

       通过上述的指令可以看出，通过I/O端口地址实现对输入输出设备的访问，I/O端口地址是端口的编号，通过端口地址可以访问端口或者存取接口中的寄存器。 

5. 设置光标位置

        在实地址模式下，使用10H中断设置光标的位置，设置方法是AH寄存器的值为2，DL和DH设置光标的行和列。

6. 示例

        这里编写一个实地址模式下获取主板CMOS实时时钟汇编程序，实现系统上电启动时在屏幕指定位置显示的时间信息。获取RTC/CMOS RAM的时间信息，需要用到I/O指令；指定位置输出信息，需要用到INT中断指令。

      RTC/CMOS时钟的I/O端口地址如下：

•  秒：      00H
• 报警秒：01H
• 分：       02H
• 报警分：03H
• 时：       04H
• 报警时：05H
• 星期：   06H
• 日：       07H
• 月：       08H
• 年：       09H

         获取主板CMOS实时时钟并显示的汇编代码如下：

; nasm -fbin xx.asm -o xx.bin

segment text
	org 7c00h ; dos env should be 100h
start:
	mov ax, cs
	mov ds, ax
	mov es, ax	
	mov ah, 3
	int 10h
	mov si, msg
	mov ax, mlen
	call ostr
.refresh:
	call gettm
	call fmttm	
	mov ah, 3
	int 10h
	mov dl, mlen
	mov si, data
	mov ax, dlen
	call ostr
	mov ax, 40h
.wait:
	mov cx, 0xffff
	loop $
	dec ax
	jnz .wait
.end:
	jmp .refresh
	
gettm:
	mov al, 0
	out 70h, al
	in al, 71h	
	mov [buf+5], al

	mov al, 2
	out 70h, al
	in al, 71h	
	mov [buf+4], al

	mov al, 4
	out 70h, al
	in al, 71h	
	mov [buf+3], al

	mov al, 7
	out 70h, al
	in al, 71h	
	mov [buf+2], al

	mov al, 8
	out 70h, al
	in al, 71h	
	mov [buf+1], al

	mov al, 9
	out 70h, al
	in al, 71h
	mov [buf], al
	ret

; format time str 
fmttm:
	mov di, data
	mov si, buf
	mov cx, 6
.floop:
	lodsb
	mov ah, al
	sar al, 4
	add al, 30h
	and ah, 0fh
	add ah, 30h
	stosw	
	inc di
	loop .floop	
	ret

; output a string
; si: str pointer
; ax: str length
; dx: location
ostr:
	push ax	
	mov bp, si
	push cs
	pop es
	mov al, 1
	mov ah, 13h
	mov bl, 00000010b
	mov bh, 0
	pop cx
	int 10h
	ret
	
buf resb 6
data db "00/00/00 00:00:00"
dlen equ $-data
msg db "Current date and time: "
mlen equ $-msg

times 510-($-$$) db 0h
	db 0x55,0xaa

       将编译后机器码写入手动创建的bochs flat虚拟硬盘并运行，如下图所示：

      使用freedos系统编译运行，如下图所示：

        也可以使用物理机器运行，运行效果和bochs一样。运行方法是将编译后的bin文件写入u盘，并从u盘启动物理机。