用VB编写OPC客户端访问WINCC
OPC是一个工业标准,它是由一些世界上著名的自动化系统和硬件、软件公司和Microsoft(微软)紧密合作而建立的。〔O代表OLE(对象链接和嵌入),P (process过程),C (control控制)。OLE已从面向对象重新定义为基于对象并更名为Active X〕。
WinCC是西门子公司在自动化领域采用最先进的技术与微软公司在共同开发的居于世界领先地位的工控软件。WinCC即WINDOWS CONTROL CENTER(视窗控制中心)。WinCC是一个功能强大的全面开放的监控系统,既可以用来完成小规模的简单的过程监控应用,也可以用来完成复杂的应用。在任何情况下WinCC都可以生成漂亮而便捷的人机对话接口,使操作员能够清晰地管理和优化生产过程。它集成的OPC(OLE for process control)服务器使得过程数据可由其它应用程序(OPC客户机)访问。
WinCC在安装时提供了OPC的客户端控件: Siemens OPC DAAutomation 2.0( SOPCDAAuto.dll),这个控件就是我们在VB中要用到的控件,我们也可以使用通用的OPC客户端控件: OPC Automation 2.0.
在WINCC的帮助中,有Siemens OPC DAAutomation 2.0使用的简略帮助,但说得不很详细,我在使用中碰到不少问题,现一并写出来,与大家共享。
一、OPC的连接
先在“引用”将近 Siemens OPC DAAutomation 2.0加入,然后开始定义全局变量。在本程序中,我使用了两个OPC组进行OPC访问,所以定义了全局变量。我们要首先定义OPC服务类型与计算机结点名。定义OPC组与OPC标签组。并定义OPC的标签数组与值数,注意,值数组一定要设为Variant。
'OPC处理:只对WINCC
Const ServerName = "OPCServer.WinCC" ‘OPC的类型
Const NodeName = "GUK" ‘结点名,即计算机名
‘Dim NodeName As String
Dim WithEvents MyOPCServer As OPCServer ‘OPC服务
Dim MyOPCGroupColl As OPCGroups ‘
Dim WithEvents MyOPCGroupOut As OPCGroup ‘OPC组,本程序用两个组进行OPC连接
Dim WithEvents MyOPCGroupIn As OPCGroup
Dim MyOPCItemCollIn As OPCItems ‘OPC标签组
Dim MyOPCItemCollOut As OPCItems
Dim ServerHandlesIn() As Long ‘句柄
Dim ServerHandlesOut() As Long
Dim ErrorsIn() As Long ‘错误句柄
Dim ErrorsOut() As Long
Dim WatchDataReadItem(100) As String '记录OPC的标签
Dim WatchDataReadValue(100) As Variant '存放OPC的值
Dim WatchDataWriteItem(100) As String '记录OPC的标签
Dim WatchDataWriteValue(100) As Variant '存放OPC的值
在定义所有变量后,我们就要进行OPC连接了,要进行OPC连接之前,先要配置要访问的OPC标签名,我们WatchDataReadItem、WatchDataWriteItem中加入相应的标签名,注意:这两个数组必须由1开始,不能由0开始。
配置好标签后就要进行OPC连接了。如下面子程序:
1、 ClientHandles1先配置名柄索引,这将在读取OPC标签的值时可要用到
2、 生成OPC对象,
3、 进行OPC标签连接
至此:OPC连接就成功了,我们可以对OPC进行读与写的操作了。
'---------------------------------------------------------------------
' Sub StartClient()
' 目的:连接至OPC_server,创建组和添加条目
'---------------------------------------------------------------------
Private Sub StartClient()
Dim ItemNum As Integer
Dim TarnscationID As Long
Dim CanceID As Long
Dim ClientHandles1(100) As Long
Dim ii As Integer
On Error GoTo HANDLEeRROR
For ii = 0 To 100
ClientHandles1(ii) = ii 先配置名柄索引,这将在读取OPC标签的值时可要用到
Next ii
TarnscationID = 1
‘ NodeName = xProfile.GetValue("SYSTEM", "NodeName")
‘生成OPC对象,
Set MyOPCServer = New OPCServer
MyOPCServer.Connect ServerName, NodeName
Set MyOPCGroupColl = MyOPCServer.OPCGroups
MyOPCGroupColl.DefaultGroupIsActive = True
Set MyOPCGroupIn = MyOPCGroupColl.Add("MYGROUPIN")
Set MyOPCGroupOut = MyOPCGroupColl.Add("MYGROUPOUT")
Set MyOPCItemCollIn = MyOPCGroupIn.OPCItems
Set MyOPCItemCollOut = MyOPCGroupOut.OPCItems
‘进行OPC标签连接
If WriteItemIdex > 0 Then
MyOPCItemCollOut.AddItems WriteItemIdex, WatchDataWriteItem, ClientHandles1, ServerHandlesOut, ErrorsOut '初始化OCP连接
MyOPCGroupOut.IsSubscribed = True
End If
If ReadItemIdex > 0 Then
MyOPCItemCollIn.AddItems ReadItemIdex, WatchDataReadItem, ClientHandles1, ServerHandlesIn, ErrorsIn '初始化OCP连接
MyOPCGroupIn.IsSubscribed = True
End If
Exit Sub
HANDLEeRROR:
needOPCRestart = True
xLog1.log "OPCl连接发生错误"
End Sub
二、OPC的标签读写
对OPC标签的读可以通过MyOPCGroupIn组与MyOPCGroupOut的DataChange事件来读取。该事件有多个参数:其中NumItems是指标签改变值的个数,ClientHandles是改变值的标签索引,ItemValues为改变值的数据,具体的意思是ClientHandles(1)的值是其对应的标签数组的索引,其所指的OPC标签的值在ItemValues(1)中。一般来说,刚连接上时,该事件会把全部所要求访问的OPC标签值全部读取过来(顺序不一,要通过ClientHandles索引),此后只有数据发生变化时才会触发该事件。也只会传输发生了变化的数据,没有变化的数据不会出现在本事件的ItemValues中。
Private Sub MyOPCGroupOut_DataChange(ByVal TransactionID As Long, ByVal NumItems As Long, ClientHandles() As Long, ItemValues() As Variant, Qualities() As Long, TimeStamps() As Date)
'产生要通知下一级的数据变化,根椐不再的控件有不同的处理
For ii = 1 To NumItems
WatchDataWriteValue(ClientHandles(ii) - 1) = ItemValues(ii) '对改变的值读入本数组
Next ii
End Sub
对OPC的写可以有同步与异步之分,对于大量的数据传输,异步是更佳的选择,但对少量的数据传输,同步表现得更好。
要进行数据传输,先要将值数据进行赋值,注意:值数据要由0开始,也就是说,值数组与标签数据不是一、一对应,值要比标签前一位,这一点,在WINCC说明中没有,但在我的实际的使用中一直要这样,不然数据就产生错位,看下面程序。
这是一个拔号完毕后返回的数据进行OPC传递的程序。包含解包过程,
Private Sub showSuccess(msg As String)
Dim location As String
Dim nowTime As String
Dim logStr As String
Dim Value() As String
Dim ii, temp As Integer
Dim isPack As Boolean
Dim sHead, sDelimited, sTail As String
location = xProfile.GetValue(WatchPoint(nowRunID), "LOCATION")
nowTime = Now
logStr = "拔" & location & "取数成功" & msg
xLog1.log logStr
logStr = " " & msg
xLog2.log logStr '记录数据
'数据上传
'如果有包结构,则显示包结构,
isPack = xProfile.GetValue(WatchPoint(nowRunID), "ISRECHEAD")
If WatchPointRBegin(nowRunID) < 0 Then Exit Sub
If isPack Then
sHead = xProfile.GetValue(WatchPoint(nowRunID), "RECHEAD")
sDelimited = xProfile.GetValue(WatchPoint(nowRunID), "RECDELIMITER")
sTail = xProfile.GetValue(WatchPoint(nowRunID), "RECEND")
Value = Split(msg, sDelimited)
For ii = 0 To UBound(Value) - 1
temp = WatchPointRBegin(nowRunID) + ii
If temp > WatchPointREnd(nowRunID) Then Exit For
WatchDataReadValue(temp - 1) = Value(ii + 1) 'VALUE要从0开始,比ITEM少1,所以减一。 有包头,占去一位,向后延一
Next ii
Else
WatchDataReadValue(WatchPointREnd(nowRunID) - 1) = msg
End If
MyOPCGroupIn.SyncWrite ReadItemIdex, ServerHandlesIn, WatchDataReadValue, ErrorsIn '数据上传
'记录上次成功执行的时间
xProfile.SetValue WatchPoint(nowRunID), "LASTTIME", nowTime
End Sub
三、OPC连接断开。
OPC客户端连接后要占用服务器资源,所以如果不需要使用OPC时,必须进行OPC连接断开。
断开的程序相当简单,释放资源即可。如下,
Sub StopClient()
On Error Resume Next
'----------- 释放组和服务器对象
MyOPCGroupColl.RemoveAll
'----------- 与服务器断开连接并且清除
MyOPCServer.Disconnect
Set MyOPCItemCollIn = Nothing
Set MyOPCItemCollOut = Nothing
Set MyOPCGroupIn = Nothing
Set MyOPCGroupOut = Nothing
Set MyOPCGroupColl = Nothing
Set MyOPCServer = Nothing
End Sub
但在实际的使用中发现,频繁的连接与断开,将使服务器的资源被大量的消耗,最终让服务器出错。所以尽量减少无谓的OPC连接与断开。
结语:
OPC的使用是作为一个DCOM在使用,所以OPC客户端可以网络上任一计算机运行,但你必须配置DCOM的访问权限,如果你不想费神,把服务器与客户端都用相同的用户名与密码登录就成了。如果想配置DCOM,请参看DCOM的配置。
参考资料:
《WinCC在线帮助》
作者简介:
顾恺,高级程序员,湖南大学毕业,曾从事过LINUX的内核研究,从事过企业信息化平台的开发,当前从事SCADA的开发,主要将各种不同类型的远程设备通过同一手段进行数据采集,并集成到企业信息化平台中去。喜欢将工作中的一些积累形成文字。
come from: