代码导出job3--autopackstepARES3-UFT.bat

echo *********************************************************
echo 脚本功能：O4UFT、UFR的ARES导出。
echo 脚本编写：
echo 修订时间：2014.10.23
echo *********************************************************


rem 主流程
:main
    rem SVN更新(在Jenkins中执行)


    rem 初始配置
    call %Workspace%\initTMP.bat
    call %Workspace%\autopack\UFT_20160122_LS\initNEW2-UFT.bat
    

  rem 判断是否需要编译交易核心
if "%U_uft%" EQU "true" (
      rem 导出UFT代码及脚本
      call :ExportSrc_UFT


  ) else (
   echo 本次不需要编译交易核心
  )
 
  rem Debugtool导出日志和配置文件
    call :Expinfo
 
   
    if "%U_uft%" EQU "true" (
    rem 编译UFT后台服务
    call :Compilesrc_UFT
  )
 
  rem SVN清理
    call :Svncleanup
    
goto :eof


exit /b




rem ==========================Debugtool导出日志和配置文件============================================
:Expinfo


    echo DEBUG导出前时间：%time% >>%LogDir%\ARES3计算时间.log
    rem     通过DebugTools导出日志和配置文件
    rem     DebugTools路径 %DebugTools%  
    cd /d %DebugTools%
    DebugTools.exe file=%Workspace%\autopack\UFT_20160122_LS\DebugToolsNEW-%AresProject%_UFT.bat
    copy /y  %SourcesDirUFT%\UFT\makeall %SrcDir%\UFT2.0\Run\UFTServerNew\交易核心\src\
    cd /d %SrcDir%\UFT2.0\Run\UFTServerNew\交易核心\src
    svn add * --force
    svn commit -m "生成makeall文件提交SVN" %SrcDir%\UFT2.0\Run\UFTServerNew\交易核心\src
    echo 导出debugtool日志
    cd.>%LogDir%\DebugTools_UFT.log
    move /y %DebugTools%\DebugTools.log %LogDir%\DebugTools_UFT.log
    del /q  %DebugTools%\DebugTools.log
 
    echo DEBUG导出后时间：%time% >>%LogDir%\ARES3计算时间.log
 
    echo 导出日志和配置文件完成。
goto :eof








rem ==========================导出UFT代码及脚本===============================================
:ExportSrc_UFT
    echo 导出目标源码及脚本......
    echo     本次导出配置如下：
    echo     Ares工作空间: %AresData%
    echo     Ares工程名称: %AresProject%
    
    echo ARES导出UFT导出前时间：%time% >>%LogDir%\ARES3计算时间.log
    
    rem eclipsec.exe 参数格式:
    rem -project ARES的工程(分支版本，需要修改)
    rem -data 工作空间(不同的环境，需要修改)
    rem -aresuserargs script:cmd_integrated.js 命令行需要执行的脚本
    rem -noSplash 取消启动画面 (不需修改)
    rem -application 要启动的应用，此应用固定在开发工具中(不需修改)
    
    cd /d %UFTAresPath%
    rmdir /q /s  %SourcesDirUFT%\UFT\
    eclipsec.exe -noAutoBuild -noSplash -application com.hundsun.ares.studio.compile.application -data %UFTAresData% -project %UFTAresProject% -aresuserargs script:cmd_integrated.js 1>%LogDir%\uft_ares_info.log 2>%LogDir%\uft_ares_error.log
    rem ARES工具导出makeall有问题，删除导出的makeall，避免覆盖SVN上正确的makeall
    del /q  %SourcesDirUFT%\UFT\makeall
    copy /y  %SourcesDirUFT%\UFT\*_lsu_*.xml %SrcDir%\UFT2.0\Run\UFTServerNew\前置机\workspace\convert\      
    echo UFT导出目标源码及脚本完成。
    
    echo ARES导出UFT导出后时间：%time% >>%LogDir%\ARES3计算时间.log
    
goto :eof


rem ==========================编译UFT、UFR后台服务======================================================
:Compilesrc_UFT
 
    echo 编译UFT后台前时间：%time% >>%LogDir%\ARES3计算时间.log
    
   rem 删除服务器上的程序
    %puttyDir%\plink.exe -ssh -l %UFTCompileUser% -pw %UFTCompilePwd% -m %SrcDir%\base\Run\buildscript\autopack\后台编译命令\rm.txt %UFTCompileIp% >%LogDir%\srcuft_error.log 2>>&1
    rem 上传UFT后台
    %puttyDir%\pscp.exe -sftp -l %UFTCompileUser% -pw %UFTCompilePwd% -r %SrcDir%\UFT2.0\Run\UFTServerNew\交易核心\* %UFTCompileIp%:/home/%UFTCompileUser% 2>>%LogDir%\ftp_error.log
    %puttyDir%\pscp.exe -sftp -l %UFTCompileUser% -pw %UFTCompilePwd% -r %SourcesDirUFT%\UFT\* %UFTCompileIp%:/home/%UFTCompileUser%/src 2>>%LogDir%\ftp_error.log
    %puttyDir%\pscp.exe -sftp -l %UFTCompileUser% -pw %UFTCompilePwd% -r %SrcDir%\base\Run\as2.0_x64\workspace\bin %UFTCompileIp%:/home/%UFTCompileUser%/linux.x64 2>>%LogDir%\ftp_error.log
    %puttyDir%\pscp.exe -sftp -l %UFTCompileUser% -pw %UFTCompilePwd% -r %SrcDir%\base\Run\as2.0_x64\workspace\lib %UFTCompileIp%:/home/%UFTCompileUser%/linux.x64 2>>%LogDir%\ftp_error.log
    %puttyDir%\pscp.exe -sftp -l %UFTCompileUser% -pw %UFTCompilePwd% -r %SrcDir%\UFT2.0\Run\librm\* %UFTCompileIp%:/home/%UFTCompileUser%/linux.x64/lib 2>>%LogDir%\ftp_error.log        
    rem 编译UFT后台
    %puttyDir%\plink.exe -ssh -l %UFTCompileUser% -pw %UFTCompilePwd% -m %SrcDir%\base\Run\buildscript\autopack\后台编译命令\srcuft_cmd1.txt %UFTCompileIp% >>%LogDir%\srcuft_error.log 2>>&1
    %puttyDir%\plink.exe -ssh -l %UFTCompileUser% -pw %UFTCompilePwd% -m %SrcDir%\base\Run\buildscript\autopack\后台编译命令\srcuft_cmd2.txt %UFTCompileIp% >>%LogDir%\runuft_error.log 2>>&1


    echo 编译UFT后台后时间：%time% >>%LogDir%\ARES3计算时间.log


goto :eof


rem ==========================SVN清理===========================================
:Svncleanup


    rem 避免出现下次任务运行出现SVN更新报错


       svn cleanup %workspace%\compliance\Sources\ufrcore_code
       svn cleanup %workspace%\compliance\Sources\ufrmgnt
       svn cleanup %workspace%\UFT2.0\Run
       svn cleanup %workspace%\UFT2.0\Sources\Client
       svn cleanup %workspace%\UFT2.0\Sources\newtran
       svn cleanup %workspace%\UFT2.0\Sources\资管UFT系统V20
       svn cleanup %workspace%\升级脚本




goto :eof