在Oralce9i内向给定的表对象内插入实际的行

     在开发数据库程序时,经常需要象数据库表对象内录入些测试数据,如果针对每个表对象都建立一个录入的存储过程,显得有些麻烦。这里给出一个示例pl/sql代码,调用者给出要插入测试数据的表对象名称,和待插入的行数后,过程即可产生随机数据,录入到表对象内。

/*-------------向给定的表对象内插入实际的行。---------------------------*/
  procedure Insert_Rows(p_tablename varchar, p_numrows number)
  as
    --定义dba_tab_columns视图类型的表对象,用于存储给定表的字段的定义信息
    type table_define is table of dba_tab_columns%rowtype index by binary_integer;
    td table_define;
    i binary_integer;

    --定义动态sql查询的游标
    l_cursor number:= dbms_sql.open_cursor;
    l_ignone number;
    --动态sql语句字符变量
    sqlstr varchar2(1000);
  begin
    --获得表的所有字段的定义信息
    i:=0;
    for rec in(select * from dba_tab_columns where table_name=upper(p_tablename))
    loop
      i:= i+1;
      td(i):= rec;
      dbms_output.put_line(td(i).table_name);
    end loop;
    --组织insert sql语句的字段字符串
    sqlstr:='insert into '||td(1).table_name||'(';
    for var in 1..i loop
      sqlstr:=sqlstr||td(var).column_name;
      if(var<>i) then
        sqlstr:=sqlstr||',';
      end if;
    end loop;
    --组织insert sql语句的参数字符串
    sqlstr:=sqlstr||')'||'values(';
    for var in 1..i loop
     sqlstr:=sqlstr||':'||td(var).column_name;
     if(var<>i) then
       sqlstr:=sqlstr||',';
     end if;
    end loop;
    sqlstr:=sqlstr||')';

    dbms_output.put_line(sqlstr);

    --为参数变量赋值
    dbms_sql.parse(l_cursor,sqlstr,dbms_sql.native);
   
    for var_rows in 1..p_numrows loop
      --填充插入参数的值
      for var in 1..i loop
        if td(var).data_type='VARCHAR2' then
          dbms_sql.bind_variable(l_cursor,':'||td(var).column_name,dbms_random.string('A',td(var).data_length));
        elsif td(var).data_type='NUMBER' then
          dbms_sql.bind_variable(l_cursor,':'||td(var).column_name,
          round(dbms_random.value*power(10,td(var).data_precision-td(var).data_scale),td(var).data_scale));
        else
          dbms_sql.bind_variable(l_cursor,':'||td(var).column_name,'UNKNOW_TYPE');
        end if;
      end loop;
      --执行动态的SQL语句
      l_ignone:=dbms_sql.execute(l_cursor);
    end loop; 
    commit;
    dbms_sql.close_cursor(l_cursor);
   
  end Insert_Rows;

微信扫码订阅
UP更新不错过~
关注
  • 0
    点赞
  • 0
    收藏
  • 打赏
    打赏
  • 0
    评论

“相关推荐”对你有帮助么?

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
©️2022 CSDN 皮肤主题:大白 设计师:CSDN官方博客 返回首页
评论

打赏作者

fwtandpj

你的鼓励将是我创作的最大动力

¥2 ¥4 ¥6 ¥10 ¥20
输入1-500的整数
余额支付 (余额:-- )
扫码支付
扫码支付:¥2
获取中
扫码支付

您的余额不足,请更换扫码支付或充值

打赏作者

实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、C币套餐、付费专栏及课程。

余额充值