简体中文数字转阿拉伯数字

简体中文数字转阿拉伯数字，分为两个存储过程，一个是处理小数位的，一个是处理整数位的，加入部分检错处理，没有穷举所有非法输入，支持数据大小为：number型支持到多少就支持到多少，这是个写得比较好的转换方法，不过当遇到如10000 0000 0000 0000 这么大的数字，我的习惯是称之为“一万万亿”，可能有人认为应该叫做“一亿亿”，那就一习惯问题，改起来也不难，有需要再改吧。

  --将中文数字转为阿拉伯小数
  function cnNum2AraDec(p_cnNum string) return number is
    v_cnNum varchar2(255);
    t_cnNum varchar(4);
    v_dec   varchar2(255);
    v_num   number;
  begin
    if p_cnNum is not null then
      if instr(p_cnNum, '点') > 1 then
        v_cnNum := substr(p_cnNum, instr(p_cnNum, '点') + 1);
        for i in 1 .. length(v_cnNum) loop
          t_cnNum := substr(v_cnNum, i, 1);
          begin
            v_dec := v_dec || case
                       when t_cnNum = '一' then
                        1
                       when t_cnNum = '二' then
                        2
                       when t_cnNum = '三' then
                        3
                       when t_cnNum = '四' then
                        4
                       when t_cnNum = '五' then
                        5
                       when t_cnNum = '六' then
                        6
                       when t_cnNum = '七' then
                        7
                       when t_cnNum = '八' then
                        8
                       when t_cnNum = '九' then
                        9
                       when t_cnNum = '〇' then
                        0
                     end; --出现这十个数字以外的将报错
          exception
            when others then
              raise_application_error(-20999, '非法中文数字!');
          end;
        end loop;
        v_num := to_number('0.' || v_dec);
        if instr(p_cnNum, '负') = 1 then
          v_num := -v_num;
        end if;
        return v_num;
      else
        return null;
      end if;
    else
      return null;
    end if;
  end;

  --将中文数字转为阿拉伯整数
  function cnNum2AraInt(p_cnNum string) return number is
    i        pls_integer;
    v_cnPNum varchar2(255); --整数部分
    t_araNum number;
    s_araNum number := 0;
    t_cnNum  varchar(4);
    t2_cnNum varchar2(4);
    len      pls_integer;
    dn       pls_integer; --十的次数,为空时不用检错，为0时需要检查数字相连接的错误输入
    wn       pls_integer := 0; --万的次数
  begin
    if instr(p_cnNum, '点') > 0 then
      v_cnPNum := substr(p_cnNum, 1, instr(p_cnNum, '点') - 1);
    else
      v_cnPNum := p_cnNum;
    end if;
 
    if instr(v_cnPNum, '负') = 1 then
      v_cnPNum := substr(v_cnPNum, 2);
    end if;
 
    --如果以'十'开头，则在前面补'一'
    if substr(v_cnPNum, 1, 1) = '十' then
      v_cnPNum := '一' || v_cnPNum;
    end if;
 
    len := length(v_cnPNum);
    i   := len;
    loop
      exit when i <= 0;
      t_cnNum := substr(v_cnPNum, i, 1);
      if t_cnNum in ('十', '百', '千') and dn > 0 then
        raise_application_error(-20999, '非法中文数字!'); --当出现"十百千"相连接时，为非法中文数字
      end if;
      case
        when t_cnNum = '十' then
          dn := 1;
          i  := i - 1;
        when t_cnNum = '百' then
          dn := 2;
          i  := i - 1;
        when t_cnNum = '千' then
          dn := 3;
          i  := i - 1;
        when t_cnNum = '万' then
          dn := null;
          wn := nvl(wn, 0) + 1;
          i  := i - 1;
        when t_cnNum = '亿' then
          dn := null;
          wn := 2;
          i  := i - 1;
        else
          if t_cnNum in
             ('一', '两', '二', '三', '四', '五', '六', '七', '八', '九') and dn = 0 then
            raise_application_error(-20999, '非法中文数字!'); --当出现"一二三四..."相连接时，为非法中文数字
          end if;
          t_araNum := case
                        when t_cnNum = '一' then
                         1
                        when t_cnNum = '二' then
                         2
                        when t_cnNum = '两' then
                         2
                        when t_cnNum = '三' then
                         3
                        when t_cnNum = '四' then
                         4
                        when t_cnNum = '五' then
                         5
                        when t_cnNum = '六' then
                         6
                        when t_cnNum = '七' then
                         7
                        when t_cnNum = '八' then
                         8
                        when t_cnNum = '九' then
                         9
                        when t_cnNum = '〇' then
                         0
                      end;
          if t_araNum is null then
            --不在所有有效中文数字中，则报错
            raise_application_error(-20999, '非法中文数字!');
          elsif t_araNum is not null then
            s_araNum := s_araNum + t_araNum * power(10, nvl(dn, 0)) *
                        power(10000, nvl(wn, 0));
            i        := i - 1;
            dn       := 0; --重置十的次数为0;
            t_araNum := null;
          end if;
      end case;
    end loop;
    if instr(p_cnNum, '负') = 1 then
      s_araNum := -s_araNum;
    end if;
    return s_araNum;
  end;

  --将中文数字转为阿拉伯数字
  function cnNumtoAraNum(p_cnnum string) return number is
  begin
    return nvl(cnNum2AraInt(p_cnnum), 0) + nvl(cnNum2AraDec(p_cnnum), 0);
  end;