《王爽——汇编语言》P172答案

assume cs:codesg, ds:datasg, es: table, ss: stack

datasg segment
    db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
    db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
    db '1993','1994','1995'
    ;21年的年份字符串，每个字符占一个字节
    dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
    dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
    ;以上表示21年公司收入的21个dword型数据
    dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
    dw 11542,14430,15257,17800
    ;以上表示21年公司雇员人数的21个word型数据
datasg ends

table segment
    db 21 dup ('year summ ne ?? ')
table ends

stack segment

    dw 0,0,0,0,0,0,0,0
stack ends

codesg segment 

start:    mov ax, datasg
          mov ds, ax
          mov ax, table
          mov es, ax
          mov ax, stack
          mov ss, ax
          mov sp, 16

          mov bx, 0      ;table每一行的首地址
          mov dx, 0      ;与每年各项的数据项的位置对应
          mov cx, 21     ;外层循环次数
    
s1:       mov si, 0
          push cx,       ;保存外层循环的次数，
          mov cx, 4      ;内存循环次数，用户年份

          mov bp, dx
          add bp, bp
          add bp, bp
          

s0:      ;内层循环，将年份字符串复制到table的第一项内
          
          mov al, ds:[bp+si]
          mov es:[bx+si], al
          inc si 
          loop s0
          
          mov ax, ds:[bp+54H]
          mov es:[bx+5H], ax
          mov ax, ds:[bp+56H]
          mov es:[bx+7H], ax

          mov bp, dx
          add bp, bp
          mov ax, ds:[bp+0A8H]
          mov es:[bx+0AH], ax

          push dx              ;dx入栈，下面这段除法程序用到dx寄存器
          mov ax, es:[bx+5H]   ;被除数的低16位
          mov dx, es:[bx+7H]   ;被除数的高16位
          div word ptr es:[bx+0AH]
          mov es:[bx+0DH], ax

          add bx, 10H
          pop dx
          inc dx
          pop cx
          loop s1

          mov ax, 4c00H
          int 21H

codesg ends

end start