千万级数据库查询+分页优化

思路:

方法一:

select top 5 *

from dbo.CompanyNews

where PKId >

(select max(PKId) from CompanyNews WHERE pkid in

(select top 5 PKId from dbo.CompanyNews order by PKId)

)

order by pkid

上面等价于= =

方法二(建议采用该方法,原因:top加快查询速度,而in 减慢数度,)

select top 5 *

from dbo.CompanyNews

where PKId >

(select max(PKId) from

(select top 5 PKId from dbo.CompanyNews order by PKId) as T

)

order by pkid

示例代码如下:

-------------------------------------------------------------------
-- 功能:     获取指定页的分页数据
-- 作者:     SQ
-- 修改时间: 2005-08-24
CREATE PROCEDURE p_GetPageRecord
@tblName varchar(255), -- 表名
@strGetFields varchar(1000) = '*', -- 需要返回的列
@fldName varchar(255)='', -- 排序的字段名
@PageSize int = 10, -- 页尺寸
@PageIndex int = 1, -- 页码
@doCount bit = 0, -- 返回记录总数, 非 0 值则返回
@OrderType bit = 0, -- 设置排序类型, 非 0 值则降序
@strWhere varchar(1500) = '' -- 查询条件 (注意: 不要加 where)
AS
declare @strSQL varchar(5000) -- 主语句
declare @strTmp varchar(110) -- 临时变量
declare @strOrder varchar(400) -- 排序类型
if @doCount != 0
begin
  if @strWhere !=''
  set @strSQL = 'select count(*) as Total from [' + @tblName + '] where '+@strWhere
  else
  set @strSQL = 'select count(*) as Total from [' + @tblName + ']'
end
--以上代码的意思是如果@doCount传递过来的不是0，就执行总数统计。以下的所有代码都是@doCount为0的情况
else
begin
  if @OrderType != 0
   begin
   set @strTmp = '<(select min'
   set @strOrder = ' order by [' + @fldName +'] desc'
   --如果@OrderType不是0，就执行降序，这句很重要！
   end
  else
   begin
   set @strTmp = '>(select max'
   set @strOrder = ' order by [' + @fldName +'] asc'
   end
  if @PageIndex = 1
   begin
   if @strWhere != ''
   set @strSQL = 'select top ' + str(@PageSize) +' '+@strGetFields+ ' from [' + @tblName + '] where ' + @strWhere + ' ' + @strOrder
   else
   set @strSQL = 'select top ' + str(@PageSize) +' '+@strGetFields+ ' from ['+ @tblName + '] '+ @strOrder
   --如果是第一页就执行以上代码，这样会加快执行速度
   end
  else
   begin
   --以下代码赋予了@strSQL以真正执行的SQL代码
   set @strSQL = 'select top ' + str(@PageSize) +' '+@strGetFields+ ' from ['
   + @tblName + '] where [' + @fldName + ']' + @strTmp + '(['+ @fldName + ']) from (select top ' + str((@PageIndex-1)*@PageSize) + ' ['+ @fldName + '] from [' + @tblName + ']' + @strOrder + ') as tblTmp)'+ @strOrder
   if @strWhere != ''
   set @strSQL = 'select top ' + str(@PageSize) +' '+@strGetFields+ ' from ['
   + @tblName + '] where [' + @fldName + ']' + @strTmp + '(['
   + @fldName + ']) from (select top ' + str((@PageIndex-1)*@PageSize) + ' ['
   + @fldName + '] from [' + @tblName + '] where ' + @strWhere + ' '
   + @strOrder + ') as tblTmp) and ' + @strWhere + ' ' + @strOrder
   end
end
exec (@strSQL)
--print @strSQL

GO
 

在大数据量的情况下，特别是在查询最后几页的时候，查询时间一般不会超过9秒；而用其他存储过程，在实践中就会导致超时，所以这个存储过程非常适用于大容量数据库的查询。
笔者希望能够通过对以上存储过程的解析，能给大家带来一定的启示，并给工作带来一定的效率提升，同时希望同行提出更优秀的实时数据分页算法。
四、聚集索引的重要性和如何选择聚集索引
在上一节的标题中，笔者写的是：实现小数据量和海量数据的通用分页显示存储过程。这是因为在将本存储过程应用于“办公自动化”系统的实践中时，笔者发现这第三种存储过程在小数据量的情况下，有如下现象：
1、分页速度一般维持在1秒和3秒之间。
2、在查询最后一页时，速度一般为5秒至8秒，哪怕分页总数只有3页或30万页。
虽然在超大容量情况下，这个分页的实现过程是很快的，但在分前几页时，这个1－3秒的速度比起第一种甚至没有经过优化的分页方法速度还要慢，借用户的话说就是“还没有ACCESS数据库速度快”，这个认识足以导致用户放弃使用您开发的系统。
笔者就此分析了一下，原来产生这种现象的症结是如此的简单，但又如此的重要：排序的字段不是聚集索引！
本篇文章的题目是：“查询优化及分页算法方案”。笔者只所以把“查询优化”和“分页算法”这两个联系不是很大的论题放在一起，就是因为二者都需要一个非常重要的东西――聚集索引。
在前面的讨论中我们已经提到了，聚集索引有两个最大的优势：
1、以最快的速度缩小查询范围。
2、以最快的速度进行字段排序。
第1条多用在查询优化时，而第2条多用在进行分页时的数据排序。
而聚集索引在每个表内又只能建立一个，这使得聚集索引显得更加的重要。聚集索引的挑选可以说是实现“查询优化”和“高效分页”的最关键因素。
但要既使聚集索引列既符合查询列的需要，又符合排序列的需要，这通常是一个矛盾。
笔者前面“索引”的讨论中，将fariqi，即用户发文日期作为了聚集索引的起始列，日期的精确度为“日”。这种作法的优点，前面已经提到了，在进行划时间段的快速查询中，比用ID主键列有很大的优势。
但在分页时，由于这个聚集索引列存在着重复记录，所以无法使用max或min来最为分页的参照物，进而无法实现更为高效的排序。而如果将ID主键列作为聚集索引，那么聚集索引除了用以排序之外，没有任何用处，实际上是浪费了聚集索引这个宝贵的资源。
为解决这个矛盾，笔者后来又添加了一个日期列，其默认值为getdate()。用户在写入记录时，这个列自动写入当时的时间，时间精确到毫秒。即使这样，为了避免可能性很小的重合，还要在此列上创建UNIQUE约束。将此日期列作为聚集索引列。
有了这个时间型聚集索引列之后，用户就既可以用这个列查找用户在插入数据时的某个时间段的查询，又可以作为唯一列来实现max或min，成为分页算法的参照物。
经过这样的优化，笔者发现，无论是大数据量的情况下还是小数据量的情况下，分页速度一般都是几十毫秒，甚至0毫秒。而用日期段缩小范围的查询速度比原来也没有任何迟钝。
聚集索引是如此的重要和珍贵，所以笔者总结了一下，一定要将聚集索引建立在：
1、您最频繁使用的、用以缩小查询范围的字段上；
2、您最频繁使用的、需要排序的字段上。