【X86汇编语言 从实模式到保护模式】04 内存中的栈结构

1. 回顾

前面两章的主引导扇区功能展示了在屏幕显示字符串。02 编写主引导扇区代码 的做法是一个字符一个字符的传送到显存。编写主引导扇区代码-另一种写法 的做法是将要传送的字符先暂存到内存中，使用 movesw 指令来将这些字符传送到显存，显然这种做法更加的高效。

本章的目的是利用栈这种结构来向屏幕输出字符串 ‘1+2+3+…+100=’ ，并计算其结果然后输出。

2. 汇编代码

下面给出程序的汇编代码并进行解析。

         ;代码清单7-1
         ;文件名：c07_mbr.asm
         ;文件说明：硬盘主引导扇区代码
         ;创建日期：2011-4-13 18:02
         
         jmp near start
	
 message db '1+2+3+...+100='
        
 start:
         mov ax,0x7c0           ;设置数据段的段基地址 
         mov ds,ax

         mov ax,0xb800          ;设置附加段基址到显示缓冲区
         mov es,ax

         ;以下显示字符串 
         mov si,message          
         mov di,0
         mov cx,start-message
     @g:
         mov al,[si]
         mov [es:di],al
         inc di
         mov byte [es:di],0x07
         inc di
         inc si
         loop @g

         ;以下计算1到100的和 
         xor ax,ax
         mov cx,1
     @f:
         add ax,cx
         inc cx
         cmp cx,100
         jle @f

         ;以下计算累加和的每个数位 
         xor cx,cx              ;设置堆栈段的段基地址
         mov ss,cx
         mov sp,cx

         mov bx,10
         xor cx,cx
     @d:
         inc cx
         xor dx,dx
         div bx
         or dl,0x30
         push dx
         cmp ax,0
         jne @d

         ;以下显示各个数位 
     @a:
         pop dx
         mov [es:di],dl
         inc di
         mov byte [es:di],0x07
         inc di
         loop @a
       
         jmp near $ 
       

times 510-($-$$) db 0
                 db 0x55,0xaa

3. 代码分析

• 6行：跳转到标号 start 处执行指令。
• 8行：将想要显示的内容 ‘1+2+3+…+100=’ 存储到已标号 message 起始的内存中，以供后面来循环传送字符。
• 11-15行：和上一章的代码一样，DS 指向数据段地址，ES 指向显存的段基地址。
• 18-28行：使用 loop 指令循环将标号 message 起始的内存中的内容传送到显存中，来显示字符串。18 行使用 SI 指向源内容的起始偏移地址，DI 指向显存第一个字符的偏移地址，即 0 。
• 31-37行：循环计算从1加到100，结果存放在寄存器 AX 中。寄存器 CX 用来存放加数，每次执行完 34 行add ax,cx 后自增1。37行使用指令 jle @g 控制循环，表示上一次的比较是 目的操作数 <= 源操作数 就跳转到 @g 处执行。
• 40-53行：循环分解各个计算结果的各个数位，并使用栈结构来存储计算得到的数位信息。

栈是一种特殊的数据存储结构，数据的存取操作只能从一端进行。先进去的数据后出来。存数操作叫入栈，对应汇编指令push。取数操作叫出栈，对应汇编指令 pop。

如下图是栈的入出栈示意图。入栈时：sp = sp-2，然后再从存入一个字的数据到 ss:sp 指向的内存。出栈时：先从 ss:sp 指向的内存取出一个字的数据，然后 sp = sp+2。

和代码段，数据段还有附加段一样，栈也是一个内存段，叫做栈段（Stack Segment），由段寄存器执行。入栈和出栈只能在一端进行操作，因此需要使用栈指针寄存器 SP 来指示下一个数据应当压入到什么位置，或者数据从哪里弹出。定义一个栈需要两个连续的步骤，即初始化段寄存器 SS 和栈指针 SP 的内容。42-43行就定义了一个栈，SS 和 SP 的的内容都为 0x0000。

目前，我们已经定义了3个段，内存布局如下图所示。

总内存容量是1MB，物理地址范围是 0x00000-0xFFFFF。

其中假定数据段长度是64KB（实际上它的长度无关紧要），占据的物理地址范围是0x07C00-0x17BFF，对应的逻辑地址为范围为 0x07C0:0x0000-0x7C00:0xFFFF;

代码段和栈段是同一个段，占据着物理地址0x00000-0x0FFFF，对应的逻辑地址的范围是0x0000:0x0000-0x0000:0xFFFF。

虽然代码段和栈段在本质上指向同一块内存，但是栈是从高地址向低地址扩展的，代码段是 低地址向高地址推进的。代码段和栈段是互不干扰的。如下图所示

使用除法来分解数位，44行把除数10用寄存器 BX 暂存。因为后面需要显示各个数位，所以使用 CX 来保存一共有多少位数。

• 57-62行：循环出栈，并传输到显存中，循环次数在 CX 中。
• 64行：死循环。
• 67-68行：填充剩余的空间。最后的 0x55 和 0xaa 是主引导扇区的有效标志。

4. 进一步认识栈

1. push 指令的操作数可以是 16 位寄存器或者 16 位内存单元。push指令执行后，压入栈中的仅仅是该寄存器或者内存单元中的数值。
2. 栈在本质上也只是普通的内存区域，之所以用 push 和 pop 指令来访问，是因为你把它看成栈而已。引入栈和 push、pop 只是方便程序开发而已。
3. 要注意保持栈平衡。push 和 pop 的次数应当一致。
4. 在编写程序时，必须充分估计所需的栈空间，以防止破坏有用的数据。
5. 尽管不能完全阻止程序中的错误，但是，通过将栈定义到一个单独的 64KB 段，可以使错误仅局限于栈，而不破坏其他段的有用数据。

5. 运行结果

程序运行结果示意图：