jboss-as-7.1.1.Final注册为windows服务

     第一步

    先到网页http://www.jboss.org/jbossweb/downloads/jboss-native-2-0-10.html
    下载相应的辅助文件，我的系统是win7的64位系统，所以下载的是

    下载后的名字是jboss-native-2.0.10-windows-x64-ssl.zip

   第二步

   解压下载的zip文件，在路径D:\jBoss\jboss-native-2.0.10-windows-x64-ssl\bin下面找到

   两个文件，将他们放入jboss 文件夹的bin目录下，我的是D:\jBoss\jboss-as-7.1.1.Final\bin

   第三步

   对刚刚的service.bat进行修改。

   在我的文档中

    里面的jboss的路径是这样的，一定要记得对里面所有的jboss路径进行修改，大概一共有12个，我开始的时候就是没有修改这个地方，然后注册的服务不能启动。

   第四步

   打开cmd页面，cd到jboss的bin目录下面，运行service.bat install

 

   然后打开服务窗口，就可以看到刚刚注册的服务了。

 

 

ps:我的service.bat并不是压缩包里面的，而是在网上另外找的，源代码如下：

@echo off

REM JBoss, the OpenSource webOS

REM

REM Distributable under LGPL license.

REM See terms of license at gnu.org.

REM

REM -------------------------------------------------------------------------

REM JBoss Service Script for Windows

REM -------------------------------------------------------------------------

 

 

 

 

@if not "%ECHO%" == "" echo %ECHO%

@if "%OS%" == "Windows_NT" setlocal

set DIRNAME=%CD%

 

 

REM

REM VERSION, VERSION_MAJOR and VERSION_MINOR are populated

REM during the build with ant filter.

REM

set SVCNAME=JBoss7

set SVCDISP=JBoss Application Server 7.1.1

set SVCDESC=JBoss Application Server 7.1.1 Platform: Windows x64

set NOPAUSE=Y

 

 

REM Suppress killing service on logoff event

set JAVA_OPTS=%JAVA_OPTS% -Xms512m -Xmx512m -XX:PermSize=128M -XX:MaxNewSize=256m -XX:MaxPermSize=512m

 

 

REM Figure out the running mode

 

 

if /I "%1" == "install"   goto cmdInstall

if /I "%1" == "uninstall" goto cmdUninstall

if /I "%1" == "start"     goto cmdStart

if /I "%1" == "stop"      goto cmdStop

if /I "%1" == "restart"   goto cmdRestart

if /I "%1" == "signal"    goto cmdSignal

echo Usage: service install^|uninstall^|start^|stop^|restart^|signal

goto cmdEnd

 

 

REM jbosssvc retun values

REM ERR_RET_USAGE           1

REM ERR_RET_VERSION         2

REM ERR_RET_INSTALL         3

REM ERR_RET_REMOVE          4

REM ERR_RET_PARAMS          5

REM ERR_RET_MODE            6

 

 

:errExplain

if errorlevel 1 echo Invalid command line parameters

if errorlevel 2 echo Failed installing %SVCDISP%

if errorlevel 4 echo Failed removing %SVCDISP%

if errorlevel 6 echo Unknown service mode for %SVCDISP%

goto cmdEnd

 

 

:cmdInstall

jbosssvc.exe -imwdc %SVCNAME% "%DIRNAME%" "%SVCDISP%" "%SVCDESC%" service.bat

if not errorlevel 0 goto errExplain

echo Service %SVCDISP% installed

goto cmdEnd

 

 

:cmdUninstall

jbosssvc.exe -u %SVCNAME%

if not errorlevel 0 goto errExplain

echo Service %SVCDISP% removed

goto cmdEnd

 

 

:cmdStart

REM Executed on service start

del .r.lock 2>&1 | findstr /C:"being used" > nul

if not errorlevel 1 (

  echo Could not continue. Locking file already in use.

  goto cmdEnd

)

echo Y > .r.lock

jbosssvc.exe -p 1 "Starting %SVCDISP%" > D:\jBoss\jboss-as-7.1.1.Final\standalone\log\standalone.log

call standalone.bat --server-config=standalone.xml < .r.lock >> D:\jBoss\jboss-as-7.1.1.Final\standalone\log\standalone.log 2>&1

jbosssvc.exe -p 1 "Shutdown %SVCDISP% service" >> D:\jBoss\jboss-as-7.1.1.Final\standalone\log\standalone.log

del .r.lock

goto cmdEnd

 

 

:cmdStop

REM Executed on service stop

echo Y > .s.lock

jbosssvc.exe -p 1 "Shutting down %SVCDISP%" > D:\jBoss\jboss-as-7.1.1.Final\standalone\log\shutdown.log

call jboss-cli.bat --connect command=:shutdown >> D:\jBoss\jboss-as-7.1.1.Final\standalone\log\shutdown.log 2>&1

jbosssvc.exe -p 1 "Shutdown %SVCDISP% service" >> D:\jBoss\jboss-as-7.1.1.Final\standalone\log\shutdown.log

del .s.lock

goto cmdEnd

 

 

:cmdRestart

REM Executed manually from command line

REM Note: We can only stop and start

echo Y > .s.lock

jbosssvc.exe -p 1 "Shutting down %SVCDISP%" >> D:\jBoss\jboss-as-7.1.1.Final\standalone\log\shutdown.log

call jboss-cli.bat --connect command=:shutdown >> D:\jBoss\jboss-as-7.1.1.Final\standalone\log\shutdown.log 2>&1

del .s.lock

:waitRun

REM Delete lock file

del .r.lock > nul 2>&1

REM Wait one second if lock file exist

jbosssvc.exe -s 1

if exist ".r.lock" goto waitRun

echo Y > .r.lock

jbosssvc.exe -p 1 "Restarting %SVCDISP%" >> D:\jBoss\jboss-as-7.1.1.Final\standalone\log\standalone.log

call standalone.bat --server-config=standalone.xml < .r.lock >> D:\jBoss\jboss-as-7.1.1.Final\standalone\log\standalone.log 2>&1

jbosssvc.exe -p 1 "Shutdown %SVCDISP% service" >> D:\jBoss\jboss-as-7.1.1.Final\standalone\log\standalone.log

del .r.lock

goto cmdEnd

 

 

:cmdSignal

REM Send signal to the service.

REM Requires jbosssch.dll to be loaded in JVM

@if not ""%2"" == """" goto execSignal

echo Missing signal parameter.

echo Usage: service signal [0...9]

goto cmdEnd

:execSignal

jbosssvc.exe -k%2 %SVCNAME%

goto cmdEnd

 

 

:cmdEnd

pps:注册的jBoss服务内存是在service.bat里面配置的，我之前一直在standalone.conf里面配置内存，然后配置的内存都已经很大了，但是部署项目的时候还是一直要报内存溢出。查了好久资料，都没有什么办法，突然脑洞一开试试在service.bat里面配置，果然可以了。