易语言写的浏览器雏形

.版本 2
.支持库 HtmlView
.支持库 iext
.支持库 xplib

.程序集 窗口程序集1

.子程序 __启动窗口_尺寸被改变

超文本浏览框1.移动 (, , 取用户区宽度 (), 取用户区高度 () － 超文本浏览框1.顶边 － 状态条1.高度)
编辑框1.移动 (, , 取用户区宽度 () － 编辑框1.左边 － 按钮1.宽度 － 25, )
按钮1.左边 ＝ 编辑框1.左边 ＋ 编辑框1.宽度 ＋ 10
.如果 (编辑框1.宽度 ＜ 200)
    编辑框1.宽度 ＝ 200
    按钮1.可视 ＝ 假
.否则
    按钮1.可视 ＝ 真
.如果结束




.子程序 __启动窗口_创建完毕

XP风格 (1)
编辑框1.获取焦点 ()
超文本浏览框1.离线浏览 ＝ 假


.子程序 _工具条1_被下拉
.参数 按钮索引, 整数型
.参数 下拉横座标, 整数型
.参数 下拉纵座标, 整数型

弹出菜单 (字体, 下拉横座标, 下拉纵座标)


.子程序 _工具条1_被单击
.参数 按钮索引, 整数型

.判断开始 (按钮索引 ＝ 0)
    超文本浏览框1.执行命令 (#到首页)
.判断 (按钮索引 ＝ 1)
    超文本浏览框1.执行命令 (#后退)
.判断 (按钮索引 ＝ 2)
    超文本浏览框1.执行命令 (#前进)
.判断 (按钮索引 ＝ 3)
    超文本浏览框1.执行命令 (#停止)
.判断 (按钮索引 ＝ 4)
    超文本浏览框1.执行命令 (#刷新)
.默认

.判断结束


.子程序 _超文本浏览框1_即将跳转, 逻辑型

状态条1.置文本 (1, “正在转到:” ＋ 超文本浏览框1.地址)


.子程序 _超文本浏览框1_载入进度改变
.参数 进度百分比, 整数型

状态条1.置文本 (1, “已载入” ＋ 到文本 (进度百分比) ＋ “%”)



.子程序 _超文本浏览框1_已就绪

状态条1.置文本 (1, “就绪”)
编辑框1.内容 ＝ 超文本浏览框1.地址


.子程序 _超文本浏览框1_标题被改变

标题 ＝ 超文本浏览框1.标题 ＋ “ - 雁子浏览器”


.子程序 _超文本浏览框1_命令状态被改变
.参数 命令, 整数型
.参数 是否被允许, 逻辑型

.如果 (是否被允许 ＝ 假)
    .判断开始 (命令 ＝ #前进)
        工具条1.加入状态 (2, #禁止)
        前进.禁止 ＝ 真
    .判断 (命令 ＝ #后退)
        工具条1.加入状态 (1, #禁止)
        后退.禁止 ＝ 真
    .默认

    .判断结束

.否则
    .判断开始 (命令 ＝ #前进)
        工具条1.去除状态 (2, #禁止)
        前进.禁止 ＝ 假
    .判断 (命令 ＝ #后退)
        工具条1.去除状态 (1, #禁止)
        后退.禁止 ＝ 假
    .默认

    .判断结束

.如果结束


.子程序 _超文本浏览框1_字符输入, 整数型
.参数 字符代码, 整数型

.如果真 (字符代码 ＝ #回车键)
    超文本浏览框1.地址 ＝ 编辑框1.内容
.如果真结束


.子程序 _在新窗口中打开_被选择
.局部变量 局_变量1, 文本型

.如果真 (输入框 (“输入”, , , 局_变量1, ))
    超文本浏览框1.地址 ＝ 局_变量1
.如果真结束


.子程序 _另存为_被选择

超文本浏览框1.执行命令 (#另存为)


.子程序 _打印_被选择

超文本浏览框1.执行命令 (#打印)


.子程序 _打印预览_被选择

超文本浏览框1.执行命令 (#打印预览)


.子程序 _页面设置_被选择

超文本浏览框1.执行命令 (#页面设置)


.子程序 _退出_被选择

结束 ()


.子程序 _前进_被选择

超文本浏览框1.执行命令 (#前进)


.子程序 _后退_被选择

超文本浏览框1.执行命令 (#后退)


.子程序 _到首页_被选择

超文本浏览框1.执行命令 (#到首页)


.子程序 _到搜索页_被选择

超文本浏览框1.执行命令 (#到搜索页)


.子程序 _刷新_被选择

超文本浏览框1.执行命令 (#刷新)


.子程序 _停止_被选择

超文本浏览框1.执行命令 (#停止)


.子程序 _最大_被选择

选择字体大小 (4)

.子程序 选择字体大小
.参数 字体大小, 整数型
.局部变量 字体菜单项, 菜单, , "5"
.局部变量 容器1, 整数型

字体菜单项 [1] ＝ 最小
字体菜单项 [2] ＝ 较小
字体菜单项 [3] ＝ 中等
字体菜单项 [4] ＝ 较大
字体菜单项 [5] ＝ 最大
.计次循环首 (5, 容器1)
    字体菜单项 [容器1].选中 ＝ 假
.计次循环尾 ()
字体菜单项 [字体大小 ＋ 1].选中 ＝ 真
超文本浏览框1.字体大小 ＝ 字体大小



.子程序 _较大_被选择

选择字体大小 (3)


.子程序 _中等_被选择

选择字体大小 (2)


.子程序 _较小_被选择

选择字体大小 (1)


.子程序 _最小_被选择

选择字体大小 (0)


.子程序 _关于易浏览器_被选择

' 信息框 (“简单浏览器”, 0, )
API_ShellAbout (取窗口句柄 (), “易浏览器”, “@雁子”, 0)

.子程序 _按钮1_被单击

超文本浏览框1.跳转 (编辑框1.内容, , )

工程文件：http://www.kuaipan.cn/file/id_30136668824535061.htm