jzoj P2131【2017.4.21普及】数字游戏

题目大意：
一行n个数字数字a1，a2，a3，……，an，第二行也n个数字b1，b2，b3，……，bn，给出M个回合的机会，每回合你可以从中选择一个数字擦去它，接着剩下来的每个数字ai都要递减一个值bi,即a1减掉b1,a2减掉b2,….。如此重复M个回合，所有你擦去的数字之和就是你所得的分数，求最后你最多能得到的分数。

1<=n<=2000
1<=m<=n
1<=a[1]..a[n]<=10000
1<=b[1]..b[m]<=500

题解：
DP：
一开始将b排序，让大的尽量靠前，满足贪心策略。
然后做DP，
f[i,j]表示前i个数字擦了j次的擦去的数字之和的最大值。
然后状态转移方程：
边界:
fillchar(f,sizeof(f),200);
//因为方程的过程中可能会出现负数，所以不能初值为0，不然会出事……
f[i-1,0]:=0; 1<=i<=n
f[i,j]=max(f[i-1,j]，f[i-1,j-1]+a[i]-b[i]*(j-1))

var
       a,b:array [0..2001] of longint;
       f:Array [0..2001,0..2001] of longint;
       n,m,i,j:longint;
begin
       assign(input,'game.in'); reset(input);
       assign(output,'game.out'); rewrite(output);
       readln(n);
       readln(m);
       for i:=1 to n do read(a[i]); readln;
       for i:=1 to n do read(b[i]); readln;
       for i:=1 to n do
           for j:=i+1 to n do
               if b[i]<b[j] then
                  begin
                       a[0]:=a[i];a[i]:=a[j];a[j]:=a[0];
                       b[0]:=b[i];b[i]:=b[j];b[j]:=b[0];
                  end;
       fillchar(f,sizeof(f),200);
       for i:=1 to n do
       begin
            f[i-1,0]:=0;
            for j:=1 to m do
               if f[i-1,j]>f[i-1,j-1]+a[i]-b[i]*(j-1)
                  then f[i,j]:=f[i-1,j]
                  else f[i,j]:=f[i-1,j-1]+a[i]-b[i]*(j-1);
       end;
       writeln(f[n,m]);
       close(input); close(output);
end.