VB6.0实现系统托盘

 　WINDOWS状态栏也称系统托盘，在WINDOWS9X中已有系统时钟、音量控制、输入法等程序在WINDOWS的状态栏中设有图标，一些应用程序在安装完后也将它们本身的图标放入了状态栏中，如超级解霸、WINAMP等。通过在应用程序中有效地控制状态栏中的图标，不仅可以使应用程序具有专业水准，也方便了用户的操作。VB做为一种使用很广的高级语言，实现将图标放入状态栏的功能并不困难，只要有效地利用一个API函数 Shell_NotifyIcon和NOTIFYICONDATA数据结构就能达到这一目的，有关这两者的定义和使用在程序中有详细的注释，在此就不再详述了。

　　下面的这个程序运行后，将窗口图标加入到了WINDOWS状态栏中，用鼠标右击该图标会弹出一个菜单，可实现修改该图标、窗口复位、最小化、最大化及关闭程序等功能。

　　在VB6中新建一工程，将FORM1的ScalMode的属性设为3，加入一个image控件和一个对话框控件（要加入对话框控件，须在部件中选取Microsoft Common Dialog Control 6.0），将image1的visible属性改为False，为该Form添加一个菜单，菜单设置如下：

标题 名称
文件(&F) mnuFile （一级菜单）
退出(&E) mnuExit （二级菜单）
Popup mnuTray （一级菜单,去掉该项的"可见"项）
更换图标(&I)  mnuTrayChangeIcon (以下全为二级菜单)
恢复(&R) mnuTrayRestore
最小化(&N) mnuTrayMinimize
最大化(&X) mnuTrayMaximize
-  mnuTrayLine
关闭(&C) mnuTrayClose
对于Windows来说，这些图标并非窗口或程序，它们只是托盘图标，能作出这样的功能，关键在于调用了Windows的API函数Shell_NotifyIcon，在Visual Basic开发环境中，通过其所附带的API浏览器，我们可查找出Shell_NotifyIcon的声明格式如下：

---- Declare Function Shell_NotifyIcon Lib "shell32.dll" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, lpData As NOTIFYICONDATA) As Long

---- 现把本函数声明中的参数分别说明如下：

---- 参数dwMessage为消息设置值，它可以是以下的几个常数值：0、1、2。在程序中为了使用更方便，我们把它们定义为三个常量：NIM_ADD、NIM_MODIFY及NIM_DELETE，本示例中的常量及Shell_NotifyIcon调用都可以在窗口新建的模块中声明它：

Public Const NIM_ADD = 0 //加入图标到系统状态栏中
Public Const NIM_MODIFY = 1 //修改系统状态栏中的图标
Public Const NIM_DELETE = 2 //删除系统状态栏中的图标

---- 这三个常量的应用将中下文中具体介绍。
---- 参数LpData 用以传入NOTIFYICONDATA数据结构变量，我们也需要在"模块"中定义其结构如下：

Type NOTIFYICONDATA
cbSize As Long
hWnd As Long
uID As Long
uFlags As Long
uCallbackMessage As Long
hIcon As Long
szTip As String * 64
End Type

---- 在本数据结构定义中，各变量都有其实用意义：
cbSize：需填入NOTIFYICONDATA数据结构的长度。
HWnd：设置成窗口的句柄。
Uid：为图标所设置的ID值。
UFlags：用来设置以下三个参数uCallbackMessage、
hIcon、szTip是否有效。
UCallbackMessage：消息编号。
HIcon：显示在状态栏上的图标。
SzTip：提示信息。

---- 其中参数uCallbackMessage、hIcon、szTip也应在模块中声明为以下的常量：
Public Const NIF_MESSAGE = 1
Public Const NIF_ICON = 2
Public Const NIF_TIP = 4

---- 了解了上述各参数所代表的意义，就可以直接编写代码了。
---- 例

---- 1、加入图标按钮。代码如下：

Dim nid As NOTIFYICONDATA

nid.cbSize = Len(nid)
//取数据结构的长度设置给cbSize
nid.hWnd = Me.hWnd //设置窗体的句柄
nid.uID = 9999 //图标的ID值，可自定义
nid.uFlags = NIF_ICON //表示设置图标
nid.hIcon = Me.Icon
//把图标设置成当前窗体的图标，也可以指定为某一图标文件

Shell_NotifyIcon NIM_ADD, nid //加入图标

---- 2、删除图标按钮。这里要注意的是，当我们把图标加入到状态栏后，一定要把hWnd及uID的值记下来，不然将无法正确删除此图标，本按钮的Click事件代码如下：

Dim nid As NOTIFYICONDATA
nid.cbSize = Len(nid)
nid.hWnd = Me.hWnd //记下句柄
nid.uID = 9999 //ID值
Shell_NotifyIcon NIM_DELETE, nid
//调用Shell_NotifyIcon函数删除它

---- 3、改变图标按钮。同样的道理，在窗体运行过程中，如果要更新图标，可以用以下的Click事件代码来完成：
Dim nid As NOTIFYICONDATA
nid.cbSize = Len(nid)
nid.hWnd = Me.hWnd
nid.uID = 9999
nid.uFlags = NIF_ICON
nid.hIcon = Image1.Picture
//用窗体中的Image控件中之图片来代替

Shell_NotifyIcon NIM_MODIFY, nid //修改它

---- 4、设置信息提示按钮。提示信息就是当我们将鼠标移到本图标上时，这些图标会显示出来的信息，下面的Click事件代码可以作到：
Dim nid As NOTIFYICONDATA

nid.cbSize = Len(nid)
nid.hWnd = Me.hWnd
nid.uID = 9999
nid.uFlags = NIF_ICON + NIF_TIP
nid.szTip = "这是试验图标" + Chr(0)
Shell_NotifyIcon NIM_MODIFY, nid

---- 当然，在把本窗口缩小成图标的同时，也别忘了将窗口隐藏，代码是：Me.hide。这样窗口就不会在任务栏中出现了。
---- 利用Win 32 API函数，我们可以完成很多VB本身不具备的功能，只要灵活运用，必能为VB应用程序增色不少
　　以下是程序清单：

Option Explicit

Private Declare Function Shell_NotifyIcon Lib "shell32.dll" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, lpData As NOTIFYICONDATA) As Long

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

Private Const WM_SYSCOMMAND = &H112
Private Const SC_RESTORE = &HF120&

Private LastState As Integer '保留原窗口状态

'---------- dwMessage可以是以下NIM_ADD、NIM_DELETE、NIM_MODIFY 标识符之一----------
Private Const NIM_ADD = &H0 '在任务栏中增加一个图标
Private Const NIM_DELETE = &H2 '删除任务栏中的一个图标
Private Const NIM_MODIFY = &H1 '修改任务栏中个图标信息

Private Const NIF_MESSAGE = &H1 'NOTIFYICONDATA结构中uFlags的控制信息
Private Const NIF_ICON = &H2
Private Const NIF_TIP = &H4

Private Const WM_MOUSEMOVE = &H200 '当鼠标指针移至图标上

Private Const WM_LBUTTONUP = &H202
Private Const WM_RBUTTONUP = &H205

Private Type NOTIFYICONDATA
　cbSize As Long '该数据结构的大小
　hwnd As Long '处理任务栏中图标的窗口句柄
　uID As Long '定义的任务栏中图标的标识
　uFlags As Long '任务栏图标功能控制，可以是以下值的组合（一般全包括）
　'NIF_MESSAGE 表示发送控制消息；
　'NIF_ICON表示显示控制栏中的图标；
　'NIF_TIP表示任务栏中的图标有动态提示。
　uCallbackMessage As Long '任务栏图标通过它与用户程序交换消息，处理该消息的窗口由hWnd决定
　hIcon As Long '任务栏中的图标的控制句柄
　szTip As String * 64 '图标的提示信息
End Type

Dim myData As NOTIFYICONDATA

Private Sub Form_Load()
　If WindowState = vbMinimized Then
　　LastState = vbNormal
　Else
　　LastState = WindowState
　End If

　With myData
　　.cbSize = Len(myData)
　　.hwnd = Me.hwnd
　　.uID = 0
　　.uFlags = NIF_ICON Or NIF_MESSAGE Or NIF_TIP
　　.uCallbackMessage = WM_MOUSEMOVE
　　.hIcon = Me.Icon.Handle '默认为窗口图标
　　.szTip = "提示" & vbNullChar
　End With

　Shell_NotifyIcon NIM_ADD, myData

End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
　Select Case CLng(X)
　　Case WM_RBUTTONUP '鼠标在图标上右击时弹出菜单
　　　　Me.PopupMenu mnuTray
　　Case WM_LBUTTONUP '鼠标在图标上左击时窗口若最小化则恢复窗口位置
　　　　If Me.WindowState = vbMinimized Then
　　　　　Me.WindowState = LastState
　　　　　Me.SetFocus
　　　　End If
　End Select
End Sub

Private Sub Form_Unload(Cancel As Integer)
　Shell_NotifyIcon NIM_DELETE, myData '窗口卸载时，将状态栏中的图标一同卸载
End Sub

Private Sub mnuExit_Click()
　Unload Me
End Sub

Private Sub mnuTrayChangeIcon_Click()
　On Error GoTo ErrHandler
　With cdlOpen
　　.CancelError = True ' 设置标志
　　.InitDir = App.Path ' 默认的文件夹为当前文件夹
　　.Flags = cdlOFNHideReadOnly ' 设置过滤器
　　.Filter = "图标文件 (*.ico)|*.ico" ' 指定缺省的过滤器为图标文件
　　.ShowOpen ' 显示选定文件的名字
　End With

　Image1.Picture = LoadPicture(cdlOpen.FileName)

　With myData
　　.hIcon = Image1.Picture
　　.uFlags = NIF_ICON
　End With
　Shell_NotifyIcon NIM_MODIFY, myData

ErrHandler: ' 用户按了"取消"按钮
　　Exit Sub
End Sub

Private Sub mnuTrayClose_Click()
　Unload Me
End Sub

Private Sub Form_Resize()
　Select Case WindowState
　　Case vbMinimized
　　　mnuTrayMaximize.Enabled = True
　　　mnuTrayMinimize.Enabled = False
　　　mnuTrayRestore.Enabled = True
　　Case vbMaximized
　　　mnuTrayMaximize.Enabled = False
　　　mnuTrayMinimize.Enabled = True
　　　mnuTrayRestore.Enabled = True
　　Case vbNormal
　　　mnuTrayMaximize.Enabled = True
　　　mnuTrayMinimize.Enabled = True
　　　mnuTrayRestore.Enabled = False
　End Select
　If WindowState <> vbMinimized Then LastState = WindowState
End Sub

Private Sub mnuTrayMaximize_Click()
　WindowState = vbMaximized
End Sub

Private Sub mnuTrayMinimize_Click()
　WindowState = vbMinimized
End Sub

Private Sub mnuTrayRestore_Click()
　SendMessage hwnd, WM_SYSCOMMAND, SC_RESTORE, 0&
End Sub