ABAP - SALV教程05 添加页眉和页脚

最新推荐文章于 2024-05-07 09:44:22 发布
最新推荐文章于 2024-05-07 09:44:22 发布
阅读量1k 收藏 21
点赞数 16
分类专栏： ABAP-SALV 文章标签： ABAP
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/heathlx/article/details/136424204
版权
  •  先看看效果叭
  • CL_SALV_TABLE提供了SET_TOP_OF_LIST方法设置页眉显示和SET_TOP_OF_LIST_PRINT方法设置页眉打印来实现添加页眉的目的。
  • CL_SALV_TABLE提供了SET_END_OF_LIST方法设置页脚显示和SET_END_OF_LIST_PRINT方法设置页脚打印来实现添加页脚的目的。
  • 这个四个方法的传入参数为CL_SALV_FORM_LAYOUT_GRID类型，这是个类。
  • 实现步骤
  • 定义两个私有方法；SET_TOPPAGE:添加页眉，SET_ENDPAGE:添加页脚 
      PRIVATE SECTION.

    METHODS:
      set_toppage CHANGING co_alv TYPE REF TO cl_salv_table.

    METHODS:
      set_endpage CHANGING co_alv TYPE REF TO cl_salv_table.
      METHOD set_toppage.

    DATA: lo_h_label TYPE REF TO cl_salv_form_label,
          lo_h_flow  TYPE REF TO cl_salv_form_layout_flow.

    DATA(lo_header) = NEW cl_salv_form_layout_grid( ).

*   通过Row 和 column字段定位在top of page的文本输出位置
*   粗体 第一行第一列
    lo_h_label = lo_header->create_label( row = 1 column = 1 ).
    lo_h_label->set_text( 'Sale Orders of Report' ).

*   第二行第一列
    lo_h_flow = lo_header->create_flow( row = 2  column = 1 ).
    lo_h_flow->create_text( text = 'Create By:' && sy-uname ).

*   第三行第一列
    lo_h_flow = lo_header->create_flow( row = 3  column = 1 ).
    lo_h_flow->create_text( text = 'Number of Records in the output' ).

*   第三行第二列
    lo_h_flow = lo_header->create_flow( row = 3  column = 2 ).
    lo_h_flow->create_text( text = '20' ).

*   页眉显示
    co_alv->set_top_of_list( lo_header ).
*   页眉打印
    co_alv->set_top_of_list_print( lo_header ).
  ENDMETHOD.

  METHOD set_endpage.

    DATA: lo_f_label TYPE REF TO cl_salv_form_label,
          lo_f_flow  TYPE REF TO cl_salv_form_layout_flow.

    DATA(lo_footer) = NEW cl_salv_form_layout_grid( ).

*   通过Row 和 column字段定位在top of page的文本输出位置
*   粗体 第一行第一列
    lo_f_label = lo_footer->create_label( row = 1 column = 1 ).
    lo_f_label->set_text( 'Bilibili University' ).

*   第二行第一列
    lo_f_flow = lo_footer->create_flow( row = 2  column = 1 ).
    lo_f_flow->create_text( text = 'Date:' && sy-datum ).

*
    lo_f_flow = lo_footer->create_flow( row = 3  column = 1 ).
    lo_f_flow->create_text( text = 'Footer number' ).
*
    lo_f_flow = lo_footer->create_flow( row = 3  column = 2 ).
    lo_f_flow->create_text( text = 1 ).

*   页眉打印
    co_alv->set_end_of_list( lo_footer ).
*   页脚打印
    co_alv->set_end_of_list_print( lo_footer ).

  ENDMETHOD.
     
  • 同样的也是在创建SALV实例对象后调用方法 
        TRY.
        cl_salv_table=>factory(
          IMPORTING
            r_salv_table = mo_salv
          CHANGING
            t_table      = mt_data ).
      CATCH cx_salv_msg INTO DATA(lx_msg).
    ENDTRY.

    me->set_toppage( CHANGING co_alv = mo_salv ).
    me->set_endpage( CHANGING co_alv = mo_salv ).
     
  • 完整代码  
    CLASS lcl_model DEFINITION.
  PUBLIC SECTION.
    TYPES:BEGIN OF TY_dATA,
            vbeln TYPE vbak-vbeln,
            erdat TYPE erdat,
            erzet TYPE erzet,
            ernam TYPE ernam,
            auart TYPE auart.
    TYPES:END  OF ty_data.

    DATA mt_data TYPE TABLE OF ty_data.

    DATA mo_salv TYPE REF TO cl_salv_table.

    "获取数据的方法
    METHODS get_data.
    "展示SALV的方法
    METHODS alv_show.

  PRIVATE SECTION.
    METHODS:
      set_status  CHANGING co_alv TYPE REF TO cl_salv_table.

    METHODS:
      set_toppage CHANGING co_alv TYPE REF TO cl_salv_table.

    METHODS:
      set_endpage CHANGING co_alv TYPE REF TO cl_salv_table.

ENDCLASS.

CLASS lcl_model IMPLEMENTATION.
  METHOD get_data.
    SELECT vbeln erdat erzet ernam auart
      INTO TABLE mt_data
      FROM vbak
      UP TO 20 ROWS.
  ENDMETHOD.

  METHOD alv_show.
    TRY.
        cl_salv_table=>factory(
          IMPORTING
            r_salv_table = mo_salv
          CHANGING
            t_table      = mt_data ).
      CATCH cx_salv_msg INTO DATA(lx_msg).
    ENDTRY.
    me->set_status( CHANGING co_alv = mo_salv ).
    me->set_toppage( CHANGING co_alv = mo_salv ).
    me->set_endpage( CHANGING co_alv = mo_salv ).
    mo_salv->display( ).
  ENDMETHOD.

  METHOD set_status.
    DATA(lo_functions) = co_alv->get_functions( ).
    "cl_salv_functions_list类型的实例对象的添加状态方法
    lo_functions->set_all( abap_true ).
    "lo_functions->set_default( abap_true ).
  ENDMETHOD.

  METHOD set_toppage.

    DATA: lo_h_label TYPE REF TO cl_salv_form_label,
          lo_h_flow  TYPE REF TO cl_salv_form_layout_flow.

    DATA(lo_header) = NEW cl_salv_form_layout_grid( ).

*   通过Row 和 column字段定位在top of page的文本输出位置
*   粗体 第一行第一列
    lo_h_label = lo_header->create_label( row = 1 column = 1 ).
    lo_h_label->set_text( 'Sale Orders of Report' ).

*   第二行第一列
    lo_h_flow = lo_header->create_flow( row = 2  column = 1 ).
    lo_h_flow->create_text( text = 'Create By:' && sy-uname ).

*   第三行第一列
    lo_h_flow = lo_header->create_flow( row = 3  column = 1 ).
    lo_h_flow->create_text( text = 'Number of Records in the output' ).

*   第三行第二列
    lo_h_flow = lo_header->create_flow( row = 3  column = 2 ).
    lo_h_flow->create_text( text = '20' ).
*
*   页眉显示
    co_alv->set_top_of_list( lo_header ).
*
*   页眉打印
    co_alv->set_top_of_list_print( lo_header ).
  ENDMETHOD.

  METHOD set_endpage.

    DATA: lo_f_label TYPE REF TO cl_salv_form_label,
          lo_f_flow  TYPE REF TO cl_salv_form_layout_flow.

    DATA(lo_footer) = NEW cl_salv_form_layout_grid( ).

*   通过Row 和 column字段定位在top of page的文本输出位置
*   粗体 第一行第一列
    lo_f_label = lo_footer->create_label( row = 1 column = 1 ).
    lo_f_label->set_text( 'Bilibili University' ).

*   第二行第一列
    lo_f_flow = lo_footer->create_flow( row = 2  column = 1 ).
    lo_f_flow->create_text( text = 'Date:' && sy-datum ).

*
    lo_f_flow = lo_footer->create_flow( row = 3  column = 1 ).
    lo_f_flow->create_text( text = 'Footer number' ).
*
    lo_f_flow = lo_footer->create_flow( row = 3  column = 2 ).
    lo_f_flow->create_text( text = 1 ).

    co_alv->set_end_of_list( lo_footer ).
*   页脚打印
    co_alv->set_end_of_list_print( lo_footer ).

  ENDMETHOD.

ENDCLASS.

START-OF-SELECTION.
  DATA(lo_model) = NEW lcl_model( ).
  lo_model->get_data( ).
  lo_model->alv_show( ).

HeathlX
关注
  • 16
    点赞
  • 踩
  • 21
    收藏
    觉得还不错? 一键收藏
  • 2
    评论
专栏目录
Function实现ALV Table六：页眉页脚
焕然一新
09-23 2761
 v/:* {behavior:url(#default#VML);}o/:* {behavior:url(#default#VML);}w/:* {behavior:url(#default#VML);}.shape {behavior:url(#default#VML);} Normal 0 7.8 磅 0 2
五、SALV 添加页眉Top of Page 和页脚End of Page
weixin_42459695的博客
03-13 274
SALV 添加页眉Top of Page 和页脚End of Page
SAP ABAP ALV分页显示
12-22
这个代码是利用了内表数据转到另一个内表的技术.达到最后的分页效果
OO实现ALV TABLE 十：ALV的页眉页脚
少年休闲海
06-20 1403
除了可以通过类CL_SALV_EVENTS_TABLE的事件设置ALV的页眉页脚之外，还可以通过类CL_SALV_TABLE的方法SET_TOP_OF_LIST,SET_TOP_OF_LIST_PRINT, SET_END_OF_LIST,SET_END_OF_LIST_PRINT这四个方法。页眉页脚的显示可以设置显示和打印时不一样，打印时的页眉页脚通过方法SET_TOP_OF_LIST_PRI
SAP 页眉and页脚
weixin_43523421的博客
01-08 987
进行需求开发时，会需要在页眉和页脚进行信息展示，本文主要讲如何实现页眉和页脚的内容输出。页眉页脚的输出主要依赖于两个事件：top_of_page、end_of_list，function alv和oo alv只是在实现方法上有所不同，开发者可以根据自己的需要进行选择。
SAP-ABAP-OO-实现-CL-SALV-TABLE
09-06
### SAP-ABAP-OO 实现 CL-SALV-TABLE 的关键知识点 #### 1. ABAP 面向对象的 ALV 显示方法 在 SAP 的 ABAP 环境中，ALV (Application List Viewer) 是一种非常常用的技术，用于在屏幕上以表格的形式展示数据。传统...
ABAP-培训教程.ppt
12-25
ABAP-培训教程.ppt该文档详细且完整，值得借鉴下载使用，欢迎下载使用，有问题可以第一时间联系作者~
abap-metrics-provider:让我们使用预定义或自定义指标通过您选择的监视工具来监视abap堆栈
05-17
abap-metrics提供者 兼容性 建筑学 组件图 类图 提供者 刮刀 文件资料 本地测试 本地测试文件夹 影片播放清单 基于 https://github.com/pacroy/abap-prometheus
abap-openapi-client:ABAP中的ABAP OpenAPI客户端生成器
05-19
abap-openapi-client ABAP中的ABAP 客户端生成器 通过命令行运行的可能性（NodeJS） 有可能针对不同的ABAP版本（例如Steampunk）生成 每个OpenAPI定义一个独立的全局类+接口 可以在ABAP堆栈上运行生成 最终支持...
ABAP-Library:有用的ABAP代码段
05-29
ABAP库 该存储库代表我的个人可重用ABAP代码库。 随意使用或贡献！ 为了组织起见，文件位于干净的子文件夹中。 这里的许多类还表示示例实现。 这些文件都不包含任何公司特定的功能逻辑-因此没有“机密”被泄露。 ...
【ABAP系列】SAP ABAP ALV中的TOP_OF_PAGE添加任意图标
ARICK2014的博客
07-12 696
公众号：SAP Technical 本文作者：matinal 原文出处：http://www.cnblogs.com/SAPmatinal/ 原文链接：【MM系列】SAP ABAP ALV中的TOP_OF_PAGE添加任意图标 前言部分 大家可以关注我的公众号，公众号里的排版更好，阅读更舒适。 正文部分 自己测试内容，仅供参考。 转载于:htt...
matinal：SAP ABAP cl_salv_table的简单使用
matinal 當冬夜漸暖 。公众号：matinal
09-06 315
双击汇总ALV的某一行
ABAP--如何使用CL_SALV_TABLE 的代码样例
阿土工作室
04-23 1189
1、简单的CL_SALV_TABLE 的使用 REPORT ZALVOM_DEMO1. data: ispfli type table of spfli. data: gr_table type ref to cl_salv_table. start-of-selection. select * into table ispfli from spfli. cl_salv_table=>factory( importing r_salv_table = gr_table changing t...
abap cl_salv_table使用方法
u010398600的博客
11-24 255
abap cl_salv_table使用方法
ABAP ALV中的TOP_OF_PAGE添加任意图标
matinal 當冬夜漸暖 。公众号：matinal
12-09 2257
ABAP TOP_OF_PAGE添加任意图标
ALV TOP_OF_PAGE-页头信息
Leo520liang的博客
05-07 1335
在ABAP ALV中，是一个事件标识符，用于描述在报表每一页顶部打印或显示内容的情况。当ALV在打印或显示数据时，每翻到新的一页，系统就会触发事件，这时你可以定义一个处理程序（通常是FORM或CLASS的方法）来控制在新页顶部展示哪些内容，比如公司logo、报表标题、页码、日期等。
ALV 页眉的使用
Nathan的博客
06-03 579
FORMFRM_DISPLAY. CLEARS_LAYOUT.S_LAYOUT-ZEBRA='X'.S_LAYOUT-COLWIDTH_OPTIMIZE='X'.*s_layout-box_fieldname='BOX'. PERFORMFRM_FILL_FIELD. CALLFUNCTION'REUSE_ALV_GRID_DISPLAY' ...
SQLAlchemy-2.0.31-cp38-cp38-musllinux_1_2_aarch64.whl
最新发布
08-31
SQLAlchemy 是一个 SQL 工具包和对象关系映射（ORM）库，用于 Python 编程语言。它提供了一个高级的 SQL 工具和对象关系映射工具，允许开发者以 Python 类和对象的形式操作数据库，而无需编写大量的 SQL 语句。SQLAlchemy 建立在 DBAPI 之上，支持多种数据库后端，如 SQLite, MySQL, PostgreSQL 等。 SQLAlchemy 的核心功能： 对象关系映射（ORM）： SQLAlchemy 允许开发者使用 Python 类来表示数据库表，使用类的实例表示表中的行。 开发者可以定义类之间的关系（如一对多、多对多），SQLAlchemy 会自动处理这些关系在数据库中的映射。 通过 ORM，开发者可以像操作 Python 对象一样操作数据库，这大大简化了数据库操作的复杂性。 表达式语言： SQLAlchemy 提供了一个丰富的 SQL 表达式语言，允许开发者以 Python 表达式的方式编写复杂的 SQL 查询。 表达式语言提供了对 SQL 语句的灵活控制，同时保持了代码的可读性和可维护性。 数据库引擎和连接池： SQLAlchemy 支持多种数据库后端，并且为每种后端提供了对应的数据库引擎。 它还提供了连接池管理功能，以优化数据库连接的创建、使用和释放。 会话管理： SQLAlchemy 使用会话（Session）来管理对象的持久化状态。 会话提供了一个工作单元（unit of work）和身份映射（identity map）的概念，使得对象的状态管理和查询更加高效。 事件系统： SQLAlchemy 提供了一个事件系统，允许开发者在 ORM 的各个生命周期阶段插入自定义的钩子函数。 这使得开发者可以在对象加载、修改、删除等操作时执行额外的逻辑。
SAP ABAP入门教程：BC-ABAP Programming指南
"SAP ABAP学习教材，专注于Programming，适合作为入门教程。包含SAP ABAP BC系列的相关内容，基于Release 4.6B，适用于了解和掌握ABAP编程基础知识。" SAP ABAP（Advanced Business Application Programming）是SAP...
评论 2
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值