[poj2761]Feed the dogs

最新推荐文章于 2018-06-01 12:27:42 发布

hccz95

最新推荐文章于 2018-06-01 12:27:42 发布

阅读量1k

点赞数

文章标签： delete insert tree search each intervals

本文链接：https://blog.csdn.net/hccz95/article/details/6310627

版权

Feed the dogs

Time Limit: 6000MS		Memory Limit: 65536K
Total Submissions: 9390		Accepted: 2603

Description

Wind loves pretty dogs very much, and she has n pet dogs. So Jiajia has to feed the dogs every day for Wind. Jiajia loves Wind, but not the dogs, so Jiajia use a special way to feed the dogs. At lunchtime, the dogs will stand on one line, numbered from 1 to n, the leftmost one is 1, the second one is 2, and so on. In each feeding, Jiajia choose an inteval[i,j], select the k-th pretty dog to feed. Of course Jiajia has his own way of deciding the pretty value of each dog. It should be noted that Jiajia do not want to feed any position too much, because it may cause some death of dogs. If so, Wind will be angry and the aftereffect will be serious. Hence any feeding inteval will not contain another completely, though the intervals may intersect with each other.

Your task is to help Jiajia calculate which dog ate the food after each feeding.

Input

The first line contains n and m, indicates the number of dogs and the number of feedings.

The second line contains n integers, describe the pretty value of each dog from left to right. You should notice that the dog with lower pretty value is prettier.

Each of following m lines contain three integer i,j,k, it means that Jiajia feed the k-th pretty dog in this feeding.

You can assume that n<100001 and m<50001.

Output

Output file has m lines. The i-th line should contain the pretty value of the dog who got the food in the i-th feeding.

Sample Input

7 2
1 5 2 6 3 7 4
1 5 3
2 7 1

Sample Output

3
2

Source

POJ Monthly--2006.02.26,zgl & twb

译题:

野生动物园

Time Limit:30000MS Memory Limit:65536K
Total Submit:25 Accepted:13

Description

有一个很大的野生动物园。这个动物园坐落在一个狭长的山谷内，这个区域从南到北被划分成N个区域，每个区域都饲养着一头狮子。这些狮子从北到南编号为1,2,3,…,N。每头狮子都有一个觅食能力值Ai，Ai越小觅食能力越强。饲养员cmdButtons决定对狮子进行M次投喂，每次投喂都选择一个区间[I,J]，从中选取觅食能力值第K强的狮子进行投喂。值得注意的是，cmdButtons不愿意对某些区域进行过多的投喂，他认为这样有悖公平。因此cmdButtons的投喂区间是互不包含的。你的任务就是算出每次投喂后，食物被哪头狮子吃掉了。

Input

输入文件第一行有两个数N和M。此后一行有N个数，从南到北描述狮子的觅食能力值。此后M行，每行描述一次投喂。第t+2的三个数I,J,K表示在第t次投喂中，cmdButtons选择了区间[I,J]内觅食能力值第K强的狮子进行投喂。

Output

有M行，每行一个整数。第i行的整数表示在第i次投喂中吃到食物的狮子的觅食能力值。

Sample Input

7 2
1 5 2 6 3 7 4
1 5 3
2 7 1

Sample Output

3
2
数据范围：
对于50%的数据，有1<=N<=10000，1<=M<=500；
对于100%的数据，有1<=N<=100000，1<=M<=50000。

思路:

由于各个区间不包含,所以采用离线算法.

将所有区间按左端点(左端点相同时按右端点)排好序,

每次执行这个操作

再在treap中查找第k大的数.

{
Source Code

Problem: 2761  User: hccz95 
Memory: 4212K  Time: 2172MS 
Language: Pascal  Result: Accepted

Source Code
}
const   maxM            = 50000 ;
        maxN            = 100000 ;
var     n , m , root , size     : Longint ;
        q               : array[ 0..maxM ] of record
                x , y , k , r : Longint end;
        a , ans         : array[ 0..maxN ] of Longint ;
        tree , L , R    : array[ 0..maxN*2 ] of Longint ;
        Aux , wei       : array[ 0..maxN*2 ] of Longint ;

function max( a , b : Longint ) : Longint ;
begin
        if a > b then exit( a ) else exit( b );
end;

procedure qsort( L , R : Longint );
var     i , j , mx , my : Longint ;
begin
        i := L ; j := R ;
        mx := q[ ( i + j ) >> 1 ].x ; my := q[ ( i + j ) >> 1 ].y ;
        repeat
            while ( q[ i ].x < mx ) or ( q[ i ].x = mx ) and ( q[ i ].y < my ) do inc( i );
            while ( q[ j ].x > mx ) or ( q[ j ].x = mx ) and ( q[ j ].y > my ) do dec( j );
            if i <= j then
            begin
                q[ 0 ] := q[ i ] ; q[ i ] := q[ j ] ; q[ j ] := q[ 0 ] ;
                inc( i ); dec( j );
            end;
        until i > j ;
        if i < R then qsort( i , R );
        if j > L then qsort( L , j );
end;

procedure Rotate_L( var i : Longint );
var     j               : Longint ;
begin
        j := R[ i ] ;
        R[ i ] := L[ j ] ;
        L[ j ] := i ;
        wei[ j ] := wei[ i ] ;
        wei[ i ] := wei[ L[ i ] ] + wei[ R[ i ] ] + 1 ;
        i := j ;
end;

procedure Rotate_R( var i : Longint );
var     j               : Longint ;
begin
        j := L[ i ] ;
        L[ i ] := R[ j ] ;
        R[ j ] := i ;
        wei[ j ] := wei[ i ] ;
        wei[ i ] := wei[ L[ i ] ] + wei[ R[ i ] ] + 1 ;
        i := j ;
end;

procedure insert( var i : Longint ; x : Longint );
begin
        if i = 0 then
        begin
            inc( size ); i := size ;
            tree[ i ] := x ; Aux[ i ] := random( 65536 ); wei[ i ] := 1 ;
            exit;
        end;
        if x <= tree[ i ] then
        begin
            insert( L[ i ] , x );
            if Aux[ L[ i ] ] > Aux[ i ] then Rotate_R( i );
        end else
        begin
            insert( R[ i ] , x );
            if Aux[ R[ i ] ] > Aux[ i ] then Rotate_L( i );
        end;
        wei[ i ] := wei[ L[ i ] ] + wei[ R[ i ] ] + 1 ;
end;

procedure delete( var i : Longint ; x : Longint );
begin
        if i = 0 then exit;
        if tree[ i ] = x then
        begin
            if ( L[ i ] = 0 ) or ( R[ i ] = 0 ) then i := L[ i ] + R[ i ] else
                if Aux[ L[ i ] ] > Aux[ R[ i ] ] then
                begin
                    Rotate_R( i );
                    delete( R[ i ] , x );
                end else
                begin
                    Rotate_L( i );
                    delete( L[ i ] , x );
                end;
            if i > 0 then wei[ i ] := wei[ L[ i ] ] + wei[ R[ i ] ] + 1 ;
            exit;
        end;
        if x < tree[ i ] then delete( L[ i ] , x )
        else delete( R[ i ] , x );
        wei[ i ] := wei[ L[ i ] ] + wei[ R[ i ] ] + 1 ;
end;

function search( i : Longint ; x : Longint )        : Longint ;
begin
        if wei[ L[ i ] ] + 1 = x then exit( tree[ i ] );
        if x <= wei[ L[ i ] ] then exit( search( L[ i ] , x ) );
        exit( search( R[ i ] , x - wei[ L[ i ] ] - 1 ) );
end;

procedure main;
var     i , j           : Longint ;
begin
        readln( n , m );
        for i := 1 to n do read( a[ i ] );
        readln;
        for i := 1 to m do with q[ i ] do
        begin
            readln( x , y , k );
            r := i ;
        end;
        qsort( 1 , m );
        size := 0 ; root := 0 ;
        fillchar( q[ 0 ] , sizeof( q[ 0 ] ) , 0 );
        for i := 1 to m do
        begin
            for j := q[ i - 1 ].x to q[ i ].x - 1 do delete( root , a[ j ] );
            for j := max( q[ i ].x , q[ i - 1 ].y + 1 ) to q[ i ].y do insert( root , a[ j ] );
            ans[ q[ i ].r ] := search( root , q[ i ].k );
        end;
        for i := 1 to m do writeln( ans[ i ] );
end;

begin
        main;
end.