windows下bat方式快速修改ip

某些情况下，客户场地调试代码，客户内网无法上网且调试需设置固定ip，想要上网又要重新设置ip自动获得。
手动设置麻烦，就写个批处理文件修改吧。

选择【更改网络适配器选项】

查看你需要修改的网络

如果是wifi 一般设置下面脚本里面的变量名称networkName为WLAN，有线连接一般设为以太网，具体根据自己电脑查看决定。

bat文件内容如下：

@echo off 
 
:: BatchGotAdmin 
:------------------------------------- 
REM --> Check for permissions 
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system" 
 
REM --> If error flag set, we do not have admin. 
if '%errorlevel%' NEQ '0' ( 
 goto UACPrompt 
) else ( goto gotAdmin ) 
 
:UACPrompt 
 echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs" 
 echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs" 
 
 "%temp%\getadmin.vbs" 
 exit /B 
 
:gotAdmin 
 if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" ) 
 pushd "%CD%" 
 CD /D "%~dp0" 
:-------------------------------------- 
echo ---- 
echo 脚本变量[networkName]为网络的名称，默认为"以太网"
echo ---- 
echo 设置自动ip请按1

echo 设置固定ip请按2

echo 请选择,或按q退出...

set /p shu= 

set networkName=WLAN

if "%shu%"=="1" cls&goto ONE
if "%shu%"=="2" cls&goto TWO
if "%shu%"=="q" exit

:ONE
echo 正在设置网络[%networkName%]自动获得IP地址，请稍等……

netsh interface ip set address name=%networkName% source=dhcp

netsh interface ip set dns name=%networkName% source=dhcp 

set /p wait= 设置成功，按任意键退出

exit

:TWO
echo 正在设置网络[%networkName%]固定IP地址请稍等……

netsh interface ip set address name=%networkName% source=static addr=192.168.0.108 mask=255.255.255.0 gateway=192.168.0.1 gwmetric=1

echo 正在设置您的DNS，请稍等……

netsh interface ip set dns name=%networkName% source=static addr=114.114.114.114 validate=no
netsh interface ip add dns name=%networkName% addr=114.114.115.115 validate=no

set /p wait= 设置成功，按任意键退出

exit

运行bat文件弹出框如下：