Flash 刮刮乐

通过ActionScript3.0的位图BitmapData可以实现类似刮刮乐的效果

1、新建一fla文件GGL，在舞台上摆好刮刮乐背景图片，包括刮奖区，兑换，在刮一次等，这里主要处理兑换区。

2、将图片兑换区转换成元件，即将要操作的对象，选择在第一帧导出ScratchLayer

3、新建一as文件GGL，与fla文件关联，主要代码如下：

package
{
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.display.Bitmap;
import flash.display.BitmapData;


public class GGK extends Sprite
{
private var scratchBmp:Bitmap;//刮涂层位图显示对象
private var scratchContent:BitmapData;//刮涂层位图数据
private var scrachlayer:Sprite;//刮涂层精灵
private var tipWnd:PopWindow;//提示窗口
private var isScratch:Boolean;
public function GGK():void
{
init();
}


private function init():void
{
tipWnd = null;
isScratch = false;
var rewardItem:Sprite = new reward();
addChild(rewardItem);
rewardItem.x = 86;
rewardItem.y = 175;


scratchContent = new ScratchLayerBitmapData();
scratchBmp = new Bitmap();
scratchBmp.bitmapData = scratchContent;
this.addChild(scratchBmp);
scratchBmp.x = 42;
scratchBmp.y = 150;


scrachlayer = new Sprite();
scrachlayer.graphics.beginFill(0xff33cc,0);
scrachlayer.graphics.drawRect(0,0,scratchBmp.width,scratchBmp.height);
scrachlayer.graphics.endFill();
this.addChild(scrachlayer);
scrachlayer.x = scratchBmp.x;
scrachlayer.y = scratchBmp.y;
scrachlayer.addEventListener(MouseEvent.MOUSE_DOWN,onScrachHandler);

exchange_btn.addEventListener(MouseEvent.CLICK,onExchangeHandler);
once_btn.addEventListener(MouseEvent.CLICK,onOnceMoreHandler);
}


/**
开始刮涂
**/
private function onScrachHandler(e:MouseEvent):void
{
scrachlayer.addEventListener(MouseEvent.MOUSE_MOVE,scrachingHandler);
stage.addEventListener(MouseEvent.MOUSE_UP,stopScrachHandler);
}
/**
刮涂过程
**/
private function scrachingHandler(e:MouseEvent):void
{
var mousex:int = mouseX - scratchBmp.x;
var mousey:int = mouseY - scratchBmp.y;
for (var i:int = mousex-5; i<mousex+5; i++)
{
for (var j:int = mousey-5; j<mousey+5; j++)
{
scratchBmp.bitmapData.setPixel32(i,j,0);
}
}
}


/**
停止刮涂
**/
private function stopScrachHandler(e:MouseEvent):void
{
scrachlayer.removeEventListener(MouseEvent.MOUSE_MOVE,scrachingHandler);
stage.removeEventListener(MouseEvent.MOUSE_UP,stopScrachHandler);
isScratch = true;
}

/**兑换处理**/
private function onExchangeHandler(e:MouseEvent):void
{
if(!tipWnd&&isScratch)
{
tipWnd = new PopWindow();
tipWnd.x = 52; 
tipWnd.y = 50;
this.addChild(tipWnd);
}
}

/**再刮一次处理**/
private function onOnceMoreHandler(e:MouseEvent):void
{
scratchContent.dispose();
scratchContent = null;
scratchContent = new ScratchLayerBitmapData();
scratchBmp.bitmapData = scratchContent;
if(tipWnd)
{
this.removeChild(tipWnd);
tipWnd = null;
}
isScratch = false;
}
}

}

Ctrl+Enter导出效果如下：