一、定义
返回执行的上一个 Transact-SQL语句的错误号。
二、注意事项
1. 如果前一个T-SQL语句没有执行错误,则返回0
2. 如果前一个语句遇到错误,则返回错误号。如果错误是 sys.messages 目录视图中的错误之一,则 @@ERROR 将包含 sys.messages.message_id 列中表示该错误的值。可以在 sys.messages 中查看与 @@ERROR 错误号相关的文本信息。
3. 由于 @@ERROR 在每一条语句执行后被清除并且重置,因此应在语句验证后立即查看它,或将其保存到一个局部变量中以备以后查看。
4. 使用 TRY…CATCH 构造来处理错误。 TRY…CATCH 构造也支持返回错误信息多于 @@ERROR 的其他系统函数(ERROR_LINE、ERROR_MESSAGE、ERROR_PROCEDURE、ERROR_SEVERITY 和 ERROR_STATE)。 TRY…CATCH 也支持 ERROR_NUMBER 函数,但不限制该函数在语句产生错误后立即在语句中返回错误号。
三、实际应用
1.用@@ERROR检测一个特定错误
以下示例用 @@ERROR 在 UPDATE 语句中检测约束检查冲突(错误 #547)。
USE AdventureWorks2012;
GO
UPDATE HumanResources.EmployeePayHistory
SET PayFrequency = 4
WHERE BusinessEntityID = 1;
IF @@ERROR = 547
BEGIN
PRINT N'A check constraint violation occurred.';
END
GO
2. 用@@ERROR有条件地退出一个过程
以下示例使用 IF…ELSE 语句在存储过程中测试 @@ERROR 语句后的 DELETE。@@ERROR 变量的值将确定发送给调用程序的返回代码,以指示此过程的成功与失败。
--基础表准备
if object_id('tblProductinfo','U') is not null
drop table tblProductinfo
create table tblProductinfo
(ID int
,Name varchar(100)
,Price int )
insert into tblProductinfo
values
(1,'Computer',4000)
,(2,'Headset',200)
,(3,'Phone',5000)
go
select * from tblProductinfo
--新建SP
IF OBJECT_ID(N'Deletethespecifiedproduct', N'P') IS NOT NULL
DROP PROCEDURE Deletethespecifiedproduct;
GO
CREATE PROCEDURE Deletethespecifiedproduct
(
@ProductID INT
)
AS
DELETE FROM tblProductinfo
WHERE ID = @ProductID;
IF @@ERROR <> 0
BEGIN
-- Return 99 to the calling program to indicate failure.
PRINT N'An error occurred deleting the candidate information.';
RETURN 99;
END
ELSE
BEGIN
-- Return 0 to the calling program to indicate success.
PRINT N'The job candidate has been deleted.';
RETURN 0;
END;
GO
--运行SP
exec Deletethespecifiedproduct 10
3.将@@ERROR与@@ROWCOUNT一起使用
下面的示例将 @@ERROR 与 @@ROWCOUNT 一起使用来验证一条 UPDATE 语句的操作。为任何可能出现的错误而检验 @@ERROR 的值,并且用 @@ROWCOUNT 保证更新已成功应用于表中的某行。
USE AdventureWorks2012;
GO
IF OBJECT_ID(N'Purchasing.usp_ChangePurchaseOrderHeader',N'P')IS NOT NULL
DROP PROCEDURE Purchasing.usp_ChangePurchaseOrderHeader;
GO
CREATE PROCEDURE Purchasing.usp_ChangePurchaseOrderHeader
(
@PurchaseOrderID INT
,@BusinessEntityID INT
)
AS
-- Declare variables used in error checking.
DECLARE @ErrorVar INT;
DECLARE @RowCountVar INT;
-- Execute the UPDATE statement.
UPDATE PurchaseOrderHeader
SET BusinessEntityID = @BusinessEntityID
WHERE PurchaseOrderID = @PurchaseOrderID;
-- Save the @@ERROR and @@ROWCOUNT values in local
-- variables before they are cleared.
SELECT @ErrorVar = @@ERROR
,@RowCountVar = @@ROWCOUNT;
-- Check for errors. If an invalid @BusinessEntityID was specified,
-- the UPDATE statement returns a foreign key violation error #547.
IF @ErrorVar <> 0
BEGIN
IF @ErrorVar = 547
BEGIN
PRINT N'ERROR: Invalid ID specified for new employee.';
RETURN 1;
END
ELSE
BEGIN
PRINT N'ERROR: error '
+ RTRIM(CAST(@ErrorVar AS NVARCHAR(10)))
+ N' occurred.';
RETURN 2;
END
END
-- Check the row count. @RowCountVar is set to 0
-- if an invalid @PurchaseOrderID was specified.
IF @RowCountVar = 0
BEGIN
PRINT 'Warning: The BusinessEntityID specified is not valid';
RETURN 1;
END
ELSE
BEGIN
PRINT 'Purchase order updated with the new employee';
RETURN 0;
END;
GO