29. 面向对象的LotusScript（五）之ExtDoc

最新推荐文章于 2015-03-17 13:20:28 发布
最新推荐文章于 2015-03-17 13:20:28 发布
阅读量170 收藏
点赞数
NotesDocument是Lotus Notes的核心对象之一，在开发中会遇到很多与它有关的反复出现的功能需求，可以写成通用的函数，比如针对一个文档，创建回复、取得父文档等等。下面就是一些例子： 
%REM
	Description: Create a response for the given document.
	Use the given form name. Return the unsaved response.
%END REM
Public Function CreateResponse(doc As NotesDocument, form As String)As NotesDocument
	Dim response As NotesDocument
	Set response=doc.Parentdatabase.Createdocument()
	response.Form=form
	Call response.Makeresponse(doc)
	Set CreateResponse=response
End Function
%REM
	Description: Description: Replace the given items of the document collection 
	with the given document's items of the same name. 
	@param: itemNames is an array or a string conainting names separated by '^'
	other types provided, an error will occur
%END REM
Public Function StampCollection(dc As NotesDocumentCollection, doc As NotesDocument, itemNames As Variant) 
	Dim v
	If Not IsArray(itemNames) Then
		v=Split(itemNames, "^")
	Else
		v=itemNames
	End If
	ForAll itemName In v
		Call dc.Stampall(itemName, doc.Getitemvalue(itemName))
	End ForAll
End Function
%REM
	Description: Replace the given items of the reponses of the given document with its own items of the same name. 
	@param: itemNames is an array or a string conainting names separated by '^'
	other types provided, an error will occur
%END REM
Public function StampResponses(doc As NotesDocument, itemNames As Variant)
	Dim dc As NotesDocumentCollection
	Set dc=doc.Responses
	Call StampCollection(dc, doc, itemNames)
	'Call dc.StampAll(itemName,doc.GetItemValue(itemName))
End Function
这样的函数创建多了，我们便可以发现进一步改进的可能。它们都与NotesDocument有关，按照面向对象语言的规范，应该将它们集中到一个对象里。这样，可以收到使用对象的诸多好处，比如可以省去参数中的NotesDocument，减少了函数名称冲突的可能性。本来根据面向对象的思想，可以考虑扩展NotesDocument成为一个新的具备更多功能的类。但是LotusScript中由产品本身提供的类是不能扩展的。继承不了，我们可以换一种方式。创建一个“包含”NotesDocument的类，在其构造函数中传入需要“增强”的NotesDocument，保存在内部变量中，然后为其增加任意需要的方法，从中引用该NotesDocument。在面向对象的架构里，要创建一个新类，利用已有的类，也不只有继承一径，还可以组合或包含。 
%REM
	Class ExtDoc
	Description: Comments for Class
%END REM
Public Class ExtDoc
	Public mdoc As NotesDocument
	
	%REM
		Sub New
		Description: Comments for Sub
	%END REM
	Sub New(doc As NotesDocument)
		Set me.mdoc=doc
	End Sub
	
	%REM
		Function ReplaceItemValue
		Description: Replace the given item's value using the given "from" array to "to" array. 
	%END REM
	Public Function ReplaceItemValue(itemName As String, compareArray As Variant, replaceArray As Variant)
		Dim v As Variant
		v=me.mdoc.Getitemvalue(itemName)
		Call me.mdoc.Replaceitemvalue(itemName, ArrayReplace(v, compareArray, replaceArray))
	End Function
	
	%REM
		Function CopyAllTo
		Description: copy the document and all its descendents to
		another db.
	%END REM
	Public Function CopyAllTo(dest As NotesDatabase )
		Call mdoc.Copytodatabase(dest)
		Dim dc As NotesDocumentCollection
		Dim rdoc As NotesDocument
		Dim rext As ExtDoc
		Set dc=mdoc.Responses
		
		Set rdoc=dc.Getfirstdocument()
		Do Until rdoc Is Nothing
			Set rext=New ExtDoc(rdoc)
			Call rext.CopyAllTo(dest)
			Set rdoc=dc.Getnextdocument(rdoc)
		Loop
		Call mdoc.Copytodatabase(dest)
	End Function
	
	%REM
		Function RemoveAll
		Description: Remove the document and all its descendents
	%END REM
	Public Function RemoveAll(force As Boolean)
		Dim dc As NotesDocumentCollection
		Dim docR As NotesDocument, docTmp As NotesDocument
		Dim ed As ExtDoc
		Set dc=mdoc.Responses
		
		Set docR=dc.Getfirstdocument()
		Do Until docR Is Nothing			
			Set docTmp=dc.Getnextdocument(docR)
			Set ed=New ExtDoc(docR)
			Call ed.RemoveAll(force)
			Set docR=docTmp
		Loop
		Call mdoc.Remove(force)
	End Function
	
	%REM
		Function ComputeAndSave
		Description: Comments for Function
	%END REM
	Public Function ComputeAndSave()
		Call mdoc.Computewithform(False, False )
		Call mdoc.save(True, False)
	End Function
	
	%REM
		Function CopyItemsFrom
		Description: Comments for Function
	%END REM
	Public Function CopyItemsFrom(source As NotesDocument, items As Variant)
		If IsArray(items) Then
			ForAll itemName In items
				Call mdoc.Replaceitemvalue(itemName, source.Getitemvalue(itemName))
			End ForAll
		Else
			Call mdoc.Replaceitemvalue(items, source.Getitemvalue(items))
		End If
	End Function
	
	%REM
		Function CreateResponse
		Description: Comments for Function
	%END REM
	Public Function CreateResponseDoc(form As String ) As NotesDocument
		Set me.CreateResponseDoc=CreateResponse(me.mdoc, form)
	End Function
	
	%REM
		Function StampResponses
		Description: Replace the given item of the reponses of the wrapped document with its own item of the same name. 
	%END REM
	Public Function StampResponseDocs(itemName As Variant)
		Call StampResponses(me.mdoc, itemName)
	End Function
	
	%REM
		Function GetParentDoc
		Description: Comments for Function
	%END REM
	Public Function GetParentDoc() As NotesDocument
		Dim docResult As NotesDocument
		If me.mdoc.Isresponse Then
			Set docResult=mdoc.Parentdatabase.Getdocumentbyunid(mdoc.Parentdocumentunid)
		Else
			Set docResult=Nothing 
		End If
		Set GetParentDoc=docResult
	End Function
	
	%REM
		Function IsUnique
		Description: Check if the wrapped document is unique in the given view.
		A document is unique if for the given number -- keyNum -- of sorted columns, there's no other document
		having the same values. That is, if a GetDocumentByKey is called with an array cotaining
		keyNum of keys, no other document is returned.
	%END REM
	Public Function IsUnique(viewName As String, keyNum As Integer) As Boolean
		Dim view As NotesView
		Set view=Me.mdoc.ParentDatabase.GetView(viewName)
		Dim doc As NotesDocument
		Dim keys As New NArray(-1)
		ForAll c In view.Columns
			If c.IsSorted Then
				keys.Add(mdoc.Getitemvalue(c.Itemname)(0))
				keyNum=keyNum-1
				If keyNum=0 Then
					Exit ForAll 
				End If
			End If
		End ForAll
		
		Set doc=view.Getdocumentbykey(keys.Container, True)
		If doc Is Nothing Then
			IsUnique=True
		Else
			If doc.Universalid=mdoc.Universalid Then
				IsUnique=True
			Else
				IsUnique=False 
			End If
		End If		
	End Function
	
	%REM
		Function IsValueUnique
		Description: Check if the wrapped document is unique in the given column of the given view.
	%END REM
	Public Function IsValueUnique(value As Variant,viewName As String,columnNum As Integer) As Boolean
		Dim s As New NotesSession
		Dim view As NotesView
		Dim doc As NotesDocument	
		Set view=s.CurrentDatabase.GetView(viewName)
		Set doc=view.GetFirstDocument
		Do Until doc Is Nothing
			If doc.ColumnValues(columnNum)=value And doc.Universalid><mdoc.Universalid Then 
				Me.IsValueUnique=False
				Exit Function
			End If
			Set doc=view.GetNextDocument(doc)
		Loop
		Me.IsValueUnique=True		
	End Function
	
	%REM
		Description: Check if the wrapped document is unique in the given field of the given document collection.
	%END REM
	Public Function IsValueUniqueInDC(Field As String, dc As NotesDocumentCollection) As Boolean
		Dim doc As NotesDocument
		Set doc=dc.Getfirstdocument()
		Do Until doc Is Nothing
			'cannot compare the item value array, compare the first value instead
			If doc.GetItemValue(Field)(0)=mdoc.Getitemvalue(field)(0) And doc.Universalid><mdoc.Universalid Then 
				Me.IsValueUniqueInDC=False
				Exit Function
			End If
			Set doc=dc.GetNextDocument(doc)
		Loop
		Me.IsValueUniqueInDC=True 
	End Function
	
	%REM
		Function GetDuplicatedDoc
		Description: Return the first found document in the given view, which has the same value
		with the given document in the given column.
	%END REM
	Public Function GetDuplicatedDoc(value As Variant, viewName As String, columnNum As Integer) As NotesDocument 
		Dim s As New NotesSession
		Dim view As NotesView
		Dim doc As NotesDocument	
		Set view=s.CurrentDatabase.GetView(viewName)
		Set doc=view.GetFirstDocument
		Do Until doc Is Nothing
			If doc.ColumnValues(columnNum)=value And doc.Universalid><mdoc.Universalid Then 
				Set Me.GetDuplicatedDoc=doc
				Exit Function
			End If
			Set doc=view.GetNextDocument(doc)
		Loop		
	End Function
	%REM
		Obsolete Function ReplicateTo
		Description: Make sure the copied document has the same universal id.
		Direct copied documents will keep the response relations in 8.5. Modifying a document's universal id and saving it will generate another document with still a different OF part of the id.
	Public Function ReplicateTo(dest As NotesDatabase )
		Dim doc As NotesDocument
		Set doc= mdoc.Copytodatabase(dest)
		doc.Universalid=mdoc.Universalid
		Call doc.Save(True, False)
		Set me.ReplicateTo=doc
	End Function
	%END REM
	
	%REM
		Obsolete Function ReplicateAllTo
		Description: Comments for Function
	Public Function ReplicateAllTo(dest As NotesDatabase)
		Call me.ReplicateTo(dest)
		Dim dc As NotesDocumentCollection
		Dim rdoc As NotesDocument
		Dim rext As ExtDoc
		Set dc=mdoc.Responses
		Set rdoc=dc.Getfirstdocument()
		Do Until rdoc Is Nothing
			Set rext=New ExtDoc(rdoc)
			Call rext.ReplicateAllTo(dest)
			Set rdoc=dc.Getnextdocument(rdoc)
		Loop
	End Function
	%END REM
End Class

上面的CreateResponseDoc和StampResponseDocs方法分别调用了CreateResponse和StampResponses函数。当然也可以将这些函数本身包含进类中。大部分方法的作用都一看即知。稍微复杂一些的做了详细的注释，这里再略加说明。GetDuplicatedDoc,IsUnique, IsValueUnique,这些方法提到的Unique, Duplicated的含义都是针对某个视图的某个或某些列；IsUnique可以比较视图的前若干个排序列；IsValueUniqueInDC针对的是文档集合和某个字段。StampResponseDocs使用父文档的域更改子文档，参数中的域名可以是数组或由特殊字符^分隔开的字符串。CopyAllTo和RemoveAll里的All指的是连带所有子文档。ReplicateTo和ReplicateAllTo会修改目的文档的UniversalID，但是在8.5中似乎Notes会自动保持答复关系，故不再需要。

ExtDoc就像一把瑞士军刀，而且你还可以随时丰富它的功能。同样，对于其它Notes对象，你也可以制造你的瑞士军刀。
从此醉
关注
39. 面向对象的LotusScript（十一）之导出Excel（三）
JavaScript
07-12 3679
我们再来看一个模版型的报表的实例。 选择报表类型，输入参数： 产生的报表： 预先设计好的Excel模版以附件形式保存在配置文档中： 继承了Report基类的子类Report2的代码如下： Public Class Report2 As Report Private intYear As Integer Private intMonth As In
33. 面向对象的LotusScript（六）之为自定义对象模拟事件
JavaScript
07-02 8238
（这是一篇我几年前发表在IBM developerWorks上的文章，在此转帖，构成面向对象的LotusScript的系列文章之一篇，并为后续的讨论做准备。） 前言 事件是面向对象语言普遍支持和使用的一种模式。事件不仅在与用户交互的系统中应用很广泛，设计对象时恰当地采用事件对写出结构清晰、独立的代码也很有帮助。LotusScript支持事件，各个UI对象公布的事件在程序中都经常使用。不过在LotusScript支持的三种对象：Notes对象、自定义对象和OLE对象中，只有Notes对象支持事件。也就是说我们
ExtJs5-doc
11-21
这个是ExtJs5的离线的API文档，可以在自己机器上运行，功能强大
js doc工具推荐及使用（二）：ext-doc
wjxbj的博客
01-22 303
        在项目开发过程中，需要合适的工具来生成doc文件，通过google以及试用，发现jsdoc-toolkit和ext-doc2个工具比较有意思。         下面详细介绍下ext-doc在实际工程中的应用         官方地址为：http://code.google.com/p/ext-doc/ 一.下载解压后，目录如下图所示：         其中sample是...
Ext4.1.0 Doc中文版 和官方示例
ahua186186的专栏
07-25 345
最近要弄EXT，学习学习 http://dev.sencha.com/deploy/ext-4.0.0/examples/ http://extjs-doc-cn.github.io/ext4api/
ext4.0中文文档
08-21
ext4.0的中文文档，界面很优美
Lotus类和函数
12-17 742
Notes类 Notes 定义的 LotusScript 类允许您在两个级别上访问 Notes 的结构： 数据库（后端）类允许您访问命名的数据库、视图、文档和其他 Notes 对象。工作站和服务器的用户都可以运行访问数据库对象的 Script。 UI（前端）类允许您访问用户当前正在使用的对象。只有工作站用户才能运行访问 UI 对象的 Script 。 下列表格概述 Notes 中定义的 L
37. 面向对象的LotusScript（九）之导出Excel（一）
JavaScript
07-07 4989
上一篇文章说到在LotusScript编写类时采用继承有两类情况，接下来的几篇文章介绍的就是其中的一种：为了重用代码。将Notes数据导出到Excel就是展现这类继承的一个很好场合。 微软的Excel有很多方便有用的处理数据的功能，如筛选、排序、计算。很多公司用它来做出精美、复杂的报表。Lotus Notes的视图虽然也有很多功能，但是在多条件组合查询、统计等方面上，常常不能满足报表的需求（在客
35. 面向对象的LotusScript（七）之导入Excel
JavaScript
07-04 5247
Microsoft Office是应用最广泛的办公软件，绝大多数公司的必备软件。其中的Excel操作直观方便，很多公司都有大量数据以Excel文件的格式保存。一个LotusNotes应用在很多情况下都会需要导入Excel文件，比如程序初始化的时候导入历史数据，批量导入配置数据，定期导入人工输入或从其他系统导出的Excel文件。导入Excel文件的功能，从原理上说并不复杂，就是读取Excel工作表中
85. BASIC和LotusScript中的Variant
JavaScript
12-02 4281
缘起最近我回看以前记的关于Notes的笔记，发现在Notes bugs类别下，两条编号间隔一的竟然是相差无几的内容。2. 'Type mismatch' occurs if an nested array e.g. when an item of ColumnValues is an array, is assigned to a variant or passed as an argument
Domino 9下通过程序删除并记录未知用户及邮件组
weixin_34273479的博客
03-17 296
Domino 9下通过程序删除并记录未知用户及邮件组说道domino相信大家都很熟悉了，而我们今天呢，主要介绍在Domino 9下通过程序删除并记录未知用户及邮件组，是什么意思呢，我们都知道Domino提供的邮件服务是个人数据库文件系统，每个邮箱用户都有一个独立的数据库存放邮件信息，跟其他提供邮件服务的系统不一样，当然Domino使用起来比较灵活，可以根据自己的需求开发自定义...
用JAVA读取Domain的数据库
抢财猫股票课堂
02-22 5325
　　去年，由于做一个项目是针对DOMINO的系统，所以抽出时间研究了一个这个当初是莲花公司的传家宝。    　其实，DOMINO有自己的LOTUSSRIPT，但是大家都用JAVA习惯了，当然它也提供了JAVA的接口，所以我们参考一下它的开发文档，写了一下JAVA操作DOMNIO的数据库的例子。public class LotusReadDB {  private static String use
extJS在tomcat下部署看extjs文档
全世界失眠
08-06 3268
把ext 2.2 解压缩到$tomcat_home/webapps/下 帮助文档http://localhost:8080/ext2/docs/index.html 实例http://localhost:8080/ext2/examples/samples.html
Lotus 公式用法归类
咸鱼白菜
07-14 1524
访问用户环境用户环境是包含数据库的服务器或工作站，数据库包括以下内容： 复制公式、由新邮件到达时或定时触发的代理、选择公式或列公式。否则，用户环境是用户运行公式的 Notes 工作站。用户名可以是专有名称也可以是非专有名称，专有名称可以是规范或缩写的，使用 @Name 可更改用户名的格式。以下函数返回或处理用户环境的信息。函数 描述@UserName 返回用户名或服务器名。@Name([key
Lotus Notes企业高级开发摘要
冰火欢迎您的光临！
05-29 2022
本篇源于Lotus Notes企业高级开发这本书中的内容，感觉比较陌生的东西记录了下来。没有具体的解决办法与技巧，全是凭感觉记录下来比较杂乱的知识点了。 1.判断隐藏：！@Contains(@UserRoles;"[R_FileEditor]"|(RuleState!="编辑中"))2.NOTES ID 和UNID的区别 Notes ID 副本文档彼此间具有不同的Notes ID---8个
答复文档的判断和创建
11-29 560
Sub Initialize()  On Error GoTo a  '判断当前数据库库中的一条文档是否有答复文档，如果没有则创建一条。  Dim session As New NotesSession  Dim db As NotesDatabase  Set db = session.Currentdatabase  Dim doc As NotesDocument  Set d
getItemValue方法的妙用
风影极光
09-04 5890
应用场景1:读取表单中类型为日期的域值问题描述：在webservice中读取文档中日期类型域的值，使用getItemValueString报异常的错误。处理办法：主要代码如下：import java.util.Vector;Vacation vacation=new Vacation();    Vector dM = new Vector();dM =docume
LotusScript基础教程：面向对象的编程环境
"本文档详细介绍了LotusScript语言的基本知识，包括其与Basic语言的兼容性，面向对象的特性，以及何时在Notes环境中选择使用LotusScript或公式语言。此外，还提到了如何在Notes应用程序中访问和操作对象，以及...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值