delphi 操作xml示例

最新推荐文章于 2023-08-17 13:22:19 发布
最新推荐文章于 2023-08-17 13:22:19 发布
阅读量1.5k 收藏
点赞数
文章标签： xml delphi button webbrowser object email 
自：http://www.delphibbs.com/keylife/iblog_show.asp?xid=20713

================================================================

2005-9-23 21:05:34    xml基础操作实例，因为刚开始学，如果有不对的地方，请批评指正，代码如下：



unit XMLOptionUnit;

//==============================================================================

//本实例演示

//1，XML 创建，打开，关闭操作

//2，XML 填加，添加到指定位置，删除，修改（替换），查找等操作

//作者：cactus123456@hotmail.com

//日期：2005.9.23

//版本：1.0

//==============================================================================

interface



uses

  SysUtils,ActiveX,MSXML2_TLB;



type

  RecUser=Record

    U_Id       :widestring;

    U_Name     :widestring;

    U_Sex      :widestring;

    U_Birth    :widestring;

    U_Tel      :widestring;

    U_Addr     :widestring;

    U_PostCode :widestring;

    U_Email    :widestring;

  end;



type

  TXMLOption=class

  private

    FActive  :boolean;

    FFilename: string;

    FXMLDoc  :IXMLDOMDocument;

    //填加一个子节点

    procedure AddSimpleElement(Parent: IXMLDOMElement; Field,Value: string);

  public

    procedure CreateBlank(Filename: string);

    procedure OpenXml(Filename: string);

    procedure CloseXml;

    procedure AppendUser(muser:RecUser);

    procedure InsertUser(uid:string;muser:RecUser);

    procedure RemoveUser(uid:string);

    procedure ReplaceUser(uid:string;newuser:RecUser);

    function  FindUser(userid:widestring):boolean;

  end;



implementation



const

  XMLTag          = 'xml';

  XMLPrologAttrs  = 'version="1.0" encoding="UTF-8"';

  XMLComment      = '简单XML文档操作用户实例'#13 +

                    '用户结构为序号，姓名，性别，出生年月日，电话，住址，邮编，电邮'#13 +

                    '作者 cactus123456@hotmail.com, 2005.9.21';

  UserWatcherTag = 'user-watcher';

  XMLComment2    = '创建文档时间：';

  UsersTag       = 'users';

  U_Id           = 'id';

  U_Name         = 'name';

  U_Sex          = 'sex';

  U_Birth        = 'birth';

  U_Tel          = 'tel';

  U_Addr         = 'addr';

  U_PostCode     = 'postcode';

  U_Email        = 'email';



//创建一个空XML，如果这个Filename文件已经存在，则覆盖

procedure TXMLOption.CreateBlank(Filename: string);

begin

  FActive:=false;

  FFilename:='';

  try

    FXMLDoc := CoDOMDocument.Create;

    FXMLDoc.AppendChild(FXMLDoc.CreateProcessingInstruction(XMLTag, XMLPrologAttrs));

    FXMLDoc.AppendChild(FXMLDoc.CreateComment(XMLComment));

    FXMLDoc.AppendChild(FXMLDoc.CreateElement(UserWatcherTag));

    FXMLDoc.AppendChild(FXMLDoc.CreateComment(XMLComment2+datetimetostr(now)));

    FXMLDoc.save(Filename);

    FFilename:=Filename;

    FActive:=true;

  except

    FXMLDoc:=nil;

  end;

end;

//打开一个存在的Filename XML文档

procedure TXMLOption.OpenXml(Filename: string);

begin

  if not Assigned(FXMLDoc) then

  begin

    FXMLDoc := CoDOMDocument.Create;

    if FXMLDoc.Load(Filename) then FActive:=true

    else FActive:=false;

    if FActive then FFilename:=Filename

    else FFilename:='';

  end;

end;

//关闭一个打开的XML文档

procedure TXMLOption.CloseXml;

begin

  if Assigned(FXMLDoc) then FXMLDoc:=nil;

  FFilename:='';

  FActive:=false;

end;

procedure TXMLOption.AddSimpleElement(Parent: IXMLDOMElement; Field,Value: string);

var

  Internal: IXMLDOMElement;

begin

  Internal:=IXMLDOMElement(Parent.AppendChild(FXMLDoc.CreateElement(Field)));

  Internal.AppendChild(FXMLDoc.CreateTextNode(Value));

end;

//填加一个节点到后面

procedure TXMLOption.AppendUser(muser:RecUser);

var

  xuser:IXMLDOMElement;

  xroot:IXMLDOMElement;

begin

  if FActive then

  begin

    xroot:=FXMLDoc.documentElement;

    xuser :=IXMLDOMElement(xroot.AppendChild(FXMLDoc.CreateElement(UsersTag)));

    AddSimpleElement(xuser,U_Id,muser.U_Id);

    AddSimpleElement(xuser,U_Name,muser.U_Name);

    AddSimpleElement(xuser,U_Sex,muser.U_Sex);

    AddSimpleElement(xuser,U_Birth,muser.U_Birth);

    AddSimpleElement(xuser,U_Tel,muser.U_Tel);

    AddSimpleElement(xuser,U_Addr,muser.U_Addr);

    AddSimpleElement(xuser,U_PostCode,muser.U_PostCode);

    AddSimpleElement(xuser,U_Email,muser.U_Email);

    FXMLDoc.save(FFilename);

  end;

end;

procedure TXMLOption.InsertUser(uid:string;muser:RecUser);

var

  xfind:IXMLDOMNode;

  xuser:IXMLDOMElement;

  xroot:IXMLDOMElement;

  xpath:string;

begin

  if not FActive then exit;

  xpath:=UsersTag+'['+U_Id+'="'+uid+'"]';

  xfind:=FXMLDoc.documentElement.selectSingleNode(xpath);

  //如果没有找到， xfind=nil 则在文件的末尾插入

  //如果找到，xfind<>nil 则在找到的纪录前面插入

  xroot:=FXMLDoc.documentElement;

  xuser :=IXMLDOMElement(xroot.insertBefore(FXMLDoc.CreateElement(UsersTag),xfind));

  AddSimpleElement(xuser,U_Id,muser.U_Id);

  AddSimpleElement(xuser,U_Name,muser.U_Name);

  AddSimpleElement(xuser,U_Sex,muser.U_Sex);

  AddSimpleElement(xuser,U_Birth,muser.U_Birth);

  AddSimpleElement(xuser,U_Tel,muser.U_Tel);

  AddSimpleElement(xuser,U_Addr,muser.U_Addr);

  AddSimpleElement(xuser,U_PostCode,muser.U_PostCode);

  AddSimpleElement(xuser,U_Email,muser.U_Email);

  FXMLDoc.save(FFilename);

end;

procedure TXMLOption.RemoveUser(uid:string);

var

  xfind:IXMLDOMNode;

  xroot:IXMLDOMElement;

  xpath:string;

begin

  if not FActive then exit;

  xpath:=UsersTag+'['+U_Id+'="'+uid+'"]';

  xfind:=FXMLDoc.documentElement.selectSingleNode(xpath);

  if xfind<>nil then

  begin

    xroot:=FXMLDoc.documentElement;

    xroot.removeChild(xfind);

    FXMLDoc.save(FFilename);

  end;

end;

procedure TXMLOption.ReplaceUser(uid:string;newuser:RecUser);

var

  xfind,newnode:IXMLDOMNode;

  xroot:IXMLDOMElement;

  xpath:string;

begin

  if not FActive then exit;

  xpath:=UsersTag+'['+U_Id+'="'+uid+'"]';

  xfind:=FXMLDoc.documentElement.selectSingleNode(xpath);

  //如果没有找到，则不做替换

  if xfind<>nil then

  begin

    newnode:=xfind.cloneNode(true);

    newnode.selectSingleNode(U_Id).text:=newuser.U_Id;

    newnode.selectSingleNode(U_Name).text:=newuser.U_Name;

    newnode.selectSingleNode(U_Sex).text:=newuser.U_Sex;

    newnode.selectSingleNode(U_Birth).text:=newuser.U_Birth;

    newnode.selectSingleNode(U_Tel).text:=newuser.U_Tel;

    newnode.selectSingleNode(U_Addr).text:=newuser.U_Addr;

    newnode.selectSingleNode(U_PostCode).text:=newuser.U_PostCode;

    newnode.selectSingleNode(U_Email).text:=newuser.U_Email;

    xroot:=FXMLDoc.documentElement;

    xroot.replaceChild(newnode,xfind);

    FXMLDoc.save(FFilename);

  end;

end;

function  TXMLOption.FindUser(userid:widestring):boolean;

var

  xuser:IXMLDOMNode;

  xpath:string;

begin

  result:=false;

  if not FActive then exit;

  //关于xpath语法说明，参见www.w3.org/TR/xpath

  xpath:=UsersTag+'['+U_Id+'="'+userid+'"]';

  xuser:=FXMLDoc.documentElement.selectSingleNode(xpath);

  if xuser<>nil then result:=true;

end;



initialization

  { Initialise COM }

  CoInitialize(nil);

finalization

  { Tidy up }

  CoUninitialize();



end.



调用上面单元的实例的代码，unit单元：



unit Unit1;



interface



uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, StdCtrls,XMLOptionUnit, OleCtrls, SHDocVw;



type

  TForm1 = class(TForm)

    Button1: TButton;

    Button2: TButton;

    Edit1: TEdit;

    Edit2: TEdit;

    Button3: TButton;

    Button4: TButton;

    Button5: TButton;

    WebBrowser1: TWebBrowser;

    Label1: TLabel;

    Button6: TButton;

    Button7: TButton;

    Button8: TButton;

    procedure FormCreate(Sender: TObject);

    procedure FormDestroy(Sender: TObject);

    procedure Button1Click(Sender: TObject);

    procedure Button2Click(Sender: TObject);

    procedure Button3Click(Sender: TObject);

    procedure Button4Click(Sender: TObject);

    procedure Button5Click(Sender: TObject);

    procedure Button6Click(Sender: TObject);

    procedure Button7Click(Sender: TObject);

    procedure Button8Click(Sender: TObject);

  private

    { Private declarations }

    FXMLOption:TXMLOption;

  public

    { Public declarations }

  end;



var

  Form1: TForm1;



implementation



{$R *.dfm}



procedure TForm1.FormCreate(Sender: TObject);

begin

  FXMLOption:=TXMLOption.Create;

end;



procedure TForm1.FormDestroy(Sender: TObject);

begin

  FXMLOption.Free;

end;



procedure TForm1.Button1Click(Sender: TObject);

begin

  FXMLOption.CreateBlank(edit1.Text);

end;



procedure TForm1.Button2Click(Sender: TObject);

var

  auser:RecUser;

begin

  auser.U_Id:=edit2.Text;

  auser.U_Name:='tom';

  auser.U_Sex:='男';

  auser.U_Birth:='1979-8-7';

  auser.U_Tel:='1236547890';

  auser.U_Addr:='tom 大街 8 号';

  auser.U_PostCode:='100018';

  auser.U_Email:='tom@888.com';

  FXMLOption.AppendUser(auser);

  WebBrowser1.Navigate(ExtractFilePath(application.ExeName)+edit1.Text);

end;



procedure TForm1.Button3Click(Sender: TObject);

begin

  FXMLOption.OpenXml(edit1.Text);

  WebBrowser1.Navigate(ExtractFilePath(application.ExeName)+edit1.Text);

end;



procedure TForm1.Button4Click(Sender: TObject);

begin

  FXMLOption.CloseXml;

  WebBrowser1.Navigate('about:blank');

end;



procedure TForm1.Button5Click(Sender: TObject);

begin

  if  FXMLOption.FindUser(edit2.text) then label1.Caption:='true'

  else label1.Caption:='false';

end;



procedure TForm1.Button6Click(Sender: TObject);

var

  auser:RecUser;

begin

  auser.U_Id:=edit2.Text;

  auser.U_Name:='peter';

  auser.U_Sex:='女';

  auser.U_Birth:='1980-8-7';

  auser.U_Tel:='36-3654-7890';

  auser.U_Addr:='peter 大街 8 号';

  auser.U_PostCode:='100018';

  auser.U_Email:='peter@888.com';

  FXMLOption.InsertUser(edit2.text,auser);

  WebBrowser1.Navigate(ExtractFilePath(application.ExeName)+edit1.Text);

end;



procedure TForm1.Button7Click(Sender: TObject);

begin

  FXMLOption.RemoveUser(edit2.text);

  WebBrowser1.Navigate(ExtractFilePath(application.ExeName)+edit1.Text);

end;



procedure TForm1.Button8Click(Sender: TObject);

var

  auser:RecUser;

begin

  auser.U_Id:=edit2.Text;

  auser.U_Name:='张三';

  auser.U_Sex:='男';

  auser.U_Birth:='1970-8-7';

  auser.U_Tel:='001654-7890';

  auser.U_Addr:='张三 大街 8 号';

  auser.U_PostCode:='100018';

  auser.U_Email:='zhangsan@888.com';

  FXMLOption.ReplaceUser(edit2.Text,auser);

  WebBrowser1.Navigate(ExtractFilePath(application.ExeName)+edit1.Text);

end;



end.



Unit单元对应的Form：



object Form1: TForm1

  Left = 192

  Top = 107

  Width = 696

  Height = 480

  Caption = 'Form1'

  Color = clBtnFace

  Font.Charset = DEFAULT_CHARSET

  Font.Color = clWindowText

  Font.Height = -11

  Font.Name = 'MS Sans Serif'

  Font.Style = []

  OldCreateOrder = False

  OnCreate = FormCreate

  OnDestroy = FormDestroy

  PixelsPerInch = 96

  TextHeight = 13

  object Label1: TLabel

    Left = 440

    Top = 400

    Width = 32

    Height = 13

    Caption = 'Label1'

  end

  object Button1: TButton

    Left = 256

    Top = 360

    Width = 75

    Height = 25

    Caption = 'CreateBlank'

    TabOrder = 0

    OnClick = Button1Click

  end

  object Button2: TButton

    Left = 352

    Top = 360

    Width = 75

    Height = 25

    Caption = 'AddUser'

    TabOrder = 1

    OnClick = Button2Click

  end

  object Edit1: TEdit

    Left = 208

    Top = 328

    Width = 121

    Height = 21

    TabOrder = 2

    Text = 'userxml.xml'

  end

  object Edit2: TEdit

    Left = 352

    Top = 328

    Width = 121

    Height = 21

    TabOrder = 3

    Text = '900'

  end

  object Button3: TButton

    Left = 256

    Top = 384

    Width = 75

    Height = 25

    Caption = 'OpenXml'

    TabOrder = 4

    OnClick = Button3Click

  end

  object Button4: TButton

    Left = 256

    Top = 408

    Width = 75

    Height = 25

    Caption = 'CloseXml'

    TabOrder = 5

    OnClick = Button4Click

  end

  object Button5: TButton

    Left = 352

    Top = 392

    Width = 75

    Height = 25

    Caption = 'FindUser'

    TabOrder = 6

    OnClick = Button5Click

  end

  object WebBrowser1: TWebBrowser

    Left = 0

    Top = 0

    Width = 688

    Height = 313

    Align = alTop

    TabOrder = 7

    ControlData = {

      4C0000001B470000592000000000000000000000000000000000000000000000

      000000004C000000000000000000000001000000E0D057007335CF11AE690800

      2B2E126208000000000000004C0000000114020000000000C000000000000046

      8000000000000000000000000000000000000000000000000000000000000000

      00000000000000000100000000000000000000000000000000000000}

  end

  object Button6: TButton

    Left = 432

    Top = 360

    Width = 75

    Height = 25

    Caption = 'InsertUser'

    TabOrder = 8

    OnClick = Button6Click

  end

  object Button7: TButton

    Left = 512

    Top = 360

    Width = 75

    Height = 25

    Caption = 'RemoveUser'

    TabOrder = 9

    OnClick = Button7Click

  end

  object Button8: TButton

    Left = 512

    Top = 392

    Width = 75

    Height = 25

    Caption = 'ReplaceUser'

    TabOrder = 10

    OnClick = Button8Click

  end

end
genispan
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
简单实体类和xml文件的相互转换方法
12-11
最近写一个题目，要求将一组员工实体类转换成xml文件，或将xml文件转换成一组实体类。题目不难，但写完感觉可以利用泛型和反射将任意一个实体类和xml文件进行转换。于是今天下午立马动手 试了下，做了个简单的模型，可以将简单的实体类和xml文件进行相互转换，但对实体类的属性类型有限制，目前只支持String, Integer, Double三种类型。但是后面可以扩展。 我的大概思路是这样的，只要能拿到实体类的类型信息，我就能拿到实体类的全部字段名称和类型，拼属性的set和get方法更是简单明了，这时候只需要通过方法的反射，将xml文件的数据读取出来给这个反射即可。 反过来只要给我一个任意对象，我就
多个delphi读写处理xml的示例文件
05-18
多个delphi读写处理xml的示例文件，一共包括了5个Delphi操作XML文件的相关实例，这些实例来自国外网站，有的需要使用第三方控件，XML在Delphi或者其它的程序语言中都使用广泛，掌握Delphi操作XML，会另Delphi程序...
Delphi操作XML:TXMLNode类(三)
weixin_30487701的博客
02-15 340
4.1.16.60.NodeByAttributeValue　　functionNodeByAttributeValue(const NodeName: UTF8String; const AttribName: UTF8String;const AttribValue: UTF8String; ShouldRecurse: boolean): TXmlNode;　　这个函数返回子节点中...
Delphi操作XML
weixin_34273046的博客
02-26 133
Delphi操作XML Delphi操作XMl，只要使用 NativeXml。我是用的版本是4.02。NativeXML的使用方法比较简单，但是功能很强大。 XE2的话，要在simdesign.inc后面加上： // Delphi XE2 / 16 {$ifdef VER230} {$define ...
DELPHI 把数据库中的数据转换成XML格式
zb0567的专栏
08-13 1547
function ReplaceString(AString: string): string;  begin  Result := StringReplace(AString, '&', '&', [rfReplaceAll]);  Result := StringReplace(Result, '>', '>', [rfReplaceAll]);  Result := S
string 转化 xml，并找到指定节点及节点值
weixin_30492047的博客
09-13 366
//这是一个符合xml格式的字符串 string xml = "<xmn> <people><name>zs</name><age>22</age></people> <people><n...
Delphi XE 10.3.3 TFileStream读read写write字符串必须用UTF8String防止出现垃圾字符
Delphi开发局QQ群:32422310
01-14 1885
最近需要将一个Delphi 7的古老程序重构升级为Delphi 10.3.3，没想到由于Delphi字符串定义发生了变化，造成写入文件的字符串出现垃圾字符 我有Delphi 2007代码看起来像这样： procedure WriteString(Stream: TFileStream; var SourceBuffer: PChar; s: string); begin StrPCopy(SourceBuffer,s); Stream.Write(SourceBuffer[0], StrLen
delphi-xml.rar_ delphi xml_delphi XML_delphi操作xml_xml delphi
09-20
在“www.pudn.com.txt”文件中，可能包含了关于这个示例的说明或教程，而“XML”文件可能是一个XML示例文件，供用户在Delphi中加载并进行实际操作。 通过研究这个压缩包中的资源，开发者可以深入理解Delphi如何处理...
Delphi向XML中添加节点数据.rar
07-10
Delphi7向常用的XML文件中添加内容，按照XML的节点规则依次写入内容，自定义各个节点及节点内容，具体的操作代码如下示： 　var 　iXml: IDOMDocument; 　iRoot, iNode, iNode2, iChild, iAttribute: IDOMNode; 　...
xml.rar_delphi XML_xml
09-23
标题中的"xml.rar_delphi XML_xml...此外，通过查看源代码（untContatos.pas），我们可以深入了解XML读取、节点遍历、属性获取等操作的具体实现。对于想要掌握Delphi和XML处理的开发者来说，这是一个非常有价值的示例。
Xml、Json、实体类之间的转换案例
11-22
Xml、Json、实体类之间的转换案例 Xml、Json、实体类之间的转换案例
delphi解析xml文件实例
11-05
delphi解析xml文件实例，代码为delphi7编写，逐步解示XML节点读取，与记录读取方法，
Delphi XMLDocument控件之XML实例
12-03
Delphi XMLDocument控件之XML实例:新建、打开、保存、编辑等操作 Delphi XMLDocument control XML instance: new, open, save, edit, and other operations
XML.rar_delphi XML_xml
09-22
本教程将深入探讨如何在Delphi中使用XML进行基本的操作。 1. **XML的基础概念** - **元素(Element)**：XML文档的核心组成部分，由开始标签、内容和结束标签组成，如`<element>content</element>`。 - **属性...
String转换成XMLGregorianCalendar
weixin_37370093的博客
08-17 254
【代码】String转换成XMLGregorianCalendar。
Delphi 纯文本转换为xml
NowMore_Guo的博客
12-20 1310
需要读取数据生成xml文件，要求为空值时不能为”“格式，而要为”“格式，所以单纯用TXMLDocument实现不了。 而使用TFileStream将xml格式的纯文本保存为.xml文件后，会发生读取错误的问题，估计是文件头”“部分有特殊要求。 于是，使用： Xml := TXMLDocument.Create(nil);     try         //1  xml header  
delphi操作xml
02-26 734
使用delphi来操作xml文件，或者xml字符串, 导入需要单元，XMLDoc，XMLIntf这两个库文件。 doc : TXMLDocument; rootnode : IXMLNode; chender : IXMLNodeList TXMLDocument是文档结构，IXMLNode是文档节点， IXMLNodeList是节点集合。 doc:=TXMLDocument.
xml和对象之间的互相转换以及json和对象之间的互相转换
qq_58846203的博客
10-14 3333
json、对象实体类、xml的互相转换，jaxb
c# XML和实体类之间相互转换(序列化和反序列化)
weixin_42339460的博客
06-15 146
1 using System; 2 using System.Collections.Generic; 3 using System.Linq; 4 using System.Text; 5 using System.IO; 6 using System.Data; 7 using System.Xml; 8 using System.Xml.Serialization; 9 ...
Delphi RSA XML公钥
最新发布
11-17
下面是一个简单的Delphi代码示例，演示如何使用RSA加密算法和XML格式的公钥： ```delphi uses IdSSLOpenSSL, IdGlobal, IdCTypes, IdHash, IdHashSHA, IdHMAC, XMLDoc, XMLIntf, XMLDom, msxmldom, XMLDoc, xmldom...
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值